Как мы можем провести модульное тестирование контроллера Mojolicious? - PullRequest
Новая
       18

Как мы можем провести модульное тестирование контроллера Mojolicious?

11 голосов
/ 30 марта 2011

Мы создали следующий простой Mojolicious контроллер: 

package SampleApp::Pages;

# $Id$

use strict;
use warnings;

our $VERSION = '0.01';

use Mojo::Base 'Mojolicious::Controller';

sub home {
    my $self = shift;

    $self->render( 'title' => 'Home' );

    return;
}

sub contact {
    my $self = shift;

    $self->render( 'title' => 'Contact' );

    return;
}

sub about {
    my $self = shift;

    $self->render( 'title' => 'About' );

    return;
}

1;

Соответствующие модульные тесты выглядят следующим образом: 

package Test::SampleApp::Pages;

# $Id$

use strict;
use warnings;

our $VERSION = '0.01';

use Carp;
use English '-no_match_vars';
use Readonly;
use Test::Mojo;
use Test::Most;

use base 'Test::Class';

Readonly my $SERVER_OK => 200;

sub startup : Tests(startup) {
    eval {
        require SampleApp;

        SampleApp->import;

        1;
    } or Carp::croak($EVAL_ERROR);

    return;
}

sub get_home : Tests(4) {
    my $test = shift;
    my $mojo = $test->mojo;

    $mojo->get_ok('/pages/home')->status_is($SERVER_OK);

    $mojo->text_is(
        'title',
        $test->base_title . ' | Home',
        '... and should have the right title'
    );

    $mojo->content_like(
        qr/<body>(?:\s*\S+\s*)+<\/body>/msx,
        '... and should have a non-blank body'
    );

    return;
}

sub get_contact : Tests(3) {
    my $test = shift;
    my $mojo = $test->mojo;

    $mojo->get_ok('/pages/contact')->status_is($SERVER_OK);

    $mojo->text_is(
        'title',
        $test->base_title . ' | Contact',
        '... and should have the right title'
    );

    return;
}

sub get_about : Tests(3) {
    my $test = shift;
    my $mojo = $test->mojo;

    $mojo->get_ok('/pages/about')->status_is($SERVER_OK);

    $mojo->text_is(
        'title',
        $test->base_title . ' | About',
        '... and should have the right title'
    );

    return;
}

sub base_title {
    my ( $self, $base_title ) = @_;

    if ( defined $base_title ) {
        $self->{base_title} = $base_title;
    }

    return $self->{base_title};
}

sub mojo {
    my ( $self, $mojo ) = @_;

    if ( defined $mojo ) {
        $self->{mojo} = $mojo;
    }

    return $self->{mojo};
}

sub setup : Tests(setup) {
    my $test = shift;

    $test->base_title('Mojolicious Sample App');

    $test->mojo( Test::Mojo->new( app => 'SampleApp', max_redirects => 1 ) );

    return;
}

1;

Для нас это большекак тестирование функциональности, а не модульное тестирование

Есть ли способ вызвать метод контроллера home и проверить его вывод, который не требует запуска экземпляра сервера через Test::Mojo?

1 Ответ

21 голосов
/ 04 июля 2011

Чтобы проверить проводку вашего контроллера, используйте следующий код:

Мы начинаем t/pages.t со знакомой информации. 

use Mojolicious;
use Test::More;

Теперь создайте подкласс тестирования SampleApp::Pagesкоторый записывает вызовы render. 

package TestingPages;
use Mojo::Base 'SampleApp::Pages';

has 'render_called';
has 'render_arg';

sub render {
  my($self,%arg) = @_;
  $self->render_called(1);
  $self->render_arg({ %arg });
}

Ваш вопрос использовался Test::Class, поэтому продолжайте эту тему. 

package Test::SampleApp::Pages;

use base 'Test::Class';
use Test::More;

Обратите внимание, что die без аргументов распространяется больше всегонедавнее исключение, поэтому вам не нужно явно писать $@. 

sub startup : Test(startup) {
  eval { require SampleApp::Pages; SampleApp::Pages->import; 1 } or die;
}

В setup создать экземпляр подкласса тестирования, подключить его к экземпляру Mojolicious и отключить ведение журнала. 

sub setup : Test(setup) {
  my($self) = @_;

  my $c = TestingPages->new(app => Mojolicious->new);
  $c->app->log->path(undef);
  $c->app->log->level('fatal');
  $self->{controller} = $c;
}

В домашнем тесте вызовите метод контроллера home и проверьте результаты. 

sub home : Tests(2) {
  my($self) = @_;
  my $c = $self->{controller};
  $c->home;
  is $c->render_called, 1, "render called";
  is $c->render_arg->{title}, "Home", "correct title arg";
}

Наконец, запустите свои тесты. 

package main;
Test::SampleApp::Pages->runtests;

Вывод: 

$ ./sampleapp.pl test
Running tests from '/tmp/sampleapp/t'.
t/pages.t .. ok   
All tests successful.
Files=1, Tests=2,  1 wallclock secs ( 0.03 usr  0.02 sys +  0.24 cusr  0.03 csys =  0.32 CPU)
Result: PASS

Теперь, когда вы видите, как это сделать, возникает вопрос, стоит ли это всех усилий.Контроллеры должны быть простой проводки.Подумайте, действительно ли какая-либо сложность в контроллере относится к модели, в которой тестирование гораздо проще.

...