Несколько ограничений с одинаковым именем ограничения, разные пространства имен - PullRequest
Новая
       10

Несколько ограничений с одинаковым именем ограничения, разные пространства имен

1 голос
/ 10 ноября 2011

В соответствии с Руководством для разработчиков поиска: каждое ограничение имеет имя, и имя должно быть уникальным для всех операторов и ограничений в вашем узле параметров.

Мы используем пакет обогащения контента, который выдает такой результат:

`<TM360:Measurements Measurements="Distance">
    <Measurements:Distance Amount="3" Unit="inches"/>
</TM360:Measurements>
<TM360:Measurements Measurements="Volume">
    <Measurements:Volume Amount="5.0" Unit="liters"/>
</TM360:Measurements>`

Просмотр «Amount»: атрибут localName не является уникальным, но содержащий его элемент уникален.

Есть ли способ обойти ограничение уникальности имени ограничения для построенияограниченный поиск, скажем, «Сумма: 5.0», который будет включать индексы для обеих записей выше?

Каков наилучший способ справиться с этой ситуацией?

Ответы [ 3 ]

2 голосов
/ 10 ноября 2011

Вы можете создать собственное ограничение для достижения этой цели.Мне удалось это сделать, используя следующие три сценария:

  • setup-db.xqy
  • search.xqy
  • custom-constraint.xqy

Вот скрипт установки, который создает два указателя диапазона «Количество» и добавляет пару примеров документов (test1.xml и test2.xml): 

xquery version "1.0-ml";

import module namespace admin = "http://marklogic.com/xdmp/admin" at "/MarkLogic/admin.xqy" ;

declare namespace TM360        = "http://example.com/TM360";
declare namespace Measurements = "http://example.com/Measurements";

declare function local:make-amount-index($parent-name) {
  admin:database-range-element-attribute-index(
    (: data type       :) "decimal",
    (: parent name     :) "http://example.com/Measurements",$parent-name,
    (: attribute name  :) "", "Amount",
    (: collation       :) "",
    (: value positions :) false()
  )
};

(: Set up the indexes (or you can add these via the Admin UI) :)
let $dbid       := xdmp:database(),
    $rangespec1 := local:make-amount-index("Distance"),
    $rangespec2 := local:make-amount-index("Volume"),
    $config     := admin:get-configuration(),
    $config     := admin:database-add-range-element-attribute-index($config, $dbid, $rangespec1),
    $config     := admin:database-add-range-element-attribute-index($config, $dbid, $rangespec2)
return
  admin:save-configuration($config)

,

(: Add some sample docs :)
xdmp:document-insert("/test1.xml",
  <TM360:Measurements Measurements="Distance">
      <Measurements:Distance Amount="3" Unit="inches"/>
  </TM360:Measurements>),

xdmp:document-insert("/test2.xml",
  <TM360:Measurements Measurements="Volume">
      <Measurements:Volume Amount="5.0" Unit="liters"/>
  </TM360:Measurements>)

Ниже приведен search.xqy,который выполняет два поиска:

  • search:search("Amount:3",$options)
  • search:search("Amount:5",$options)

Обратите внимание, в частности, на узел $ options, который определяет пользовательское ограничение: 

xquery version "1.0-ml";

import module namespace search="http://marklogic.com/appservices/search"
       at "/MarkLogic/appservices/search/search.xqy";

declare variable $options :=
  <options xmlns="http://marklogic.com/appservices/search">
    <constraint name="Amount">
      <custom facet="false">
        <parse apply="parse-amount"
               ns="http://example.com/custom-constraint"
               at="/custom-constraint/custom-constraint.xqy">
        </parse>
      </custom>
    </constraint>
  </options>;

(: matches test1.xml :)
search:search("Amount:3",$options),

(: matches test2.xml :)
search:search("Amount:5",$options)

И, наконец, вот код custom-constraint.xqy, который преобразует текст ограничения в запрос cts OR для двух индексов Amount: 

xquery version "1.0-ml";

module namespace my = "http://example.com/custom-constraint";

declare namespace Measurements = "http://example.com/Measurements";

declare default function namespace "http://www.w3.org/2005/xpath-functions";

(: Convert the constraint text into an OR query against "Distance" and "Volume" :)
declare function my:parse-amount($constraint-qtext as xs:string,
                                 $right as schema-element(cts:query))
        as schema-element(cts:query)
{
  let $value := xs:decimal($right//cts:text)
  return
    <cts:or-query>{
      my:make-amount-query("Distance",$value),
      my:make-amount-query("Volume"  ,$value)
    }</cts:or-query>
};


declare function my:make-amount-query($parent-name, $value) {
  cts:element-attribute-range-query(
    (: parent name    :) QName("http://example.com/Measurements", $parent-name),
    (: attribute name :) xs:QName("Amount"),
    (: operator       :) "=",
    (: value          :) $value
  )
};

Если вы хотитеЕсли вы ограничены в том, чтобы функционировать как фасет, вам также понадобится реализовать функции start-facet и finish-facet (и соответственно расширить определение в вашем узле параметров. Руководство разработчика по поиску содержит примеро том, как это сделать.

2 голосов
/ 10 ноября 2011

Для достижения наилучших результатов вам придется реорганизовать или обогатить этот XML.Поисковый API разработан таким образом, чтобы максимально использовать возможности индексации MarkLogic, основанные на QNames.XML, который у вас есть сегодня, имеет один элемент QName: TM360 и несколько атрибутов QNames, ни один из которых не является строго избирательным.

Вы можете использовать XSLT или рекурсивное преобразование для переформатирования этого XML.Я бы посоветовал вам настроить что-то вроде этого: 

<dist:inches xmlns:dist="ns://fubar.distance">3</dist:inches>
<vol:liters xmlns:vol="ns://fubar.volume">5.0</vol:liters>

В качестве побочного эффекта, это позволяет вам писать более краткие запросы XPath и позволяет гораздо более конкретные типы схем для ваших узлов.

Этот вариант использования, вероятно, надуманный, но вы также можете рассмотреть возможность нормализации всех этих измерений в стандартном подмножестве единиц СИ, например http://en.wikipedia.org/wiki/Cgs,, чтобы облегчить сравнение.

1 голос
/ 10 ноября 2011

Было бы относительно просто с функциями cts.Вы можете сделать что-то вроде: 

declare namespace Measurements = "http://example.com/Measurements";

cts:search(doc(), cts:element-attribute-value-query(
  (xs:QName("Measures:Distance"), xs:QName("Measures:Volume")),
  xs:QName("Amount"),
  $myamount
))

К счастью, вы также можете выразить это как единое ограничение поиска, начиная с MarkLogic 8.0-5, и использовать это с search:search или (в настоящее время) встроенным REST.api: 

xquery version "1.0-ml";

declare namespace TM360        = "http://example.com/TM360";
declare namespace Measurements = "http://example.com/Measurements";

xdmp:document-insert(
  "/amount3.xml",
  <TM360:Measurements Measurements="Distance">
    <Measurements:Distance Amount="3" Unit="inches"/>
  </TM360:Measurements>
),
xdmp:document-insert(
  "/amount5.xml",
  <TM360:Measurements Measurements="Volume">
    <Measurements:Volume Amount="5.0" Unit="liters"/>
  </TM360:Measurements>
)

;

import module namespace search="http://marklogic.com/appservices/search"
       at "/MarkLogic/appservices/search/search.xqy";

declare variable $options :=
  <options xmlns="http://marklogic.com/appservices/search">
    <constraint name="Amount">
      <value>
        <element ns="http://example.com/Measurements" name="Distance"/>
        <element ns="http://example.com/Measurements" name="Volume"/>
        <attribute ns="" name="Amount"/>
      </value>
    </constraint>
  </options>;

(: matches /amount3.xml :)
search:search("Amount:3",$options),

(: matches /amount5.xml :)
search:search("Amount:5.0",$options)

Если у вас есть индексы диапазона для всех комбинаций атрибутов элементов, вы также можете использовать ограничение диапазона, как предложено Evan ..

HTH!

...