Applescript: новое окно терминала с темой про

Question

Я хочу создать скрипт, который откроет мне новое окно терминала с темой pro.как будет выглядеть этот скрипт?Мне только что удалось получить новое окно, но я хочу указать тему.

Я создал для этого службу автоматического оператора, потому что я хочу использовать ярлыки.

Мне понадобятся свойства длятема или получить информацию из нее, каким-то образом для ее восстановления.

---

Так что это прекрасно работает:

Установите режим {"Basic", "Grass", "Novel", "Ocean", "Pro", "Red Sands"} установите I в случайное число от 1 до 6

Установить тему для элемента I режима

Но как мне получить текущую тему?И выполняет ли скрипт все свои переменные после завершения или как-то сохраняет его?

Answer 1

Я написал этот appleScript, чтобы я мог легко установить тему текущего окна.Это позволяет мне установить конкретную тему, случайную из благословенного набора или случайную из всех доступных.

Я использую настройку псевдонимов в моем .bashrc, чтобы легко вызывать это из командной строки.Примеры есть в шапке.

-- StyleTerm.scpt
-- Sets theme of current terminal window/tab

-----------------------
-- Arguments
-----------------------
-- If a theme name is provided on the command line then set to that
-- Example
--   osascript StyleTerm.scpt Grass
--  
-- If multiple theme names are provided on command line then choose randomly among those
--    This allows for random behavior from within blessed set
-- Example
--   osascript StyleTerm.scpt Grass Basic Ocean "Red Sands"
--  
-- If no command line args are provided then choose randomly among all themes
-- Example
--   osascript StyleTerm.scpt
-----------------------

-----------------------
-- This is best utilized via aliases set up in shell config file
-- Examples from my .bashrc
--   # Theme specific aliases
--   alias grass='osascript ~/sbin/StyleTerm.scpt Grass'
--   alias basic='osascript ~/sbin/StyleTerm.scpt Basic'
--   # Random from blessed themes
--   alias btheme='osascript ~/sbin/StyleTerm.scpt Grass Basic Ocean "Red Sands"'
--   # Random themes
--   alias rtheme='osascript ~/sbin/StyleTerm.scpt'
-----------------------

on run argv
    tell application "Terminal"
        if (count argv) is 0 then
            -- Use random theme from all possible themes
            set newTheme to some settings set
            set current settings of selected tab of front window to newTheme
        else
            -- Use random theme from arguments 
            set newThemeName to some item argv
            set current settings of selected tab of front window to first settings set whose name is newThemeName
        end if
    end tell
end run

Answer 2

Это должно сделать:

tell application "Terminal" to set current settings of (do script) to settings set "Pro"

Не уверен, что вы подразумеваете под этим, хотя:

Мне понадобится свойство для темы или получить информацию изэто, как-то для его восстановления.