Flex Binding: неожиданное поведение - PullRequest
Новая
       34

Flex Binding: неожиданное поведение

0 голосов
/ 04 мая 2011

Я заметил неожиданное поведение с привязкой во Flex, мой код выглядит следующим образом:

Код приложения 

<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="vertical" horizontalAlign="center" xmlns:Model="Model.*">
    <mx:Script>
        <![CDATA[
            import Model.DataDummy;
        ]]>
    </mx:Script>
    <mx:HBox width="100%" horizontalGap="30">
        <mx:Button id="buttonChange1" label="Change property value" click="myDummy._resetMyProperty();" />
        <mx:Label id="labelRaw" text="{'My Property=' + myDummy.MyProperty}" opaqueBackground="#DDDDDD" />
        <mx:Label id="labelFormatted" text="{'My Property formatted=' + myDummy.MyPropertyFormatted}" opaqueBackground="#DDDDDD" />
    </mx:HBox>

    <Model:MyDummy id="myDummy" />

    <mx:DataGrid id="dataGrid"
         width="100%" dataProvider="{DataDummy.Dummies}">
        <mx:columns>
            <mx:DataGridColumn dataField="MyProperty" headerText="My property" />
            <mx:DataGridColumn dataField="MyPropertyFormatted" headerText="My property Formatted" />
        </mx:columns>
    </mx:DataGrid>
    <mx:Button id="buttonChange2" click="{for each ( var d:MyDummy in DataDummy.Dummies ){d._resetMyProperty();}}" label="Change property value in DataGrid" />
</mx:Application>

Код модели Model.MyDummy 

package Model
{
    import flash.events.EventDispatcher;

    import mx.formatters.NumberFormatter;
    import mx.utils.StringUtil;

    [Bindable]
    public class MyDummy extends EventDispatcher
    {
        /*** Constructor ***/
        public function MyDummy()
        {
            this._resetMyProperty();
        }

        /*** Properties ***/
        private var _myProperty:Number;
        public function get MyProperty():Number
        {
            return _myProperty;
        }
        public function set MyProperty(value:Number):void
        {
            if ( value !== _myProperty )
            {
                _myProperty = value;

                //var event:Event = new Event("ID_Changed");
                //this.dispatchEvent(event);
            }
        }

        //[Bindable (event="ID_Changed", type="flash.events.Event")]
        public function get MyPropertyFormatted():String
        {
            var idFormatted:String = "";

            if ( ! isNaN(this.MyProperty) )
            {
                var formatter:NumberFormatter = new NumberFormatter();
                formatter.precision = 2;
                idFormatted = formatter.format(this.MyProperty);
            }
            else
                idFormatted = MyProperty.toString();

            return StringUtil.substitute( "{0} (My property has been formatted)", idFormatted );
        }

        /*** Methods ***/
        public function _resetMyProperty():void
        {
            this.MyProperty = Math.round(Math.random() * 1000000000);
        }
    }
}

Код модели Model.DataDummy 

package Model
{
    import mx.collections.ArrayCollection;

    public class DataDummy
    {
        private static var _dummies:ArrayCollection;
        public static function get Dummies():ArrayCollection
        {
            if ( _dummies == null )
            {
                _dummies = new ArrayCollection();
                _dummies.addItem(new MyDummy());
                _dummies.addItem(new MyDummy());
            }

            return _dummies;
        }
    }
}

Поведение выглядит следующим образом:

  • Когда я нажимаю на buttonChange1, _resetMyProperty вызывается для экземпляра myDummy.

    В результате текст метки "labelRaw" изменился, а текст метки "labelFormatted" не изменился . Это происходит потому, что MyPropertyFormatted является свойством только для чтения, а свойства только для чтения связываются только при инициализации приложения, а не после, согласно документации Flex. С этим я согласен.


  • Когда я нажимаю на buttonChange2, метод resetMyProperty вызывается для каждого элемента MyDummy в ArrayCollection Model.DataDummy.Dummies (это статическое свойство привязано к DataGrid).

    В результате значения в обоих столбцах DataGrid изменились , несмотря на то, что второй столбец DataGrid связан с тем же свойством только для чтения MyPropertyFormatted объектов MyDummy. Я нахожу это несовместимым с предыдущим поведением, которое я описал.

Моя точка зрения такова:
1. С одной стороны, поскольку я привязываю свои элементы управления к одному экземпляру определенного объекта, привязка не сработает для его свойств только для чтения.
2. С другой стороны, когда я привязываю элемент управления к коллекции тех же самых определенных объектов, привязка будет срабатывать для каждого свойства (только для чтения или нет).

Если я хочу, чтобы привязка была запущена для свойств только для чтения в пункте 1, я должен отправить событие и указать в метатеге свойств только для чтения, что их привязка будет запущена в соответствии с этим событием (как показано в комментариях в коде класс Model.MyDummy).

Почему это поведение отличается? Я хотел бы точно понять, что делает привязка экземпляра ArrayCollection, а не привязка отдельного экземпляра.

Спасибо за вашу помощь.

1 Ответ

2 голосов
/ 04 мая 2011

Полагаю, правильный код выглядит примерно так:

Во-первых, наш model.MyDummy класс: 

package model
{
import flash.events.EventDispatcher;

import mx.events.PropertyChangeEvent;
import mx.formatters.NumberFormatter;
import mx.utils.StringUtil;

public class MyDummy extends EventDispatcher
{

    //------------------------------------------------------------------------------
    //
    //   Constructor 
    //
    //------------------------------------------------------------------------------

    public function MyDummy()
    {
        resetMyProperty();
    }

    //------------------------------------------------------------------------------
    //
    //   Properties 
    //
    //------------------------------------------------------------------------------

    //--------------------------------------
    // myProperty 
    //--------------------------------------

    private var _myProperty:Number;

    [Bindable(event="propertyChange")]
    public function get myProperty():Number
    {
        return _myProperty;
    }

    public function set myProperty(value:Number):void
    {
        if (_myProperty == value)
            return;
        var oldPropertyValue:Number = _myProperty;
        var oldFormatted:String = myPropertyFormatted;
        _myProperty = value;
        dispatchEvent(PropertyChangeEvent.createUpdateEvent(this, "myProperty", oldPropertyValue, value));
        dispatchEvent(PropertyChangeEvent.
            createUpdateEvent(this, "myPropertyFormatted", oldFormatted, myPropertyFormatted));
    }

    [Bindable(event="propertyChange")]
    public function get myPropertyFormatted():String
    {
        var idFormatted:String = "";

        if (!isNaN(myProperty))
        {
            var formatter:NumberFormatter = new NumberFormatter();
            formatter.precision = 2;
            idFormatted = formatter.format(myProperty);
        }
        else
            idFormatted = myProperty.toString();

        return StringUtil.substitute("{0} (My property has been formatted)", idFormatted);
    }

    //------------------------------------------------------------------------------
    //
    //   Methods 
    //
    //------------------------------------------------------------------------------

    public function resetMyProperty():void
    {
        myProperty = Math.round(Math.random() * 1000000000);
    }
}
}

Мы запускаем событие propertyChange, чтобы иметь возможность запуститьcollectionChangeEvent из нашего ArrayCollection (он автоматически прослушивает propertyChange событие).

Тогда наш model.DataDummy класс: 

package model
{
import mx.collections.ArrayCollection;
import mx.events.CollectionEvent;

public class DataDummy
{

    //------------------------------------------------------------------------------
    //
    //   Constructor 
    //
    //------------------------------------------------------------------------------

    public function DataDummy()
    {
        dummies = new ArrayCollection();
        dummies.addItem(new MyDummy());
        dummies.addItem(new MyDummy());
    }

    //------------------------------------------------------------------------------
    //
    //   Variables 
    //
    //------------------------------------------------------------------------------

    [Bindable]
    public var dummies:ArrayCollection;
}
}

Мы не используем статику, чтобы иметь преимуществопривязка данных с [Bindable] метатегом.

И, наконец, наш основной класс с минимальными изменениями: 

<mx:Application horizontalAlign="center" layout="vertical" xmlns:model="model.*" xmlns:mx="http://www.adobe.com/2006/mxml">
    <mx:Script>
    <![CDATA[
        //------------------------------------------------------------------------------
        //
        //   Event Handlers 
        //
        //------------------------------------------------------------------------------

        protected function buttonChange2_clickHandler(event:MouseEvent):void
        {
            for each (var d:MyDummy in dataProvider.dummies)
            {
                d.resetMyProperty();
            }
        }
    ]]>
    </mx:Script>
    <mx:HBox horizontalGap="30" width="100%">
        <mx:Button click="myDummy.resetMyProperty();" id="buttonChange1" label="Change property value" />
        <mx:Label id="labelRaw" opaqueBackground="#DDDDDD" text="{'My Property=' + myDummy.myProperty}" />
        <mx:Label id="labelFormatted" opaqueBackground="#DDDDDD"
            text="{'My Property formatted=' + myDummy.myPropertyFormatted}" />
    </mx:HBox>

    <model:MyDummy id="myDummy" />
    <model:DataDummy id="dataProvider" />

    <mx:DataGrid dataProvider="{dataProvider.dummies}" id="dataGrid" width="100%">
        <mx:columns>
            <mx:DataGridColumn dataField="myProperty" headerText="My property" />
            <mx:DataGridColumn dataField="myPropertyFormatted" headerText="My property Formatted" />
        </mx:columns>
    </mx:DataGrid>
    <mx:Button click="buttonChange2_clickHandler(event)" id="buttonChange2" label="Change property value in DataGrid" />
</mx:Application>

Как видите, все привязки работают как положено.

PS[Bindable(event="propertyChange")] является эквивалентом простого [Bindable], но таким образом вы можете избежать предупреждений компилятора на myPropertyFormatted getter.На самом деле, использование простой формы [Bindable] заставляет компилятор mxmlc самостоятельно генерировать код dispatchEvent.И вы можете использовать указание определенного события в теге [Bindable], чтобы иметь больше контроля.Например, в нашем случае мы можем запустить событие для myPropertyFormatted.

PPS. Я изменил ваши C # -подобные соглашения об именах, чтобы они отражали действующие ActionScript / MXML.

...