XSLT накапливать - PullRequest
Новая
       13

XSLT накапливать

2 голосов
/ 31 мая 2011

У меня есть родительская переменная и две дочерние переменные для накопления

Я хотел бы использовать эти две дочерние переменные для выбора двух разных значений

Я могу только жестко закодировать его, чтобы он работал, как и все другие уроки например: $ parent [1] / цена и $ parent [1] / количество

но вместо этого я хочу следующее: 

$parent[1]/$child1 where $parent[1] = orders[1]/order and $child1 = price
$parent[1]/$child2 where $parent[1] = orders[1]/order and $child2 = quantity

    <xsl:call-template name="total">
    <xsl:with-param name="pList" select="$parent"/>
    <xsl:with-param name="price" select="Price"/>
    <xsl:with-param name="quantity" select="Quantity"/>   
    </xsl:call-template>

<xsl:template name="total">
    <xsl:param name="pListItem"/>
    <xsl:param name="pAccum" select="0"/>
    <xsl:param name="price"/>
    <xsl:param name="quantity"/>

    <xsl:choose>
      <xsl:when test="$pListItem">
        <xsl:call-template name="total">
          <xsl:with-param name="pListItem" select="$pListItem[position() > 1]"/>
          <xsl:with-param name="pAccum"
           select="$pAccum + $vHead/$price * $vHead/$quantity"/>
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$pAccum"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

Ответы [ 2 ]

2 голосов
/ 31 мая 2011

Не совсем понятно, в чем вопрос, но я думаю, что это так.

Это преобразование : 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pPriceName" select="'price2'"/>
 <xsl:param name="pQuantityName" select="'quantity1'"/>


 <xsl:template match="/">
  <xsl:call-template name="totalSales">
   <xsl:with-param name="pSales" select="/*/*"/>
   <xsl:with-param name="pPriceName" select="$pPriceName"/>
   <xsl:with-param name="pQuantityName"
        select="$pQuantityName"/>
  </xsl:call-template>
 </xsl:template>

 <xsl:template name="totalSales">
  <xsl:param name="pAccum" select="0"/>
  <xsl:param name="pSales"/>
  <xsl:param name="pPriceName"/>
  <xsl:param name="pQuantityName"/>

  <xsl:variable name="vthisSale" select="$pSales[1]"/>

  <xsl:choose>
   <xsl:when test="not($vthisSale)">
    <xsl:value-of select="$pAccum"/>
   </xsl:when>
   <xsl:otherwise>
    <xsl:call-template name="totalSales">
     <xsl:with-param name="pAccum" select=
     "$pAccum
     +
       $vthisSale/*[name()=$pPriceName]
      *
       $vthisSale/*[name()=$pQuantityName]
      "/>
      <xsl:with-param name="pSales" select=
       "$pSales[position() >1]"/>
      <xsl:with-param name="pPriceName"
           select="$pPriceName"/>
      <xsl:with-param name="pQuantityName"
           select="$pQuantityName"/>
    </xsl:call-template>
   </xsl:otherwise>
  </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

при применении к следующему документу XML (вы могли бы по крайней мере предоставить это!): 

<orders>
 <order>
  <price1>10</price1>
  <quantity1>3</quantity1>
  <price2>15</price2>
  <quantity2>1</quantity2>
 </order>
 <order>
  <price1>11</price1>
  <quantity1>2</quantity1>
  <price2>9</price2>
  <quantity2>3</quantity2>
 </order>
</orders>

дает желаемый, правильный результат: 

63

Примечание. : значения имен дочерних элементов, служащих ценой и количеством, предоставляются в качестве внешних параметров преобразования и могут быть известны только во время выполнения.

0 голосов
/ 02 июня 2011

Большое спасибо.
Все, что мне нужно, это 'Price' и $vthisSale/*[name()=$pPriceName]

Это действительно помогает !! Я застрял целую вечность из-за магии ''

...