Как обойти ограничение этапа GHC? - PullRequest
Новая
       10

Как обойти ограничение этапа GHC?

9 голосов
/ 02 апреля 2012

Я пишу генератор кода, вывод которого зависит от описания полей типа данных, которое хранится в экземплярах их классов.Однако я не могу найти способ запустить функцию с аргументом, сгенерированным TH. 

{-# LANGUAGE TemplateHaskell, ScopedTypeVariables #-}
module Generator where
import Language.Haskell.TH
import Language.Haskell.TH.Syntax

data Description = Description String [Description] deriving Show

class HasDescription a where
  getDescription :: a -> Description

instance HasDescription Int where
  getDescription _ = Description "Int" []

instance (HasDescription a, HasDescription b) => HasDescription (a, b) where
  getDescription (_ :: (a, b)) = Description "Tuple2" [getDescription (undefined :: a), getDescription (undefined :: b)]

-- | creates instance of HasDescription for the passed datatype changing descriptions of its fields
mkHasDescription :: Name -> Q [Dec]
mkHasDescription dName = do
  reify dName >>= runIO . print
  TyConI (DataD cxt name tyVarBndr [NormalC cName types] derives) <- reify dName
  -- Attempt to get description of data to modify it.
  let mkSubDesc t = let Description desc ds = getDescription (undefined :: $(return t)) in [| Description $(lift $ desc ++ "Modified") $(lift ds) |]

  let body = [| Description $(lift $ nameBase dName) $(listE $ map (mkSubDesc . snd) types) |]
  getDescription' <- funD 'getDescription [clause [wildP] (normalB body) []]
  return [ InstanceD [] (AppT (ConT ''HasDescription) (ConT dName)) [getDescription'] ]

Когда другой модуль пытается использовать Генератор 

{-# LANGUAGE TemplateHaskell, ScopedTypeVariables #-}
import Generator

data MyData = MyData Int Int

mkHasDescription ''MyData

{- the code I want to generate
instance HasDescription MyData where
  getDescription _ = Description "MyData" [Description "IntModified" [], Description "IntModified" []]
-}

, появляется ошибка 

Generator.hs:23:85:
GHC stage restriction: `t'
  is used in a top-level splice or annotation,
  and must be imported, not defined locally
In the first argument of `return', namely `t'
In the expression: return t
In an expression type signature: $(return t)

edit:

Когда я спросил, я подумал, что проблема возникла только потому, что я просто не понял чего-то важного в TH, и это можно решить, переместив некоторые функции в другие модули.

Если невозможно сгенерировать предварительно вычисленные данные, как в примере из вопроса, я хотел бы узнать больше о теоретических ограничениях TH.

Ответы [ 2 ]

7 голосов
/ 02 апреля 2012

Вы можете исправить это, переместив привязку let в скобки Оксфорда: 

let mkSubDesc t = [| let Description desc ds = getDescription (undefined :: $(return t))
                     in Description (desc ++ "Modified") ds |]

Конечно, это означает, что это будет частью сгенерированного кода, но по крайней мере для этого случая,это не должно иметь значения.

4 голосов
/ 03 апреля 2012

Это действительно проблема с ограничением уровня. Проблема, как отметил Хаммар, заключается в призыве к getDescription. 

let mkSubDesc t = ... getDescription (undefined :: $(return t)) ...

Функция getDescription перегружена, и компилятор выбирает реализацию на основе типа своего аргумента. 

class HasDescription a where
  getDescription :: a -> Description

Классы типов перегружены на основе типов. Единственный способ преобразовать t в тип - это скомпилировать его. Но его компиляция помещает тип в скомпилированную программу . Вызов getDescription выполняется во время компиляции , поэтому он не имеет доступа к этому типу.

Если вы действительно хотите оценить getDescription в Template Haskell, вам нужно написать собственную реализацию getDescription, которая считывает структуру данных Template Haskell, доступную во время компиляции. 

getDescription2 :: Type -> Q Description
getDescription2 t = cases con [ ([t| Int |], "Int")
                              , (return (TupleT 2), "Tuple")
                              ]
  where
    (con, ts) = fromApp t
    fromApp (AppT t1 t2) = let (c, ts) = fromApp t1 in (c, ts ++ [t2])
    fromApp t = (t, [])
    cases x ((make_y, name):ys) = do y <- make_y
                                     if x == y
                                       then do ds <- mapM getDescription2 ts
                                               return $ Description name ds
                                       else cases x ys
    cases x [] = error "getDescription: Unrecognized type"
...