XSLT для каждой буквы в строке

Question

Я пишу XSLT-преобразование (для XSL-FO), и мне нужно что-то повторять для каждой буквы в строковом значении, например:

Если строка хранится в MyData/MyValue строке (например,MyData.MyValue = "что-то"), мне нужно для каждого, как этот:

<xsl:for-each select="MyData/MyValue"> <!-- What goes here to iterate through letters? -->
  <someTags>
    <xsl:value-of select="Letter" /> <!-- What goes here to output current letter? -->
  </someTags>
</xsl:for-each>

Есть идеи?

Answer 1

вы можете использовать шаблон вызова и передать параметры, а затем использовать рекурсию для вызова шаблона, пока не останется символов.

пример добавлен ниже.

в этом xml

<?xml version="1.0" encoding="utf-8"?>
<data>
        <node>something</node>
</data>

и этот xslt

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
>
    <xsl:output method="xml" indent="yes"/>

    <xsl:template match="data/node">
            <xsl:call-template name="for-each-character">                    
                    <xsl:with-param name="data" select="."/>
            </xsl:call-template>
    </xsl:template>

        <xsl:template name="for-each-character">                
                <xsl:param name="data"/>
                <xsl:if test="string-length($data) &gt; 0">
                        <someTags>                            
                                <xsl:value-of select="substring($data,1,1)"/>
                        </someTags>
                        <xsl:call-template name="for-each-character">
                                <xsl:with-param name="data" select="substring($data,2)"/>
                        </xsl:call-template>
                </xsl:if>
        </xsl:template>
</xsl:stylesheet>

тогда вы сможете манипулировать в операторе if, чтобы выполнять дальнейшие действия!

Answer 2

Вы можете попробовать этот безобразный хак, который доказал свою эффективность снова и снова:

<xsl:for-each select="//*[position() &lt;= string-length(MyData/MyValue)]">
  <someTags>
    <xsl:value-of select="substring(MyData/MyValue, position(), 1)"/>
  </someTags>
</xsl:for-each>

Это будет работать, если //* соответствует большему количеству узлов, чем количество символов в вашей строке ... Конечно, это также заслуживает нечетной строки комментария для бедняги, читающего ваш код впоследствии ... ;-)

Примечание : Я знаю, что есть пуристы XSLT. Но когда вам нужно выполнить работу и не беспокоиться о гипербодальности XSLT, то иногда эти трюки просто потрясающие! IMO

Также обратите внимание : я поднял здесь вопрос производительности, чтобы узнать, насколько лучше работает итерация или рекурсия: производительность итерации или рекурсии XSLT

Answer 3

Я не уверен в целесообразности итерации.Вы можете использовать рекурсию, как показано в других ответах.Это мое предложение (мало чем отличающееся от других, за исключением того, что я использую шаблоны соответствия шаблонов, а не именованные шаблоны):

    <xsl:template match="MyData/MyValue">
        <xsl:param name="sub" select="."/>
        <xsl:variable name="subsub" select="substring($sub,1,1)"/>
        <xsl:if test="boolean($subsub)"> 
            <someTags>
                <xsl:value-of select="$subsub"/>
            </someTags>
            <xsl:apply-templates select="self::node()">
                <xsl:with-param name="sub" select="substring($sub,2)"/>
            </xsl:apply-templates>
        </xsl:if>
    </xsl:template>

Answer 4

Хороший вопрос, + 1.

Вот что шаблон / функция str-map из FXSL предназначена для :

<xsl:stylesheet version="1.0" 
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:f="http://fxsl.sf.net/" xmlns:testmap="testmap"
 exclude-result-prefixes="xsl f testmap">
   <xsl:import href="str-dvc-map.xsl"/>

   <!-- to be applied on any xml source -->

   <testmap:testmap/>

   <xsl:output method="text"/>

   <xsl:template match="/">
     <xsl:variable name="vFunTripple" select="document('')/*/testmap:*[1]"/>

     <xsl:call-template name="str-map">
       <xsl:with-param name="pFun" select="$vFunTripple"/>
       <xsl:with-param name="pStr" select="'something'"/>
     </xsl:call-template>
   </xsl:template>

    <xsl:template name="trippleChar" match="testmap:*" mode="f:FXSL">
      <xsl:param name="arg1"/>

      <xsl:value-of select="concat($arg1,$arg1,$arg1)"/>
    </xsl:template>
</xsl:stylesheet>

когда это преобразование применяется к любому документу XML (не используется), получается желаемый результат :

sssooommmeeettthhhiiinnnggg

Answer 5

Вы можете использовать рекурсию:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
    <xsl:output method="xml" indent="yes"/>


    <xsl:template match="/">

        <xsl:call-template name="get-letters">
            <xsl:with-param name="input">something</xsl:with-param>
        </xsl:call-template>

    </xsl:template>

    <xsl:template name="get-letters">
        <xsl:param name="input"/>
        <xsl:if test="string-length($input)">
            <xsl:value-of select="substring($input, 1, 1)"/>
            <xsl:text>&#xA0;</xsl:text>
            <xsl:call-template name="get-letters">
                <xsl:with-param name="input" select="substring($input, 2)"/>
            </xsl:call-template>
        </xsl:if>


    </xsl:template>
</xsl:stylesheet>

Вывод: s o m e t h i n g

Answer 6

Было опубликовано несколько решений XSLT 1.0 (поскольку это было то, что нужно оригинальному постеру). Для сравнения, вот как это можно сделать в XSLT 2.0, используя xsl: analysis-string :

<xsl:analyze-string select="MyData/MyValue" regex="."> 
  <xsl:matching-substring>
    <someTags>
      <xsl:value-of select="."/> 
    </someTags>
  </xsl:matching-substring>
</xsl:analyze-string>