Xslt извлекает атрибуты и генерирует HTML

Question

Я пытаюсь преобразовать следующий XML ..

<?xml version="1.0" encoding="utf-16"?><Member TextRank="unknown" FullName="My Name" ..etc.. />

На что-то вроде следующего,

<div class="member">
    <span class="label">
        Text Rank (note: i want to override the labels in the xslt)
    </div>
    <span class="value">
        unknown
    </span>
    <span class="label">
        Full Name
    </div>
    <span class="value">
        My Name
    </span>
    ..etc..
</div>

Как, если возможно, я могу сделать это с помощью xslt?

Answer 1

Вот другой подход, который устраняет необходимость в элементе xsl: выбрать .Вместо этого вы можете воспользоваться соответствующими шаблонами, чтобы иметь специальные шаблоны для случаев атрибутов, имена которых вы хотите переопределить, и универсальный шаблон для другого случая.

Чтобы избежать повторения кода, вы также можете сделатьуниверсальный шаблон именованный шаблон с параметром для переопределения имени

<xsl:template match="@*" name="attribute">
   <xsl:param name="label" select="local-name()" />

Таким образом, для большинства атрибутов по умолчанию будет использоваться имя атрибута, но конкретный шаблон для @ FullName может затем вызвать его с другим именем.

<xsl:template match="@FullName">
   <xsl:call-template name="attribute">
      <xsl:with-param name="label" select="'Full Name'" />
   </xsl:call-template>
</xsl:template>

Вот полный XSLT:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="html" indent="yes"/>

   <xsl:template match="*">
      <div class="{local-name()}">
         <div> Title: </div>
         <xsl:apply-templates select="@*"/>
      </div>
   </xsl:template>

   <xsl:template match="@FullName">
      <xsl:call-template name="attribute">
         <xsl:with-param name="label" select="'Full Name'" />
      </xsl:call-template>
   </xsl:template>

   <xsl:template match="@*" name="attribute">
      <xsl:param name="label" select="local-name()" />
      <span class="label">
         <xsl:value-of select="concat($label, ' : ')"/>
      </span>
      <span class="value">
         <xsl:value-of select="."/>
      </span>
      <br/>
   </xsl:template>
</xsl:stylesheet>

Применительно к следующему XML:

<Member TextRank="unknown" ID="12" FullName="My Name" Dob="01/01/1970" />

Выводится следующее:

<div class="Member">
   <div> Title: </div>
   <span class="label">TextRank : </span>
   <span class="value">unknown</span>
   <br>
   <span class="label">ID : </span>
   <span class="value">12</span>
   <br>
   <span class="label">Full Name : </span>
   <span class="value">My Name</span>
   <br>
   <span class="label">Dob : </span>
   <span class="value">01/01/1970</span>
   <br>
</div>

Answer 2

Это решение, которое я придумал.

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
     version="1.0">
    <xsl:output indent="yes" />
    <xsl:template match="*">
        <xsl:element name="div">
            <xsl:attribute name="class">className</xsl:attribute>
            <div>
                Title:
            </div>

            <!-- UID, Name, DBO-->
            <xsl:apply-templates select="@ID"/>
            <xsl:apply-templates select="@FullName"/>
            <xsl:apply-templates select="@Dob"/>

        </xsl:element>

    </xsl:template>

    <xsl:template match="@*">
        <xsl:element name="span">

            <xsl:attribute name="class">label</xsl:attribute>
            <xsl:choose>
                <xsl:when test="name() = 'FullName'">
                    Full Name
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="name()"/>
                </xsl:otherwise>
            </xsl:choose>
            :
        </xsl:element>
        <xsl:element name="span">
            <xsl:attribute name="class">value</xsl:attribute>
            <xsl:value-of select="."/>
        </xsl:element>
        <br/>
    </xsl:template>

</xsl:stylesheet>