Расшифровка и понимание кода сборки

Question

Итак, немного фона.Я начинающий с c и ассемблерным кодом, у нас есть назначение «бомба» (написанное на c), которое вызывает методы, которые требуют определенных паролей, но код не виден, и мне нужно определить правильный пароль, посмотрев на ассемблерный код.

Код указывает, что пароль для этого метода состоит из 6 цифр, которые передаются в качестве «ввода» в фазу 2 метода (я пытаюсь избежать запуска).

Часть, в которой я запутался, - это прыжок с +64 до +42.Кажется, что это цикл, но я не уверен, как стек влияет на каждый проход.Похоже, что цикл завершается, если последние два числа совпадают, и это как-то связано с сложением и вычитанием 4, но я не уверен, как обходятся адреса.Если кто-нибудь может перевести, что именно происходит, или если мне нужно посмотреть какие-то конкретные регистры / местоположения, это очень поможет.Есть еще 4 этапа, каждый из которых должен быть более сложным, поэтому я хочу получить хорошее представление о том, как подходить к их чтению.

Также, если у кого-то есть хороший ресурс (например, таблица для печати) с кодом сборкиключевые слова, которые также были бы полезны, а также, если есть какие-либо различия между 32-битными и 64-битными регистрами, мне нужно беспокоиться не только об именах регистров.

    82          phase_2(input);
(gdb) disas phase_2
Dump of assembler code for function phase_2:
0x000000000040106b <phase_2+0>: push   %rbp
0x000000000040106c <phase_2+1>: push   %rbx
0x000000000040106d <phase_2+2>: sub    $0x28,%rsp
0x0000000000401071 <phase_2+6>: mov    %rsp,%rsi
0x0000000000401074 <phase_2+9>: callq  0x401457 <read_six_numbers>
0x0000000000401079 <phase_2+14>:        cmpl   $0x0,(%rsp)
0x000000000040107d <phase_2+18>:        jne    0x401086     <phase_2+27>
0x000000000040107f <phase_2+20>:        cmpl   $0x1,0x4(%rsp)
0x0000000000401084 <phase_2+25>:        je     0x40108b <phase_2+32>
0x0000000000401086 <phase_2+27>:        callq  0x401421 <explode_bomb>
0x000000000040108b <phase_2+32>:        lea    0x8(%rsp),%rbx
0x0000000000401090 <phase_2+37>:        lea    0x18(%rsp),%rbp
0x0000000000401095 <phase_2+42>:        mov    -0x8(%rbx),%eax
0x0000000000401098 <phase_2+45>:        add    -0x4(%rbx),%eax
0x000000000040109b <phase_2+48>:        cmp    %eax,(%rbx)
0x000000000040109d <phase_2+50>:        je     0x4010a4 <phase_2+57>
0x000000000040109f <phase_2+52>:        callq  0x401421 <explode_bomb>
0x00000000004010a4 <phase_2+57>:        add    $0x4,%rbx
0x00000000004010a8 <phase_2+61>:        cmp    %rbp,%rbx
0x00000000004010ab <phase_2+64>:        jne    0x401095 <phase_2+42>
0x00000000004010ad <phase_2+66>:        add    $0x28,%rsp
0x00000000004010b1 <phase_2+70>:        pop    %rbx
0x00000000004010b2 <phase_2+71>:        pop    %rbp
0x00000000004010b3 <phase_2+72>:        retq   

Answer 1

Вот эквивалент C фазы2:

int t[6];
read_six_numbers (t);
if ((t[0] != 0) || (t[1] != 1)) {
    explode_bomb();
}

for (int i = 2; i < 6; i++) {
        if (t[i] != t[i - 2] + t[i - 1]) {
            explode_bomb();
    }
}

Итак, пароль 0, 1, 1, 2, 3, 5.

Как я это сделал?Постепенно заменяя сборку на C.

Вы заметите, что указатель стека (rsp) никогда не меняется.Вы можете видеть стек как массив из 32-битных чисел.То есть каждый раз, когда вы перемещаетесь на 4 байта, вы переходите к следующему элементу.т. е. 0 (% rsp), 4 (% rsp), ... эквивалентны t [0], t [1], ...

Я покажу вам возможное постепенное преобразование битау вас проблемы с:

                lea    0x8(%rsp),%rbx
                lea    0x18(%rsp),%rbp
<phase_2+42>:   mov    -0x8(%rbx),%eax
                add    -0x4(%rbx),%eax
                cmp    %eax,(%rbx)
                je     <phase_2+57>
                callq  explode_bomb
<phase_2+57>:   add    $0x4,%rbx
                cmp    %rbp,%rbx
                jne    phase_2+42
------------------------------------------------------
                    rbx = rsp + 8;
                    rbp = rsp + 24;
<phase_2+42>:       eax = [rbx - 8];
                    eax += [rbx - 4];
                    if (eax == [rbx]) goto <phase_2+57>;
                    explode_bomb();
<phase_2+57>:       rbx += 4;
                    if (rbx != rbp) goto phase_2+42;
------------------------------------------------------
rbx = rsp + 8;
rbp = rsp + 24;
do {
    eax = [rbx - 8] + [rbx - 4];
        if (eax != [rbx]) {
        explode_bomb();
    }
        rbx += 4;
} while (rbx != rbp);
------------------------------------------------------
rbx = 8;
do {
    eax = [rsp + rbx - 8] + [rsp + rbx - 4];
        if (eax != [rsp + rbx]) {
        explode_bomb();
    }
        rbx += 4;
} while (rbx < 24);
------------------------------------------------------
i = 2;
do {
    eax = t[i - 2] + t[i - 1];
        if (eax != t[i]) {
        explode_bomb();
    }
        i += 1;
} while (i < 6);
------------------------------------------------------
for (int i = 2; i < 6; i++) {
    if (t[i] != t[i - 2] + t[i - 1]) {
            explode_bomb();
        }
}

Если вы потратите время на понимание этих преобразований, вы сможете преобразовать и понять любой фрагмент сборки.