Как найти местоположение программы

Question

Я использую Delphi2006 и хочу найти местоположение конкретной программы, используя код Delphi.

Answer 1

Вот программа на Delphi, которая может найти все файлы с именем aFileName и поместить результаты в список строк aDestFiles.

 function findFilesCalled(aFileName : String; aDestFiles : TStringList) : boolean;
 var
   subDirs : TStringList;
   dir : Char;
   sRec : TSearchRec;
   toSearch : string;
 begin
   subdirs := TStringList.Create;
   for dir := 'A' to 'Z' do
     if DirectoryExists(dir + ':\') then
       subdirs.add(dir + ':');
   try
     while (subdirs.count > 0) do begin
       toSearch := subdirs[subdirs.count - 1];
       subdirs.Delete(subdirs.Count - 1);
       if FindFirst(toSearch + '\*.*', faDirectory, sRec) = 0 then begin
         repeat
           if (sRec.Attr and faDirectory) <> faDirectory then
             Continue;
           if (sRec.Name = '.') or (sRec.Name = '..') then
             Continue;
           subdirs.Add(toSearch + '\' + sRec.Name);
         until FindNext(sRec) <> 0;
       end;
       FindClose(sRec);
       if FindFirst(toSearch + '\' + aFileName, faAnyFile, sRec) = 0 then begin
         repeat
           aDestFiles.Add(toSearch + '\' + sRec.Name);
         until FindNext(sRec) <> 0;
       end;
       FindClose(sRec);
     end;
   finally
     FreeAndNil(subdirs);
   end;
   Result := aDestFiles.Count > 0;
 end;