Определение инкрементной переменной

Question

Я хочу автоматически определить увеличивающиеся имена переменных.

Итак, вместо этого:

$Var1 = 'This is variable one :P'
$Var2 = 'This is variable two :P'

Мне бы хотелось (псевдокод):

For $i = 1 to UBound($People)-1     
    **$var[$i]** = GUICtrlCreateCheckbox($var[$i], 24, $y, 200, 17) 
    $y = $y + 25 
Next

Кто-нибудь знает как?

В коде должно быть столько флажков, сколько определено в массиве, и каждый флажок должен иметь свою собственную переменную.

Answer 1

Вы ищете функцию Assign!

Проверьте этот пример:

For $i = 1 To 5
    Assign('var' & $i, $i);
Next

Затем вы можете получить доступ к этим переменным с помощью:

MsgBox(4096, "My dynamic variables", $var1)
MsgBox(4096, "My dynamic variables", $var3)
MsgBox(4096, "My dynamic variables", $var5)

Очевидно, var2 и var3 также могут быть использованы:)

Редактировать: Для ясности, что бы вы делали, если бы вы сделали это правильно, хранили этизначения в массиве - это лучший метод для такого рода вещей.

Answer 2

поэтому вместо этого:

$Var1 = 'This is variable one :P'
$Var2 = 'This is variable two :P'

Мне бы хотелось (псевдокод):

For $i = 1 to UBound($People)-1   
    **$var[$i]** = GUICtrlCreateCheckbox($var[$i], 24, $y, 200, 17) 
    $y = $y + 25 
Next

Кто-нибудь знает, как это можно сделать?

Согласно Документация - Вступление - Массивы :

Массив - это переменная, содержащая серию элементов данных.Каждый элемент в этой переменной может быть доступен по номеру индекса, который относится к положению элемента в массиве - в AutoIt первым элементом массива всегда является элемент [0].Элементы массивов хранятся в определенном порядке и могут быть отсортированы.

Пример создания динамического флажка, присвоение нескольких идентификаторов checkbox-control одному массиву (не проверено, проверка ошибок отсутствует)):

#include <GUIConstantsEx.au3>

Global Const $g_iBoxStartX = 25
Global Const $g_iBoxStartY = 25
Global Const $g_iBoxWidth  = 100
Global Const $g_iBoxHeight = 15
Global Const $g_iBoxSpace  = 0
Global Const $g_iBoxAmount = Random(2, 20, 1)
Global Const $g_iBoxTextEx = $g_iBoxAmount -1
Global Const $g_sBoxTextEx = 'Your text here.'

Global Const $g_iWindDelay = 50
Global Const $g_iWinWidth  = $g_iBoxWidth * 2
Global Const $g_iWinHeight = ($g_iBoxStartY * 2) + ($g_iBoxHeight * $g_iBoxAmount) + ($g_iBoxSpace * $g_iBoxAmount)
Global Const $g_sWinTitle  = 'Example'

Global       $g_hGUI
Global       $g_aID

Main()

Func Main()

    $g_hGUI = GUICreate($g_sWinTitle, $g_iWinWidth, $g_iWinHeight)
    $g_aID  = GUICtrlCreateCheckboxMulti($g_iBoxStartX, $g_iBoxStartY, $g_iBoxWidth, $g_iBoxHeight, $g_iBoxSpace, $g_iBoxAmount)

    GUICtrlSetData($g_aID[$g_iBoxTextEx], $g_sBoxTextEx)
    GUISetState(@SW_SHOW, $g_hGUI)

    While Not (GUIGetMsg() = $GUI_EVENT_CLOSE)

        Sleep($g_iWindDelay)

    WEnd

    Exit
EndFunc

Func GUICtrlCreateCheckboxMulti(Const $iStartX, Const $iStartY, Const $iWidth, Const $iHeight, Const $iSpace, Const $iAmount, Const $sTextTpl = 'Checkbox #%s')
    Local $iYPosCur = 0
    Local $sTextCur = ''
    Local $aID[$iAmount]

    For $i1 = 0 To $iAmount -1

        $iYPosCur = $iStartY + ($iHeight * $i1) + ($iSpace * $i1)
        $sTextCur = StringFormat($sTextTpl, $i1 +1)
        $aID[$i1] = GUICtrlCreateCheckbox($sTextCur, $iStartX, $iYPosCur, $iWidth, $iHeight)

    Next

    Return $aID
EndFunc

• GUICtrlCreateCheckboxMulti() демонстрирует
  • объявление массива ($aID[$iAmount])
  • назначение элементов массива в For...To...Step...Next -loop ($aID[$i1] = ...).
• Main() демонстрирует выбор отдельного элемента (изменение его текста с помощью GUICtrlSetData()).
• Отрегулируйте константы по мере необходимости ($g_iBoxAmount и т. Д.).