Как я могу получить OutputDebugString от службы? - PullRequest
Новая
       38

Как я могу получить OutputDebugString от службы?

12 голосов
/ 17 июня 2011

Я пытаюсь перехватить все OutputDebugString сообщения (включая сообщения от служб), используя следующий код. Он работал нормально, пока я не перешел на Windows 7.

Проблема в том, что поскольку службы Windows Vista работают на низкоуровневом сеансе # 0, некоторые люди говорят, что невозможно поймать их, а некоторые так и есть. Что ты думаешь?

Можно ли изменить следующий код, увеличив некоторые права, чтобы иметь возможность получать OutputDebugString сообщений из сеанса # 0? Другими словами; Можно ли использовать DBWIN_BUFFER в сеансе № 0 с сеансом № 1?

Я бы сказал, что это возможно, потому что, например, DebugView может сделать это, и я не вижу никакого сервисного помощника, который бы отправлял эти сообщения (например, через именованные каналы) из Сессии № 0 в Сессию № 1, где работает GUI.

Проблема будет в ИМО в настройках безопасности. Кто-нибудь может подсказать, как их изменить? 

type
  TODSThread = class(TThread)
  protected
    procedure Execute; override;
  end;

...

procedure TODSThread.Execute;
var SharedMem: Pointer;
    SharedFile: THandle;
    WaitingResult: DWORD;
    SharedMessage: string;
    DataReadyEvent: THandle;
    BufferReadyEvent: THandle;
    SecurityAttributes: SECURITY_ATTRIBUTES;
    SecurityDescriptor: SECURITY_DESCRIPTOR;

begin
  SecurityAttributes.nLength := SizeOf(SECURITY_ATTRIBUTES);
  SecurityAttributes.bInheritHandle := True;
  SecurityAttributes.lpSecurityDescriptor := @SecurityDescriptor;

  if not InitializeSecurityDescriptor(@SecurityDescriptor, SECURITY_DESCRIPTOR_REVISION) then
    Exit;

  if not SetSecurityDescriptorDacl(@SecurityDescriptor, True, nil, False) then
    Exit;

  BufferReadyEvent := CreateEvent(@SecurityAttributes, False, True, 'DBWIN_BUFFER_READY');

  if BufferReadyEvent = 0 then
    Exit;

  DataReadyEvent := CreateEvent(@SecurityAttributes, False, False, 'DBWIN_DATA_READY');

  if DataReadyEvent = 0 then
    Exit;

  SharedFile := CreateFileMapping(THandle(-1), @SecurityAttributes, PAGE_READWRITE, 0, 4096, 'DBWIN_BUFFER');

  if SharedFile = 0 then
    Exit;

  SharedMem := MapViewOfFile(SharedFile, FILE_MAP_READ, 0, 0, 512);

  if not Assigned(SharedMem) then
    Exit;

  while (not Terminated) and (not Application.Terminated) do
    begin
      SetEvent(BufferReadyEvent);
      WaitingResult := WaitForSingleObject(DataReadyEvent, INFINITE);

      case WaitingResult of
        WAIT_TIMEOUT: Continue;
        WAIT_OBJECT_0:
          begin
            SharedMessage := String(PAnsiChar(SharedMem) + SizeOf(DWORD));
            // here I have what I need and process it in the main thread
          end;

       WAIT_FAILED: Continue;
     end;
   end;

   UnmapViewOfFile(SharedMem);
   CloseHandle(SharedFile);
end;

Я добавил тег C #, даже если код написан на Delphi, поскольку атрибуты безопасности являются общими для всего API Windows, а у C # есть много последователей:)

1 Ответ

11 голосов
/ 17 июня 2011

Кто-то говорил о такой же проблеме на форумах SysInternals . Их решение состояло в том, чтобы добавить "Global \" к именованным объектам .

Так что используйте следующее 

CreateEvent(@SecurityAttributes, False, True, 'Global\DBWIN_BUFFER_READY');
CreateEvent(@SecurityAttributes, False, False, 'Global\DBWIN_DATA_READY');
CreateFileMapping(THandle(-1), @SecurityAttributes, PAGE_READWRITE, 0, 4096, 'Global\DBWIN_BUFFER');
...