Массив отсортированных пар ключ / значение в отсортированный массив ключей и хеш - PullRequest
Новая
       19

Массив отсортированных пар ключ / значение в отсортированный массив ключей и хеш

1 голос
/ 07 апреля 2011

Я занимаюсь разработкой приложения Catalyst, которое использует Template::Toolkit в качестве движка шаблонов.Одна страница нуждается в списке равных элементов ввода.Они могут быть взяты из массива, но мне нужен и порядок сортировки, и описательная метка для элемента.

Для того, чтобы иметь порядок сортировки, я бы использовал массив.Для хранения дополнительного значения на ключ идеально подходит хеш.Как совместить оба в ТТ ?Я мог бы использовать обе вещи, но это выглядит некрасиво и может привести к ошибкам при изменении полей.

Однако я предпочитаю делать это в TT, потому что как описания, так и порядок элементов формы являются интерфейсной вещью.

Вот как я бы сделал это на чистом Perl: 

#!/usr/bin/perl -w

use 5.10.0;

# definition of description and order in 1 step
my @fields = (
        property_foo => "Some property",
        property_bar => "Important field",
        property_baz => "Something else",
);

# extract information
my %descriptions = @fields;
my @order = @fields[grep {($_ + 1) % 2} 0..(scalar @fields - 1)];

say "=== natural perl sort order ===";
foreach (keys %descriptions) {say $_};

say "=== wanted output ===";
foreach (@order) {
        say $descriptions{$_} . ": [label for $_]";
}

Выходы: 

=== natural perl sort order ===
property_baz
property_foo
property_bar
=== wanted output ===
Some property: [label for property_foo]
Important field: [label for property_bar]
Something else: [label for property_baz]

Вот что я пишу в своем шаблоне: 

[%
order = (
    property_foo,
    property_bar,
    property_baz,
);

descriptions = {
    property_foo => "Some property",
    property_bar => "Important field",
    property_baz => "Something else",
}

FOREACH property IN order %]
    [% descriptions.$property %]: <input name="[% property %]" />
[% END %]

Однако действительно некрасиво иметь одну и ту же информацию (список полей) дважды.Я хочу избежать редактирования списка дважды, и с более длинным списком полей это становится действительно раздражающим (около 20 элементов, недостаточно длинных, чтобы выполнять некоторые операции с базой данных).

Ответы [ 4 ]

3 голосов
/ 07 апреля 2011

Возможно, вас заинтересует Tie :: IxHash

Это хеш, который хранит порядок добавления ключей (обновления значений не влияют на сортировку).

РЕДАКТИРОВАТЬ: краткий пример: 

use warnings;
use strict;

use Tie::IxHash; 
tie my %H, "Tie::IxHash"; 
$H{foo} = 1; 
$H{bar} = 2; 
# order of keys is now always 'foo', 'bar'

print keys %H;

РЕДАКТИРОВАТЬ2: я попробовал, и это на самом деле работает: 

#!/usr/bin/perl -w

use strict;
use Template;
use Tie::IxHash;

# my %h; # this breaks ordering
tie my %H, "Tie::IxHash"; # this keeps ordering
@H{qw/f oo b a r/} = 1..100;
# don't define $H{'keys'} or you'll get disappointed

my $tpl = Template->new();
$tpl->process(\*DATA, {hash=>\%H});

__DATA__
[% FOREACH k IN hash.keys %]
     [% k %] => [% hash.$k %]
[% END %]
3 голосов
/ 07 апреля 2011

Удивительно, как люди усложняют простые вещи!

Вам не нужен массив @fields. Пожалуйста, прочтите perldoc о ключах , значениях и сортировке . 

# untested sketch
my %description = ( prop23 => "foo", prop24 => "bar" );
foreach my $key(sort (keys %description)) {
    print $key, " is: ", $description{$key}, "\n";   # or whatever
}

Приложение: Что касается порядка ключей, просто сделайте следующее: 

my @arbitraryOrder = qw(prop42 prop35 prop1 ...);  # allows to map number to key
my %keytoNumber = ();                              # will map keys to numbers
foreach my $i(0..$#arbitraryOrder) $keyToNumber{$arbitraryOrder[$i]} = $i;

Запись функции сравнения для сортировки оставлена ​​в качестве упражнения:)

1 голос
/ 07 апреля 2011

На самом деле, если вы хотите, чтобы ваш хеш сортировался по алфавиту по ключу, Template :: Toolkit сделает это за вас.

test.pl 

use strict;
use warnings;

use Template;

my %hash = qw' a 1 b 2 c 3 ';

my $config = {
  INCLUDE_PATH => '/search/path',
};
my $input = 'test.tt2';

my $template = Template->new( $config );
$template->process( $input, {
  hash => \%hash,
})

test.tt2 

[% FOREACH hash -%]
[% key %] => [% value %]
[% END %]

выход 

a => 1
b => 2
c => 3
1 голос
/ 07 апреля 2011

Если вам нужно упорядочить и использовать несколько частей информации, вам следует рассмотреть массив ссылок на хеш-коды. 

my @fields = (
  { id => 'property_foo',
    label => 'Some property' },
  { id => 'property_bar',
    label => 'Important field' },
  { id => 'property_baz',
    label => 'Something else' },
);

foreach (@fields) {
  print "ID: $_->{id}, Label: $_->{label}\n";
}

Если сложность значительно возрастает, вы можете заменить хэш-ссылки на реальные объекты.

А в ТТ это выглядит так: 

[%-
properties = [
  {id => 'property_foo',
   label => 'Some property'},
  {id => 'property_bar',
   label => 'Important field'},
  {id => 'property_baz',
   label => 'Something else'},
];
-%]

[%- FOREACH property IN properties %]
    [% property.label %]: <input name="[% property.id %]" />
[% END %]
...