Как я могу получить настройки разрешения доступа Active Directory из LDAP с помощью VBScript? - PullRequest
Новая
       18

Как я могу получить настройки разрешения доступа Active Directory из LDAP с помощью VBScript?

1 голос
/ 21 мая 2009

В Active Directory есть вкладка «Dial-In», и под этой вкладкой находится переключатель с тремя настройками: 

Allow Access
Deny Access
Control access through remote access policy

Я хотел бы написать VBScript, чтобы взять имя пользователя и вернуть настройки для этого пользователя. (Я на самом деле модифицирую существующий VBScript, поэтому я вынужден использовать этот инструмент).

Каков наилучший способ сделать это?

1 Ответ

2 голосов
/ 21 мая 2009

Вот лучшее решение, которое мне удалось найти. Его легко изменить, чтобы вывести настройки для всех пользователей. 

Main

Function Main
  'Usage: cscript /nologo lookup.vbs mydomain username
  Wscript.Echo CanDialIn(Wscript.Arguments(0), Wscript.Arguments(1))
  Main = 0
End Function

Function CanDialIn(domainname, username)
  'Take a user name and query whether they have permission to Dial in or not
  'http://www.microsoft.com/technet/scriptcenter/resources/qanda/aug05/hey0825.mspx
  Const ADS_SCOPE_SUBTREE = 2
  Dim objConnection
  Dim objCommand
  Dim objRecordSet

  Set objConnection = CreateObject("ADODB.Connection")
  Set objCommand =   CreateObject("ADODB.Command")
  objConnection.Provider = "ADsDSOObject"
  objConnection.Open "Active Directory Provider"
  Set objCommand.ActiveConnection = objConnection

  objCommand.Properties("Page Size") = 1000
  objCommand.Properties("Searchscope") = ADS_SCOPE_SUBTREE 

  'Three possible values for msNPAllowDialin:
  'TRUE = "Allow Access"
  'FALSE = "Deny Access"
  'EMPTY = "Control access through remote access policy"
  objCommand.CommandText = _
    "SELECT msNPAllowDialin FROM 'LDAP://dc=" & domainname & ",dc=com' WHERE objectCategory='user' AND sAMAccountName = '" & username & "'"
  On Error Resume Next
  Set objRecordSet = objCommand.Execute
  if objRecordSet.EOF then
    CanDialIn = "Could not find user " & username
  else
    if objRecordSet.Fields("msNPAllowDialin").Value = True then
      CanDialIn = "Allow"
    else
      if objRecordSet.Fields("msNPAllowDialin").Value = False then
        CanDialIn = "Deny"
      else
        CanDialIn = "Control"
      end if
    end if  
  end if
End Function
...