Как вызвать метод веб-службы .Net из классического ASP с использованием SOAP - PullRequest
Новая
       17

Как вызвать метод веб-службы .Net из классического ASP с использованием SOAP

6 голосов
/ 21 июля 2011

Я пытаюсь вызвать .Net Web Service из Classic ASP, используя SOAP.Я построил следующий код в качестве теста и продолжаю возвращать пустой ответный файл с ошибкой 400 Bad Request.Я что-то не так делаю или проблема может быть на стороне .Net? 

'set up xmlhttp to checkout server
Dim oRequest
Set oRequest = Server.CreateObject("MSXML2.ServerXMLHTTP")

'setting this option will allow ServerXMLHTTP to ignore the certificate errors it encounters.
oRequest.setOption(2) = SXH_SERVER_CERT_IGNORE_ALL_SERVER_ERRORS


' resolve, connect, send, receive - in milliseconds
oRequest.setTimeouts 10000, 10000, 10000, 10000

'set the URL
msURL = "[redacted]"

msSOAP = "<?xml version=""1.0"" encoding=""utf-8"" ?>"
msSOAP = msSOAP & "<soap12:Envelope xmlns:xsi=""http://www.w3.org/2001/XMLSchema-instance"" xmlns:xsd=""http://www.w3.org/2001/XMLSchema"" xmlns:soap12=""http://www.w3.org/2003/05/soap-envelope"">"
msSOAP = msSOAP & "<SOAP:Body>"
msSOAP = msSOAP & "<[Some Service] xmlns=""http://localhost"">"
msSOAP = msSOAP & "<MethodName>"
msSOAP = msSOAP & "<methodParam1>[some value]</methodParam1>"
msSOAP = msSOAP & "<methodParam2>[some value]</methodParam2>"
msSOAP = msSOAP & "<methodParam3>[some value]</methodParam3>"
msSOAP = msSOAP & "</MethodName>"
msSOAP = msSOAP & "</[Some Service]>"
msSOAP = msSOAP & "</SOAP:Body>"
msSOAP = msSOAP & "</soap12:Envelope>"

oRequest.Open "POST", msURL, False
oRequest.setRequestHeader "Content-Type", "text/xml"
oRequest.setRequestHeader "SOAPMethodName", "[MethodName]"
oRequest.setRequestHeader "SOAPAction", "[Some Url]"
oRequest.send msSOAP

Response.Write oRequest.ResponseBody

1 Ответ

2 голосов
/ 22 июля 2011

Следующее решение было ответом на мою проблему. И Филбурт, как только я действительно сделал хороший SOAP-вызов, я обнаружил, что ваш вопрос был в высшей степени законным. Тип и формат имеют большое значение! 

'set up xmlhttp to checkout server
Dim oRequest
Set oRequest = Server.CreateObject("MSXML2.ServerXMLHTTP")

'setting this option will allow ServerXMLHTTP to ignore the certificate errors it encounters.
oRequest.setOption(2) = SXH_SERVER_CERT_IGNORE_ALL_SERVER_ERRORS

' resolve, connect, send, receive - in milliseconds
oRequest.setTimeouts 10000, 10000, 10000, 10000

'set the URL
msURL = "[Service Url]"

msSOAP = "<?xml version=""1.0"" encoding=""utf-8"" ?>"
msSOAP = msSOAP & "<s:Envelope xmlns:s=""http://schemas.xmlsoap.org/soap/envelope/"">"
msSOAP = msSOAP & "<s:Body>"
msSOAP = msSOAP & "<[MethodName] xmlns=""[Some Namespace]"">"
msSOAP = msSOAP & "<methodParam1>[Some value]</methodParam1>"
 msSOAP = msSOAP & "<methodParam2>[Some value]</methodParam2>"
 msSOAP = msSOAP & "<methodParam3>[Some value]</methodParam3>"
   msSOAP = msSOAP & "</MethodName>"
msSOAP = msSOAP & "</s:Body>"
msSOAP = msSOAP & "</s:Envelope>"

oRequest.Open "POST", msURL, False
oRequest.setRequestHeader "Content-Type", "text/xml"
oRequest.setRequestHeader "SOAPAction", "[Some Url]"
oRequest.send msSOAP

Я снял «? Wsdl» с URL, немного изменил конверт, и теперь он работает. Я также удалил настройку заголовка SoapMethodName.

...