Более эффективный способ выбора количества вхождений в строке

Question

Привет всем, у меня есть следующий скрипт, который отлично работает, но я не думаю, что он очень хороший или эффективный. Просто интересно, есть ли лучший и более эффективный способ сделать то же самое? Задача состоит в том, чтобы рассчитать количество появлений чисел в числовой строке и затем выбрать итоговое значение. Так, например, с номером «014812000» ожидаемый результат должен быть 6, поскольку у нас есть 4 x 0 вхождений и 2 x 1 вхождений. Нас интересуют только случаи более 1. Просто добавьте, что это используется в пользовательской функции.

DECLARE @Number nvarchar(50)
SET @Number = '014812000'

DECLARE @count0 int
DECLARE @count1 int
DECLARE @count2 int
DECLARE @count3 int
DECLARE @count4 int
DECLARE @count5 int
DECLARE @count6 int
DECLARE @count7 int
DECLARE @count8 int
DECLARE @count9 int

DECLARE @countTotal int
SET @countTotal = 0

SET @count0 = LEN(@Number) - LEN(REPLACE(@Number, '0', '')) 
SET @count1 = LEN(@Number) - LEN(REPLACE(@Number, '1', '')) 
SET @count2 = LEN(@Number) - LEN(REPLACE(@Number, '2', '')) 
SET @count3 = LEN(@Number) - LEN(REPLACE(@Number, '3', '')) 
SET @count4 = LEN(@Number) - LEN(REPLACE(@Number, '4', '')) 
SET @count5 = LEN(@Number) - LEN(REPLACE(@Number, '5', '')) 
SET @count6 = LEN(@Number) - LEN(REPLACE(@Number, '6', '')) 
SET @count7 = LEN(@Number) - LEN(REPLACE(@Number, '7', '')) 
SET @count8 = LEN(@Number) - LEN(REPLACE(@Number, '8', '')) 
SET @count9 = LEN(@Number) - LEN(REPLACE(@Number, '9', '')) 

IF @count0 > 1
    BEGIN
        SET @countTotal = @countTotal + @count0
    END
IF @count1 > 1
    BEGIN
        SET @countTotal = @countTotal + @count1
    END
IF @count2 > 1
    BEGIN
        SET @countTotal = @countTotal + @count2
    END
IF @count3 > 1
    BEGIN
        SET @countTotal = @countTotal + @count3
    END
IF @count4 > 1
    BEGIN
        SET @countTotal = @countTotal + @count4
    END
IF @count5 > 1
    BEGIN
        SET @countTotal = @countTotal + @count5
    END
IF @count6 > 1
    BEGIN
        SET @countTotal = @countTotal + @count6
    END
IF @count7 > 1
    BEGIN
        SET @countTotal = @countTotal + @count7
    END
IF @count8 > 1
    BEGIN
        SET @countTotal = @countTotal + @count8
    END
IF @count9 > 1
    BEGIN
        SET @countTotal = @countTotal + @count9
    END

SELECT @countTotal

Answer 1

Вы можете использовать таблицу чисел, чтобы разделить число на строки.Здесь я использую master..spt_values.

select sum(C)
from (
       select count(*) as C
       from master..spt_values as N
       where N.type = 'P' and
             N.number between 1 and len(@Number)
       group by substring(@Number, N.Number, 1)
       having count(*) > 1
     ) as T      

Answer 2

Это может решить вашу проблему, даже если число не является числовым, оно может подсчитать любое вхождение символов, если существует более 1 идентичного символа.

Это было сделано для таблицы символов.

declare @t table(number nvarchar(max))
insert @t values ('014812000')
insert @t values ('0148120001')
insert @t values ('0148120001aa')

;with a as
(
select number n, 0 i from @t
union all
select replace(n, cast(n as char(1)), ''), 
case when replace(n, cast(n as char(1)), '') = stuff(n,1,1,'') then i else 
i + cast(len(n) - len(replace(n, cast(n as char(1)), '')) as int)
end
from a
where n <> ''
)
select i from a where n = ''

Если вы хотите использовать только одно конкретное число, вот как вы можете его использовать:

declare @Number nvarchar(max) 
set @Number = '014812000'  

;with a as
(
select @number n, 0 i
union all
select replace(n, cast(n as char(1)), ''), 
case when replace(n, cast(n as char(1)), '') = stuff(n,1,1,'') then i else 
i + cast(len(n) - len(replace(n, cast(n as char(1)), '')) as int)
end
from a
where n <> ''
)
select i from a where n = ''

Answer 3

взгляните на это .Его использование пользовательской функции.

FUNCTION dbo.com_CountString(@Input nVarChar(max), @SearchString nVarChar(1000))
RETURNS INT
BEGIN
DECLARE @Count INT, @Index INT, @InputLength INT, @SearchLength INT
DECLARE @SampleString INT

if @Input is null or @SearchString is null
    return 0

SET @Count = 0
SET @Index = 1
SET @InputLength  = LEN(@Input)
SET @SearchLength = LEN(@SearchString)

if @InputLength = 0 or @SearchLength = 0 or @SearchLength > @InputLength
    return 0

WHILE @Index <= @InputLength - @SearchLength + 1
BEGIN
    IF SUBSTRING(@Input, @Index, @SearchLength) = @SearchString
    BEGIN
        SET @Count = @Count + 1
        SET @Index = @Index + @SearchLength
    END
    ELSE
        SET @Index = @Index + 1
END

RETURN @Count
END