Передача аргументов хранимой процедуре Oracle через задание планировщика - PullRequest
Новая
       37

Передача аргументов хранимой процедуре Oracle через задание планировщика

4 голосов
/ 07 февраля 2012

У меня есть хранимая процедура, которая вызывается из задания dbms. т.е. 

DBMS_SCHEDULER.RUN_JOB ('Procedure_JB', FALSE);

Хранимая процедура java-кода, которая после выполнения каких-либо действий запускает асинхронно процедуру__процесса. И тогда эта процедура_JB вызывает процедуру_Программа, а затем программа будет вызывать хранимую процедуру.

Как передать аргументы моей хранимой процедуре?

  • Аргументы, которые я должен передать на работу, взяты из Java.

Ответы [ 2 ]

9 голосов
/ 08 февраля 2012

Определите вашу работу по процедуре_JB, чтобы принимать аргументы. Затем используйте dbms_scheduler.set_job_argument_value, чтобы определить значение аргументов, которые вы хотите передать в программу, которую будет выполнять ваша работа. Пример (взято из https://forums.oracle.com/forums/thread.jspa?threadID=483135)

-- create a stored procedure with two arguments
create or replace procedure myproc (arg1 in varchar2, arg2 in varchar2)
is BEGIN null; END;
/

-- create a program with two arguments and define both
begin
dbms_scheduler.create_program
(
program_name=>'myprog',
program_action=>'myproc',
program_type=>'STORED_PROCEDURE',
number_of_arguments=>2, enabled=>FALSE
) ;

dbms_scheduler.DEFINE_PROGRAM_ARGUMENT(
program_name=>'myprog',
argument_position=>1,
argument_type=>'VARCHAR2',
DEFAULT_VALUE=>'13');

dbms_scheduler.DEFINE_PROGRAM_ARGUMENT(
program_name=>'myprog',
argument_position=>2,
argument_type=>'VARCHAR2');

dbms_scheduler.enable('myprog');
end;
/

-- create a job pointing to a program and set both argument values
begin
dbms_scheduler.create_job('myjob',program_name=>'myprog');
dbms_scheduler.set_job_argument_value('myjob',1,'first arg');
dbms_scheduler.set_job_argument_value('myjob',2,'second arg');
dbms_scheduler.enable('myjob');
end;
/
2 голосов
/ 03 августа 2018

Вместо этого используйте PLSQL_BLOCK: 

begin
dbms_scheduler.create_job (
    job_name => 'myjob',
    job_type => 'PLSQL_BLOCK',
    job_action => 'BEGIN myproc(''first arg'',''second arg''); END;',
    start_date => sysdate,
    repeat_interval => 'FREQ=HOURLY',
    enabled => true    
);
end;
/
...