Как вы получаете только имя файла, а не полный путь к файлу открытого файла?

Question

Другими словами, нужно ли выполнять обработку строк после вызова метода Application.GetOpenFileName()?

Answer 1

Зачем изобретать велосипед и писать тонны шаблонного кода? Просто используйте существующий метод GetFileName FileSystemObject , уже написанный, протестированный и отлаженный для вас:

filename = FSO.GetFileName(path)

Вот рабочий пример:

Dim path As String
Dim filename As String
Dim FSO As Scripting.FileSystemObject
Set FSO = New FileSystemObject

path = "C:\mydir\myotherdir\myfile.txt"

filename = FSO.GetFileName(path) 'Bingo. Done.

Debug.Print filename ' returns "myfile.txt"

' Other features:
Debug.Print FSO.GetBaseName(path) ' myfile
Debug.Print FSO.GetExtensionName(path) ' txt
Debug.Print FSO.GetParentFolderName(path) ' C:\mydir\myotherdir
Debug.Print FSO.GetDriveName(path) ' C:
' et cetera, et cetera.

Вам необходимо установить ссылку следующим образом: Инструменты> Ссылки ...> установить флажок рядом с Microsoft Scripting Runtime.

В противном случае используйте позднее связывание:

Dim FSO As Object
Set FSO = CreateObject("Scripting.FileSystemObject")

Answer 2

Я использую эти функции для обработки имени файла. Последний - тот, который вам нужен здесь.

Public Function FilePathOf(ByVal s As String) As String
    Dim pos As Integer

    pos = InStrRev(s, "\")
    If pos = 0 Then
        FilePathOf = ""
    Else
        FilePathOf = Left$(s, pos)
    End If
End Function

Public Function FileNameOf(ByVal s As String) As String
    Dim pos1 As Integer, pos2 As Integer

    pos1 = InStrRev(s, "\") + 1
    pos2 = InStrRev(s, ".")
    If pos2 = Len(s) Then pos2 = pos2 + 1
    If pos2 = 0 Then pos2 = Len(s) + 1
    FileNameOf = Mid$(s, pos1, pos2 - pos1)
End Function

Public Function FileExtOf(ByVal s As String) As String
    Dim pos As Integer

    pos = InStrRev(s, ".")
    If pos = 0 Then
        FileExtOf = ""
    Else
        FileExtOf = Mid$(s, pos + 1)
    End If
End Function

Public Function FileNameExtOf(ByVal s As String) As String
    FileNameExtOf = Mid$(s, InStrRev(s, "\") + 1)
End Function

Answer 3

активируйте файл, о котором идет речь, затем:

Function getname()

arr = Split(ActiveDocument.FullName, "\")
Debug.Print arr(UBound(arr))

End Function

Я предполагаю, что вы используете Word, отсюда и "ActiveDocument". Измените это на «ActiveWorksheet» и др., Где это необходимо

Answer 4

В этом случае вы используете Application.GetOpenFilename (), поэтому вы уверены, что файл физически существует на диске, поэтому простейшим подходом будет использование Dir ().

fileName = Dir(filePath)

Полный кодэто:

Dim fileName, filePath As Variant

filePath = Application.GetOpenFilename("Excel files (*.xlsm), *.xlsm", , "Select desired file", , False)

If filePath = False Then
    MsgBox "No file selected.", vbExclamation, "Sorry!"
    Exit Sub
Else

    'Remove path from full filename
    fileName = Dir(filePath)

    'Print file name (with extension)
    MsgBox "File selected." & vbCr & vbCr & fileName, vbInformation, "Sucess!"

End If

Answer 5

'Проще всегда лучше !! (замените подходящее местоположение ячейки R1C1 и длину строки пути)

Dim TheFile As String  
Dim TheFileLessPath As String  

Function getname()  
Workbooks.Open filename:=TheFile  
TheFileLessPath = Mid(TheFile, 12, 7)

ActiveCell.FormulaR1C1 = TheFileLessPath
End Function