арифметический компьютер

Question

Мне нужна помощь в прологе, что довольно ново для меня. Я должен спроектировать маленький арифметический компьютер. Выражение, которое будет оценено, будет представлено в виде списка, например:

?-evaluate([2,+,4,*,5,+,1,*,2,*,3],R).

Я пытаюсь сделать это, создав два предиката, один из которых называется parse, для преобразования моего списка, например:

?-parse([1,+,2,*,3],PF).
PF=[+,1,[*,2,3]]

и еще один, чтобы оценить новое выражение.

?-evpf([+,1,[*,2,3]],R).
R=7

У меня проблемы с первой частью, кто-нибудь может мне помочь с кодом?

Answer 1

Синтаксический анализ (= преобразование списка в абстрактное синтаксическое дерево) легко выполнить с помощью DCG:

list_ast(Ls, AST) :- phrase(expression(AST), Ls).

expression(E)       --> term(T), expression_r(T, E).

expression_r(E0, E) --> [+], term(T), expression_r(E0+T, E).
expression_r(E0, E) --> [-], term(T), expression_r(E0-T, E).
expression_r(E, E)  --> [].

term(T)       --> power(P), term_r(P, T).
term_r(T0, T) --> [*], power(P), term_r(T0*P, T).
term_r(T0, T) --> [/], power(P), term_r(T0/P, T).
term_r(T, T)  --> [].

power(P)          --> factor(F), power_r(F, P).
power_r(P0, P0^P) --> [^], factor(P1), power_r(P1, P).
power_r(P, P)     --> [].

factor(N) --> [N], { number(N) }.
factor(E) --> ['('], expression(E), [')'].

Для фактической оценки выражения вы можете использовать встроенный предикат / 2.Пример запроса:

?- list_ast([2,+,4,+,5,+,1,+,2,*,3], Ast), V is Ast.
Ast = 2+4+5+1+2*3,
V = 18 ;
false.