Анимировать список на графике в Mathematica? - PullRequest
1 голос
/ 21 июля 2011

У меня есть матрица координат (X, Y), и я хочу анимировать их, рисуя точки за точкой и соединяя точки.Я пробовал «ListAnimate», но он только анимирует значения каждой координаты.

Вот как выглядит пример:

{{1,1},
{1,2},
{5,4},...}

Ответы [ 2 ]

4 голосов
/ 21 июля 2011

Может быть

max = 10;
coords = Table[{i, RandomReal[]}, {i, max}];

Animate[ListPlot[coords[[1 ;; n]], PlotMarkers -> {Automatic, Small}, 
  Joined -> True, PlotRange -> {{0, max}, {0, 1}}], {n, 1, max, 1}]
1 голос
/ 22 июля 2011

Просто иллюстративный ответ. Все следующее также делает то же самое:


max = 10;
coords = Table[{i, RandomReal[]}, {i, max}];
p = PlotRange -> {{0, max}, {0, 1}};


Animate[
 ListLinePlot[coords[[1 ;; n]],   Mesh -> All, p],
{n, Range@max}]

Animate[
  Graphics[{Point@#, Line@#}, p, Axes -> True] &@coords[[1 ;; n]], 
{n, Range@max}]

Animate[
 Graphics[{ Red,   Point[#], 
            Black, BSplineCurve[#, SplineDegree -> 1]}, p] &@coords[[1 ;; n]],
{n, Range@max}]
Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.
...