искать ключевое слово и заменить текст в XML-файле на основе внешнего XML-файла

Question

У меня есть xml-файл main.xml со следующей разметкой и данными.

 main.xml

 <xml>
    <content>
     <para>
     This is a para.
     </para>
     <sub para>
     This is para.
     </sub para>
     </content>
</xml>

У меня есть еще один xml-файл keyword.xml со списком ключевых слов, которые нам нужно найти в любом месте выше xml и заменить.значение ключевого слова.

keyword.xml

 <xml>
     <keywordList>
        <keyword>
            <value>para</value>
            <replace> paragraph </replace> 
        </keyword>
        <keyword>
            <value>is</value>
            <replace>IS</replace> 
        </keyword>
  </xml>

Можем ли мы сделать это в xslt, чтобы на выходе было

    output
        <xml>
    <content>
     <para>
     This IS a paragraph.
     </para>
     <sub para>
     This IS paragraph.
     </sub para>
     </content>
</xml>

Answer 1

Попробуйте следующее

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet
    version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

    <xsl:variable name="keywords" select="document('keyword.xml')"/>

    <xsl:template match="/">
        <xsl:copy>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="text()">
        <xsl:analyze-string select="." regex="[A-Za-z]+">
            <xsl:matching-substring>
                <xsl:variable name="repl" select="$keywords//keyword[value = current()]"/>
                <xsl:choose>
                    <xsl:when test="$repl">
                        <xsl:value-of select="$repl/replace"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:value-of select="current()"/>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:matching-substring>
            <xsl:non-matching-substring>
                <xsl:value-of select="current()"/>
            </xsl:non-matching-substring>
        </xsl:analyze-string>
    </xsl:template>
</xsl:stylesheet>

Обратите внимание, что значение замены для para включает пробелы вокруг нового слова и, следовательно, дополнительные пробелы:

<?xml version="1.0" encoding="UTF-8"?>
<xml>
    <content>
        <para>
            This IS a  paragraph .
        </para>
        <subpara>
            This IS  paragraph .
        </subpara>
    </content>
</xml>

Answer 2

Это решение XSLT 1.0 (конечно, может использоваться и с XSLT 2.0):

<xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
     xmlns:ext="http://exslt.org/common"
     xmlns:my="my:my">
        <xsl:output omit-xml-declaration="yes" indent="yes"/>
        <xsl:strip-space elements="*"/>

        <my:params xml:space="preserve">
            <pattern>
                <old>para</old>
                <new> paragraph </new>
            </pattern>
            <pattern>
                <old> is </old>
                <new> IS </new>
            </pattern>
        </my:params>

        <xsl:variable name="vrtfPats">
         <xsl:for-each select="document('')/*/my:params/*">
          <xsl:sort select="string-length(old)"
               data-type="number" order="descending"/>
           <xsl:copy-of select="."/>
         </xsl:for-each>
        </xsl:variable>

        <xsl:variable name="vPats" select=
         "ext:node-set($vrtfPats)/*"/>

            <xsl:template match="node()|@*">
              <xsl:copy>
               <xsl:apply-templates select="node()|@*"/>
              </xsl:copy>
          </xsl:template>

        <xsl:template match="text()" name="multiReplace" priority="2">
            <xsl:param name="pText" select="."/>
            <xsl:param name="pPatterns" select="$vPats"/>
            <xsl:if test=    "string-length($pText) >0">
                <xsl:variable name="vPat" select=
                "$vPats[starts-with($pText, old)][1]"/>

                <xsl:choose>
                    <xsl:when test="not($vPat)">
                        <xsl:copy-of select="substring($pText,1,1)"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:copy-of select="$vPat/new/node()"/>
                    </xsl:otherwise>
                </xsl:choose>

                <xsl:call-template name="multiReplace">
                    <xsl:with-param name="pText" select=
                    "substring($pText,
                              1 + not($vPat) + string-length($vPat/old/node())
                              )"/>
                </xsl:call-template>
            </xsl:if>
        </xsl:template>
</xsl:stylesheet>

Когда это преобразование применяется к предоставленному документу XML (исправлено, чтобы оно было правильно сформировано):

<xml>
    <content>
        <para>
         This is a para.
      </para>
        <sub_para>
         This is para.
      </sub_para>
    </content>
</xml>

желаемый, правильный результат получается :

<xml>
   <content>
      <para>
         This IS a  paragraph .
      </para>
      <sub_para>
         This IS  paragraph .
      </sub_para>
   </content>
</xml>

Объяснение : текст сканируется посимвольно, и максимально длинная целевая строка, начинающаяся с этой позиции в тексте, заменяется указанной заменой.