Я хотел бы реализовать `функцию разделения / шаблон`, которая принимает в качестве входных данных строку и разделитель и возвращает массив разделения строки

Question

Я хотел бы реализовать split function/template в XSLT, который принимает в качестве входных данных строку и разделитель и возвращает разделенный массив строки ..

Вернее, я бы хотел иметь возможность делать что-то вроде:

<xsl:call-template name="F">
    <xsl:with-param name="input" select="'a,b,c,d,e'"/>
    <xsl:with-param name="replacement">
    <option value='$x'>$x</option>
</xsl:with-param>
</xsl:call-template>

, который даст мне

<option value='a'>a</option><option value='b'>b</option><option value='c'>c</option><option value='d'>d</option><option value='e'>e</option>

Вопрос нацелен на XSLT 1.0 (но я не против узнать, как это делает XSLT 2.0)

Answer 1

I.Решение XSLT 2.0

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
  <xsl:variable name="vStr" select="'a,b,c,d,e'"/>

  <xsl:for-each select="tokenize($vStr, ',')">
   <option value="{.}"><xsl:value-of select="."/></option>
  </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

когда это преобразование применяется к документу ant XML (не используется), получается требуемый, правильный результат :

<option value="a">a</option>
<option value="b">b</option>
<option value="c">c</option>
<option value="d">d</option>
<option value="e">e</option>

Пояснение : Использование стандартной функции XPath 2.0 tokenize().

II.XSLT 1.0: использование функции / шаблона FXSL 1.x str-split-to-words

Это преобразование XSLT 1.0:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common"
 exclude-result-prefixes="ext">
  <xsl:import href="strSplit-to-Words.xsl"/>
  <xsl:output indent="yes" omit-xml-declaration="yes"/>

    <xsl:template match="/">
      <xsl:variable name="vwordNodes">
        <xsl:call-template name="str-split-to-words">
          <xsl:with-param name="pStr" select="/"/>
          <xsl:with-param name="pDelimiters"
                          select="', '"/>
        </xsl:call-template>
      </xsl:variable>

      <xsl:apply-templates select=
       "ext:node-set($vwordNodes)/*"/>
    </xsl:template>

    <xsl:template match="word">
     <option value="{.}"><xsl:value-of select="."/></option>
    </xsl:template>
</xsl:stylesheet>

при применении кэтот XML-документ :

<t>a,b,c d,e</t>

дает требуемый, правильный результат :

<option value="a">a</option>
<option value="b">b</option>
<option value="c">c</option>
<option value="d">d</option>
<option value="e">e</option>

Примечание pDelimitersПараметр (как следует из его названия) может содержать более одного символа-разделителя - в этом случае мы используем ',' и ' '.

III.Решение XSLT 1.0 с использованием рукописного рекурсивного именованного шаблона :

Это преобразование:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="text()" name="tokenize">
  <xsl:param name="pText" select="."/>
  <xsl:param name="pDelim" select="','"/>

  <xsl:if test="string-length($pText) > 0">
    <xsl:variable name="vToken" select=
    "substring-before(concat($pText,','), ',')"/>

    <option value="{$vToken}">
      <xsl:value-of select="$vToken"/>
    </option>

    <xsl:call-template name="tokenize">
     <xsl:with-param name="pText" select=
      "substring-after($pText,',')"/>
    </xsl:call-template>
  </xsl:if>
 </xsl:template>
</xsl:stylesheet>

при применении к этому документу XML :

<t>a,b,c,d,e</t>

дает желаемый, правильный результат :

<option value="a">a</option>
<option value="b">b</option>
<option value="c">c</option>
<option value="d">d</option>
<option value="e">e</option>

IV.Передача шаблона tokenize в III выше в качестве параметра шаблона / функции для обработки каждого токена

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:f="http://fxsl.sf.net" exclude-result-prefixes="f">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <f:processToken/>

 <xsl:variable name="vFunc" select=
  "document('')/*/f:processToken[1]"/>

 <xsl:template match="text()" name="tokenize">
  <xsl:param name="pText" select="."/>
  <xsl:param name="pDelim" select="','"/>
  <xsl:param name="pProcessFunc" select="$vFunc"/>

  <xsl:if test="string-length($pText) > 0">
    <xsl:variable name="vToken" select=
    "substring-before(concat($pText,','), ',')"/>

    <xsl:apply-templates select="$pProcessFunc">
     <xsl:with-param name="arg1" select="$vToken"/>
    </xsl:apply-templates>

    <xsl:call-template name="tokenize">
     <xsl:with-param name="pText" select=
      "substring-after($pText,',')"/>
    </xsl:call-template>
  </xsl:if>
 </xsl:template>

 <xsl:template match="f:processToken">
  <xsl:param name="arg1"/>
    <option value="{$arg1}">
      <xsl:value-of select="$arg1"/>
    </option>
 </xsl:template>
</xsl:stylesheet>

, когда это преобразование применяется к тому же документу XML, что и в III,получается тот же, требуемый, правильный результат :

<option value="a">a</option>
<option value="b">b</option>
<option value="c">c</option>
<option value="d">d</option>
<option value="e">e</option>

Теперь, если мы заменим последний шаблон этим :

 <xsl:template match="f:processToken">
  <xsl:param name="arg1"/>
    <p>
      <xsl:value-of select="$arg1"/>
    </p>
 </xsl:template>

снова получается желаемый результат :

<p>a</p>
<p>b</p>
<p>c</p>
<p>d</p>
<p>e</p>

Answer 2

В ответе, который вы видели, пропущен только параметр разделитель :

<xsl:template name="output-tokens">
    <xsl:param name="list" />
    <xsl:param name="delimiter" />
    <xsl:variable name="newlist">
        <xsl:choose>
            <xsl:when test="contains($list, $delimiter)"><xsl:value-of select="normalize-space($list)" /></xsl:when>

            <xsl:otherwise><xsl:value-of select="concat(normalize-space($list), $delimiter)"/></xsl:otherwise>
        </xsl:choose>
    </xsl:variable>
    <xsl:variable name="first" select="substring-before($newlist, $delimiter)" />
    <xsl:variable name="remaining" select="substring-after($newlist, $delimiter)" />
    <xsl:value-of select="$first" /> <!-- token -->
    <xsl:if test="$remaining">
        <xsl:call-template name="output-tokens">
            <xsl:with-param name="list" select="$remaining" />
            <xsl:with-param name="delimiter"><xsl:value-of select="$delimiter"/></xsl:with-param>
        </xsl:call-template>
    </xsl:if>
</xsl:template>