Требуется XSLT-преобразование для преобразования входного XML в выходной XML

Question

HI

Я хочу преобразовать входной XML в OUTput XML с помощью XSLT.

Входной XML как показано ниже

<ALLFields id="0001">
  <field name="ComputerName">ABC</field>
  <field name="ComputerType">Windows</field>
  <field name="DatabaseName" />
  <field name="CPULevel">10</field>
</ALLFields>

OUTPUT XML, что мне нужно, это

<entry id="0001">
<ComputerName>ABC</ComputerName>
<ComputerType>Windows</ComputerType>
<DatabaseName />
<CPULevel>10</CPULevel>
</entry>

Answer 1

Это преобразование :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="ALLFields">
     <entry id="{@id}">
       <xsl:apply-templates select="node()"/>
     </entry>
 </xsl:template>

 <xsl:template match="field">
  <xsl:element name="{@name}">
   <xsl:apply-templates/>
  </xsl:element>
 </xsl:template>
</xsl:stylesheet>

при применении к предоставленному документу XML (исправлено, чтобы быть правильно сформированным):

<ALLFields id="0001">
    <field name="ComputerName">ABC</field>
    <field name="ComputerType">Windows</field>
    <field name="DatabaseName" />
    <field name="CPULevel">10</field>
</ALLFields>

дает желаемый, правильный результат:

<entry id="0001">
   <ComputerName>ABC</ComputerName>
   <ComputerType>Windows</ComputerType>
   <DatabaseName/>
   <CPULevel>10</CPULevel>
</entry>

Answer 2

<xsl:template match="AllFields">
    <entry id="{@id}">
        <xsl:for-each select="field">
            <xsl:element name="{@name}">
                <xsl:value-of select="text()"/>
            </xsl:element>
        </xsl:for-each>
    </entry>
</xsl:template>

Не проверено.