Delphi - HMAC-SHA256 не может пройти тестовые векторы RFC 4231 - PullRequest
Новая
       8

Delphi - HMAC-SHA256 не может пройти тестовые векторы RFC 4231

5 голосов
/ 03 апреля 2012

Мне нужен доступ к сервисам Amazon REST, как и в предыдущем вопросе на вопросе " HMAC-SHA256 в Delphi ". Поскольку это должно быть в D2010, я пытаюсь использовать последнюю версию libeay32.dll для прохождения тестовых векторов в RFC 4231:

http://tools.ietf.org/html/rfc4231

У кого-нибудь есть метод, который проходит эти тесты в Delphi, используя эту библиотеку? Код, размещенный shunty в посте, на который я ссылался, проходит первые два тестовых вектора, а также пятый, но не работает в третьем и четвертом. Эти векторы превышают 64 байта, и поскольку все URL-адреса, которые мне нужно подписать для Amazon, превышают 64 байта, это проблема. Я не смог выяснить, делаю ли я что-то не так. Тест OpenSSL находится в hmactest.c, но он проверяет только EVP_md5, и векторы испытаний не совпадают с векторами в RFC. Мне нужно это для работы с SHA256, чтобы я мог проверить по векторам тестирования в RFC. Я использую следующие константы для тестов (константы, которые теперь обновляются для будущих зрителей, чтобы исправить мои ошибки копирования и вставки, упомянутые в комментариях ниже): 

const
  LIBEAY_DLL_NAME = 'libeay32.dll';
  EVP_MAX_MD_SIZE = 64;

  //RFC 4231 Test case 1
  TEST1_KEY: string = '0b0b0b0b0b0b0b0b0b0b0b0b0b0b0b0b0b0b0b0b';
  TEST1_DATA: string = '4869205468657265';
  TEST1_DIGEST: string = 'b0344c61d8db38535ca8afceaf0bf12b881dc200c9833da726e9376c2e32cff7';

  //RFC 4231 Test case 2
  TEST2_KEY = '4a656665';
  TEST2_DATA = '7768617420646f2079612077616e7420666f72206e6f7468696e673f';
  TEST2_DIGEST = '5bdcc146bf60754e6a042426089575c75a003f089d2739839dec58b964ec3843';

  //RFC 4231 Test case 3
  TEST3_KEY = 'aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa';
  TEST3_DATA = 'dddddddddddddddddddddddddddddddddddddddddddddddddddddddddddddddddddddddddddddddddddddddddddddddddddd';
  TEST3_DIGEST = '773ea91e36800e46854db8ebd09181a72959098b3ef8c122d9635514ced565fe';

  //RFC 4231 Test case 4
  TEST4_KEY = '0102030405060708090a0b0c0d0e0f10111213141516171819';
  TEST4_DATA = 'cdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcdcd';
  TEST4_DIGEST = '82558a389a443c0ea4cc819899f2083a85f0faa3e578f8077a2e3ff46729665b';

  //RFC 4231 Test case 5
  TEST5_KEY = '0c0c0c0c0c0c0c0c0c0c0c0c0c0c0c0c0c0c0c0c';
  TEST5_DATA = '546573742057697468205472756e636174696f6e';
  TEST5_DIGEST = 'a3b6167473100ee06e0c796c2955552b';

Я не знаю, как этот код от shunty будет выглядеть вставленным, потому что здесь он выглядит ужасно (я новичок в стеке потока). Я использовал RAND_seed, а не RAND_load_file, как он, но в остальном это то же самое: 

function TForm1.GetHMAC(const AKey, AData: string): TBytes;
var
  key, data: TBytes;
  md_len: integer;
  res: PByte;
  buf: PInteger;
  rand_val: Integer;
begin
  OpenSSL_add_all_algorithms;

  Randomize;
  rand_val := Random(100);
  GetMem(buf, rand_val);
  try
    RAND_seed(buf, rand_val);

    key := TEncoding.UTF8.GetBytes(AKey);
    data := TEncoding.UTF8.GetBytes(AData);
    md_len := EVP_MAX_MD_SIZE;
    SetLength(Result, md_len);
    res := HMAC(EVP_sha256, @key[0], Length(key), @data[0], Length(data), @result[0], md_len);
    if (res <> nil) then
      SetLength(Result, md_len);

  finally
    FreeMem(buf);
  end;
end;

Код, который я использую для проверки, выглядит следующим образом. Этот конкретный метод предназначен для теста 3, который не проходит. Результат bb861233f283aef2ef7aea09785245c9f3c62720c9d04e0c232789f27a586e44, но он должен быть равен постоянному шестнадцатеричному значению для TEST3_DIGEST: 

procedure TForm1.btnTestCase3Click(Sender: TObject);
var
  LBytesDigest: TBytes;
  LHashString: string;
  LHexDigest: string;
begin
  LBytesDigest := GetHMAC(HexToStr(TEST3_KEY), HexToStr(TEST3_DATA));

  LHexDigest := LowerCase(BytesToHex(LBytesDigest));

  if LHexDigest = TEST3_DIGEST then begin
    Memo1.Lines.Add('SUCCESS: Matches test case');
    Memo1.Lines.Add(LHexDigest);
  end else begin
    Memo1.Lines.Add('ERROR: Does not match test case');
    Memo1.Lines.Add('Result:    ' + LHexDigest);
    Memo1.Lines.Add('Test Case: ' + TEST3_DIGEST);
  end;
end;

Есть идеи? Я собираюсь сдаться и просто создать приложение .NET, используя библиотеку, которую они предоставляют ...

1 Ответ

6 голосов
/ 03 апреля 2012

Вы используете D2009 + (что очевидно при использовании TEncoding), что означает, что вы имеете дело с UnicodeString, но вы не учитываете Юникод в своей логике. RFC не работает с символами, он работает с байтами. Ваши тестовые данные содержат строки в шестнадцатеричном формате. Когда вы декодируете их в значения (Unicode)String, многие из полученных символов находятся за пределами диапазона символов ASCII, что означает, что они должны быть интерпретированы кодовыми страницами Ansi, прежде чем вы сможете правильно преобразовать их в UTF-8 (чего не следует делать). в любом случае использовать в этой ситуации).

Вам нужно изменить свою реализацию, чтобы вместо этого декодировать ваши шестнадцатеричные строки прямо в TBytes (для этого можно использовать Classes.HexToBin()), чтобы правильные значения байтов сохранялись и передавались в HMAC, и полностью избавлялись от TEncoding.UTF8.GetBytes() : 

function TForm1.GetHMAC(const AKey, AData: TBytes): TBytes; 
var 
  md_len: integer; 
  res: PByte; 
  buf: PInteger; 
  rand_val: Integer; 
begin 
  OpenSSL_add_all_algorithms; 

  Randomize; 
  rand_val := Random(100); 
  GetMem(buf, rand_val); 
  try 
    RAND_seed(buf, rand_val); 
    md_len := EVP_MAX_MD_SIZE; 
    SetLength(Result, md_len); 
    res := HMAC(EVP_sha256, Pointer(AKey), Length(AKey), Pointer(AData), Length(AData), @Result[0], md_len); 
    if (res <> nil) then 
      SetLength(Result, md_len); 
  finally 
    FreeMem(buf); 
  end; 
end; 

function HexToBytes(const S: String): TBytes;
begin
  SetLength(Result, Length(S) div 2);
  SetLength(Result, HexToBin(PChar(S), Pointer(Result), Length(Result)));
en;

procedure TForm1.btnTestCase3Click(Sender: TObject);  
var  
  LBytesDigest: TBytes;  
  LHashString: string;  
  LHexDigest: string;  
begin  
  LBytesDigest := GetHMAC(HexToBytes(TEST3_KEY), HexToBytes(TEST3_DATA));  
  LHexDigest := LowerCase(BytesToHex(LBytesDigest));  
  if LHexDigest = TEST3_DIGEST then begin  
    Memo1.Lines.Add('SUCCESS: Matches test case');  
    Memo1.Lines.Add(LHexDigest);  
  end else begin  
    Memo1.Lines.Add('ERROR: Does not match test case');  
    Memo1.Lines.Add('Result:    ' + LHexDigest);  
    Memo1.Lines.Add('Test Case: ' + TEST3_DIGEST);  
  end;  
end;
...