Как я могу обрезать пробел из переменной в awk?

Question

Предположим, $ 2 - моя переменная. Я пытался перейти с

awk -F\, '{print $2 ":"}'

до

awk -F\, '{print gsub(/[ \t]+$/, "", $2) ":"}'

Но от печати чего-либо вообще ничего не происходит.

Answer 1

Вы печатаете результат gsub, но gsub выполняет модификацию на месте $2 вместо возврата измененной копии. Позвоните gsub, затем напечатайте:

awk -F\, '{gsub(/[ \t]+$/, "", $2); print $2 ":"}'

Answer 2

Эти функции пригодятся для улучшения читабельности.Они также возвращают усеченный результат:

function ltrim(s) { sub(/^[ \t\r\n]+/, "", s); return s }
function rtrim(s) { sub(/[ \t\r\n]+$/, "", s); return s }
function trim(s) { return rtrim(ltrim(s)); }
BEGIN {
# whatever
}
{
# whatever
}
END {
# whatever
} 

Источник: https://gist.github.com/andrewrcollins/1592991

Answer 3

(У меня недостаточно очков, чтобы прокомментировать предыдущий ответ напрямую.)

Для обрезки пробелов в конце из $2 используйте:

awk -F\, '{gsub(/[ \t]+$/, "", $2); print $2 ":"}'

Для обрезки пробелов в начале из $2 используйте:

awk -F\, '{gsub(/^[ \t]+/, "", $2); print $2 ":"}'

И для конца, и для начала:

awk -F\, '{gsub(/^[ \t]+/, "", $2); gsub(/[ \t]+$/, "", $2); print $2 ":"}'

Answer 4

Один вкладыш для gawk:

gawk -F\, '{$2 = gensub(/^[ \t]*|[ \t]*$/,"","g",$2)}'

Answer 5

трим и трим в Unix

awk 'BEGIN{FS=OFS="|"} {gsub(/^[ \t]+|[ \t]+$/, "", $2)}1' filename.txt

Answer 6

Более простой вариант:

Вы должны определить функцию обрезки, использовать gsub для общей замены. Затем найдите с помощью регулярного выражения, если начинается или заканчивается пробелом (один или несколько раз), возвращает поле.

   awk -F'|' 'function trim(field){
   gsub(/^ +| +$/,"", field); 
   return field
   }{
   OFS=",";
   print trim($2),trim($3)}' stations > lista.csv

С этим кодом достаточно

И файл станций имеет такую ​​структуру:

     1 | UTAR | U de Tarapacá                   
     3 | VALN | Valparaíso                      
     4 | JRGN | Junta Gorgino                   
     6 | TRPD | Torpederas