используя xsl для вывода математического выражения - PullRequest
Новая
       8

используя xsl для вывода математического выражения

4 голосов
/ 21 мая 2011

Я хочу использовать xslt для вывода математического выражения из ввода Mathml.Там должно быть какая-то ошибка в моем преобразовании.Я не знаю, как это исправить.Не могли бы вы помочь мне?Должен ли я использовать параметр или переменную для управления им?xml: 

<?xml version="1.0" encoding="UTF-8"?>

<math>
  <apply>
    <eq/>
    <apply>
      <plus/>
      <apply>
        <power/>
        <ci>x</ci>
        <cn>2</cn>
      </apply>
      <apply>
        <times/>
        <cn>2</cn>
        <ci>x</ci>
      </apply>
      <cn>2</cn>
    </apply>
    <cn>0</cn>
  </apply>
</math>

Это мой xsl: 

  <xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

   <xsl:output method="text" encoding="UTF-8"/>

    <xsl:template match="/">
     <xsl:apply-templates/>
     <xsl:text>&#10;</xsl:text>
    </xsl:template>

    <xsl:template match="math">
            <xsl:apply-templates select="apply"/>
    </xsl:template>

    <xsl:template match="apply">

        <xsl:sequence select="name(element()[1]),'('"/>
        <xsl:apply-templates select="apply">
        </xsl:apply-templates>
        <xsl:sequence select="element()[2],','"/>
        <xsl:sequence select="element()[3],')',','"/>

   </xsl:template>

</xsl:stylesheet>

Результат должен быть: 

   eq(plus(power(x,2),times(2,x),2),0)

Ответы [ 2 ]

2 голосов
/ 22 мая 2011

Это полное и короткое преобразование : 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="apply">
  <xsl:if test="not(position()=1)">,</xsl:if>
  <xsl:apply-templates select="*[1]"/>
 </xsl:template>

 <xsl:template match="eq|plus|power|times">
  <xsl:if test="not(position()=1)">,</xsl:if>
  <xsl:value-of select="concat(name(), '(')"/>
   <xsl:apply-templates select="following-sibling::*"/>
   <xsl:text>)</xsl:text>
 </xsl:template>

 <xsl:template match="cn|ci">
  <xsl:if test="not(position()=1)">,</xsl:if>
  <xsl:value-of select="."/>
 </xsl:template>
</xsl:stylesheet>

при применении к предоставленному документу XML : 

<math>
    <apply>
        <eq/>
        <apply>
            <plus/>
            <apply>
                <power/>
                <ci>x</ci>
                <cn>2</cn>
            </apply>
            <apply>
                <times/>
                <cn>2</cn>
                <ci>x</ci>
            </apply>
            <cn>2</cn>
        </apply>
        <cn>0</cn>
    </apply>
</math>

произвести желаемый, правильный результат : 

eq(plus(power(x,2),times(2,x),2),0)
2 голосов
/ 22 мая 2011

Я немного изменил исходное преобразование, чтобы получить желаемый результат.По сути, шаблонное правило apply решает парентезис функции.Чтобы определить, стоит ли вставлять запятую, я проверяю наличие следующих элементов одного типа.

Более того, я заменил ваш xsl:sequence на xsl:value-of, предотвращая тем самым создание нежелательных пробелов (я представляю себеони нежелательны).Также была заменена функция element().Таблица стилей теперь совместима с XSLT 1.0.Мне не нравится XSLT 1.0, но я предпочитаю использовать новые функции только тогда, когда это действительно необходимо.

Это решение не очень общее (MATHML - огромная спецификация, которую вы знаете), но вы можете использовать его и адаптировать к более сложным случаям.

XSLT 1.0 проверено в соответствии с Saxon 6.5.5 

  <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text" encoding="UTF-8"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="apply">
        <xsl:value-of select="concat(name(child::*[1]),'(')"/>
        <xsl:apply-templates select="apply|cn|ci"/>
        <xsl:value-of select="')'"/>
        <xsl:if test="count(following-sibling::*)">
            <xsl:value-of select="','"/>
        </xsl:if>
    </xsl:template>

    <xsl:template match="cn|ci">
        <xsl:value-of select="."/>
        <xsl:if test="count(following-sibling::*)&gt;0">
            <xsl:value-of select="','"/>
        </xsl:if>
    </xsl:template>

</xsl:stylesheet>

При применении к входу, указанному в вопросе, получается: 

eq(plus(power(x,2),times(2,x),2),0)
...