Ответ на этот вопрос уже принят, но до этого я работал над классом, который бы облегчил получение конкретного BitmapFilter, ну, в любом случае, я опубликую свой ответ.
Filters.as:
package filters
{
import flash.display.DisplayObject;
import flash.filters.BevelFilter
import flash.filters.BitmapFilter;
import flash.filters.BlurFilter
import flash.filters.ColorMatrixFilter
import flash.filters.ConvolutionFilter
import flash.filters.DisplacementMapFilter
import flash.filters.DropShadowFilter
import flash.filters.GlowFilter
import flash.filters.GradientBevelFilter
import flash.filters.GradientGlowFilter
public class Filters
{
public static var throwsError:Boolean;
public static function getBevelFilter(displayObject:DisplayObject):BevelFilter
{
return BevelFilter(getBitmapFilter(displayObject, BevelFilter));
}// end function
public static function getBlurFilter(displayObject:DisplayObject):BlurFilter
{
return BlurFilter(getBitmapFilter(displayObject, BlurFilter));
}// end function
public static function getColorMatrixFilter(displayObject:DisplayObject):ColorMatrixFilter
{
return ColorMatrixFilter(getBitmapFilter(displayObject, ColorMatrixFilter));
}// end function
public static function getConvolutionFilter(displayObject:DisplayObject):ConvolutionFilter
{
return ConvolutionFilter(getBitmapFilter(displayObject, ConvolutionFilter));
}// end function
public static function getDisplacementMapFilter(displayObject:DisplayObject):DisplacementMapFilter
{
return DisplacementMapFilter(getBitmapFilter(displayObject, DisplacementMapFilter));
}// end function
public static function getDropShadowFilter(displayObject:DisplayObject):DropShadowFilter
{
return DropShadowFilter(getBitmapFilter(displayObject, DropShadowFilter));
}// end function
public static function getGlowFilter(displayObject:DisplayObject):GlowFilter
{
return GlowFilter(getBitmapFilter(displayObject, GlowFilter));
}// end function
public static function getGradientBevelFilter(displayObject:DisplayObject):GradientBevelFilter
{
return GradientBevelFilter(getBitmapFilter(displayObject, GradientBevelFilter));
}// end function
public static function getGradientGlowFilter(displayObject:DisplayObject):GradientGlowFilter
{
return GradientGlowFilter(getBitmapFilter(displayObject, GradientGlowFilter));
}// end function
public static function updateFilters(displayObject:DisplayObject, ...bitmapFilters:Array):void
{
for (var i:uint = 0; i < bitmapFilters.length; i++)
{
if (!(bitmapFilters[i] is BitmapFilter))
{
throw new ArgumentError("bitmapFilters argument must be of type BitmapFilter");
}// end if
}// end for
var filterArray:Array = new Array();
for each(var bitmapFilter:BitmapFilter in displayObject.filters)
{
filterArray.push(bitmapFilter);
}// end for
for (var j:uint = 0; j < filterArray.length; j++)
{
for (var k:uint = 0; k < bitmapFilters.length; k++)
{
if (filterArray[j] is Class(Object(bitmapFilters[k]).constructor))
{
filterArray[j] = bitmapFilters[k];
}
else
{
if (throwsError) throw new Error("One or more bitmapFilters arguments did not exist in the display object's filters array");
}// end else
}// end for
}// end for
displayObject.filters = filterArray;
private static function getBitmapFilter(displayObject:DisplayObject, BitmapFilterClass:Class):BitmapFilter
{
var bitmapFilter:BitmapFilter;
for each(var bf:BitmapFilter in displayObject.filters)
{
if (bf is BitmapFilterClass)
{
bitmapFilter = bf;
break;
}// end if
}// end for
if (!bitmapFilter && throwsError)
throw new Error("Could not find BitmapFilter");
return bitmapFilter;
}// end function
}// end class
}// end package
Main.as:
package
{
import filters.Filters;
import flash.display.Sprite;
import flash.events.Event;
import flash.filters.GlowFilter;
public class Main extends Sprite
{
public function Main():void
{
if (stage) init();
else addEventListener(Event.ADDED_TO_STAGE, init);
}// end function
private function init(e:Event = null):void
{
removeEventListener(Event.ADDED_TO_STAGE, init);
var sprite:Sprite = new Sprite();
sprite.graphics.beginFill(0xFF0000);
sprite.graphics.drawCircle(0, 0, 100);
sprite.graphics.endFill();
sprite.filters = [new GlowFilter()];
sprite.x = stage.stageWidth / 2;
sprite.y = stage.stageHeight / 2;
addChild(sprite);
var spriteGlowFilter:GlowFilter = Filters.getGlowFilter(sprite);
spriteGlowFilter.blurX = 10;
spriteGlowFilter.blurY = 10;
sprite.filters = [spriteGlowFilter];
}// end function
}// end class
}//end package
[UPDATE]
Это обновление является ответом на первый комментарий Хуана Пабло Калифано. Проблема с «изменением последней строки на return new BitmapFilterClass();» заключается в том, что он возвращает новый экземпляр BitmapFilter, когда нам нужно вернуть ссылку на экземпляр BitmapFilter, который уже находится в filters экранного объекта массив свойств.
Например, мы создаем объект Sprite и добавляем новый экземпляр GlowFilter в его свойство filters, устанавливая аргумент цвета в 0xFFFF00 (желтый):
var sprite:Sprite = new Sprite();
sprite.graphics.beginFill(0xFF0000);
sprite.graphics.drawCircle(0, 0, 100);
sprite.graphics.endFill();
sprite.filters = [new GlowFilter(0xFFFF00)];
sprite.x = stage.stageWidth / 2;
sprite.y = stage.stageHeight / 2;
addChild(sprite);
Теперь, когда мы отслеживаем свойство color возвращенного объекта GlowFilter, используя открытый статический метод getGlowFilter, мы получаем следующее:
trace(Filters.getGlowFilter(sprite).color); // output: 16776960(0xFFFF00, yellow);
Однако, если мы изменим код, как предложено, мы получим следующее:
trace(Filters.getGlowFilter(sprite).color); // output: 16711680(0xFF0000, red);
Теперь более простой способ избежать получения ошибки при доступе к нулевому значению - использовать условное выражение:
if (Filters.getGlowFilter(sprite) != null)
{
var spriteGlowFilter:GlowFilter = Filters.getGlowFilter(sprite);
spriteGlowFilter.blurX = 10;
spriteGlowFilter.blurY = 10;
sprite.filters = [spriteGlowFilter];
}// end if
[ОБНОВЛЕНИЕ 2]
Я обновил класс Filters, чтобы включить в него простую функцию обработки ошибок, которая выдает ошибку, если BitmapFilter не может быть найден при использовании открытого статического метода, такого как getBevelFilter(). Эту функцию можно включать и выключать, устанавливая соответствующее истинное или ложное логическое значение для открытого статического свойства throwsError.
var sprite:Sprite = new Sprite();
sprite.graphics.beginFill(0xFF0000);
sprite.graphics.drawCircle(0, 0, 100);
sprite.graphics.endFill();
sprite.filters = [new GlowFilter(0xFFFF00)];
sprite.x = stage.stageWidth / 2;
sprite.y = stage.stageHeight / 2;
addChild(sprite);
Filters.throwsError = true;
Filters.getDropShadowFilter(sprite); // error: Could not find BitmapFilter
[ОБНОВЛЕНИЕ 3]
В ответ на второй комментарий Хуана Пабло Калифано я добавил публичный статический метод updateFilters(), который довольно понятен, поэтому я просто покажу пример его использования:
var sprite:Sprite = new Sprite();
sprite.graphics.beginFill(0xFF0000);
sprite.graphics.drawCircle(0, 0, 100);
sprite.graphics.endFill();
sprite.filters = [new GlowFilter()];
sprite.x = stage.stageWidth / 2;
sprite.y = stage.stageHeight / 2;
addChild(sprite);
Filters.throwsError = true;
var glowFilter:GlowFilter = Filters.getGlowFilter(sprite);
glowFilter.blurX = glowFilter.blurY += 10;
Filters.updateFilters(sprite, glowFilter);