Как заменить теги br тегами в шаблоне XSL? - PullRequest
Новая
       22

Как заменить теги br тегами в шаблоне XSL?

2 голосов
/ 31 января 2012

Предположим, у меня есть простой XML-файл: 

<data>
  <text>Hello world!&lt;br&gt;Nice to see you all!&lt;br&gt;Goodbye!</text>
</data>

Теперь я хочу заменить все &lt;br&gt; строки на &#10; строки, поэтому результат должен быть, например: 

<transformed>
  <text>Hello world!&#10;Nice to see you all!&#10;Goodbye!</text>
</transformed>

Как мне это сделать?

Функциональность замены XSL проста в реализации (например, в http://geekswithblogs.net/Erik/archive/2008/04/01/120915.aspx), но сложнее всего заставить преобразователь XSL вывести эти строки &#10;. Iлибо получите невидимый нормальный перевод строки, либо &amp;#10;

Прекрасным ответом будет шаблон XSL, который добьется цели.

1 Ответ

1 голос
/ 31 января 2012

Использование: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes"/>

  <xsl:template match="/data">
    <transformed>
      <text>
        <xsl:call-template name="string-replace-all">
          <xsl:with-param name="text" select="text" />
          <xsl:with-param name="replace">&lt;br&gt;</xsl:with-param>
          <xsl:with-param name="by">&amp;#10;</xsl:with-param>
        </xsl:call-template>
      </text>
    </transformed>
  </xsl:template>

  <xsl:template name="string-replace-all">
    <xsl:param name="text" />
    <xsl:param name="replace" />
    <xsl:param name="by" />
    <xsl:choose>
      <xsl:when test="contains($text, $replace)">
        <xsl:value-of select="substring-before($text, $replace)" />
        <xsl:value-of select="$by" disable-output-escaping="yes" />
        <xsl:call-template name="string-replace-all">
          <xsl:with-param name="text" select="substring-after($text,$replace)" />
          <xsl:with-param name="replace" select="$replace" />
          <xsl:with-param name="by" select="$by" />
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$text" />
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>

выход: 

<transformed>
  <text>Hello world!&#10;Nice to see you all!&#10;Goodbye!</text>
</transformed>

Примечание:

Установить disable-output-escaping атрибут yes

...