Унаследовал класс от EventDispatcher во Flash, но пользовательское событие не получено

Question

У меня есть пользовательское событие, которое отправляется при перемещении ползунка, но я не получаю событие от унаследованного класса диспетчера, который я создал, тогда как я следовал тому же синтаксису, что и для решения Мое пользовательское событие флэш-памяти не вызывает

Класс события:

package {

    import flash.events.Event;

     public class CustomEvent extends Event
     {
            public static const ON_DISPATCHER_EVENT = "onDispatcherEvent";
        public var value:Number;

        public function CustomEvent(type:String, bubbles:Boolean=false, cancelable:Boolean=false):void
        {
           super(type, bubbles, cancelable);
        }

     }

}

Диспетчер:

package {

    import flash.events.EventDispatcher;
    import flash.events.Event;

    public class CustomEventDispatcher extends EventDispatcher {

        private var cEvent: CustomEvent;      

        public function CustomEventDispatcher() {

        }

        public function raiseEvent(_value:Number) {
            cEvent = new CustomEvent(CustomEvent.ON_DISPATCHER_EVENT);
            cEvent.value = _value;
            dispatchEvent(cEvent);                      
        }

    }
}

Тестовый класс:

package {

    import flash.display.*;
    import flash.net.*;
    import flash.events.*;
    import fl.events.SliderEvent;
    import fl.controls.Slider;

    public class TestCustomEvent extends MovieClip {        

      private var cEvent: CustomEvent;

      public function TestCustomEvent() {   

        addEventListener( Event.ADDED_TO_STAGE, init);  

      }

      public function init( e:Event ):void {

        removeEventListener( Event.ADDED_TO_STAGE, init );

        this.addEventListener(CustomEvent.ON_DISPATCHER_EVENT,OnDispatcherEvent);

        slider.addEventListener(SliderEvent.CHANGE,OnSliderEventChange);

      } 


      public function OnDispatcherEvent(event:CustomEvent): void {

            trace(event.value);
      }


      public function OnSliderEventChange(event:SliderEvent) {

            cEvent = new CustomEvent(CustomEvent.ON_DISPATCHER_EVENT);
            cEvent.value = event.value;
            dispatchEvent(cEvent);
                    trace("hello");

      }

    }       
}

Answer 1

Я думаю, что ваше понимание потока событий немного неверно. Ответ, который я уже дал в Мое пользовательское событие flash не вызывает (что, я полагаю, вы не читали), я думаю, что это правильный способ использования пользовательских объектов Event и IEventDispatcher:

package 
{
    import flash.display.Sprite;
    import flash.events.Event;

    public class Main extends Sprite 
    {
        private var _sliderSprite:SliderSprite;

        public function Main():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);

        }// end function

        private function init(e:Event = null):void 
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);

            _sliderSprite = new SliderSprite();
            _sliderSprite.x = (stage.stageWidth / 2);
            _sliderSprite.y = (stage.stageHeight / 2);
            addChild(_sliderSprite);

        }// end function
    }// end class

}// end package

import fl.controls.Slider;
import fl.events.SliderEvent;
import flash.display.Sprite;

internal class SliderSprite extends Sprite
{
    private var _slider:Slider;

    public function SliderSprite()
    {
        init();

    }// end function

    private function init():void
    {
        _slider = new Slider();
        addChild(_slider);

        _slider.addEventListener(SliderEvent.CHANGE, onSliderChange);
        addEventListener(CustomEvent.CUSTOM_EVENT_TYPE, onSliderSpriteCustomEventType);

    }// end function

    private function onSliderSpriteCustomEventType(e:CustomEvent):void
    {
        trace(e.value);

    }// end function

    private function onSliderChange(e:SliderEvent):void
    {
        dispatchEvent(new CustomEvent(CustomEvent.CUSTOM_EVENT_TYPE, e.value));

    }// end function

}// end class

import flash.events.Event;

internal class CustomEvent extends Event
{
    public static const CUSTOM_EVENT_TYPE:String = "customEventType";
    private var _value:Number;

    public function get value():Number
    {
        return _value;

    }// end function

    public function CustomEvent(type:String, 
                                value:Number,
                                bubbles:Boolean = false,
                                cancelable:Boolean = false)
    {
        _value = value;

        super(type, bubbles, cancelable);

    }// end function

    override public function clone():Event
    {
        return new CustomEvent(type, value, bubbles, cancelable);

    }// end function

}// end class

[UPDATE] [отредактировано 08/04/2011 08:22]

Я изменил код, чтобы инкапсулировать весь код, включающий отправку и прослушивание событий / для событий, а также исключение обработчиков событий, в другой класс (EventDispatcherManager).

import flash.display.Sprite;
import flash.events.IEventDispatcher;

internal class SliderSprite extends Sprite
{
    private var _slider:Slider;
    private var _eventDispatcherManager:EventDispatcherManager;

    public function SliderSprite()
    {
        init();

    }// end function

    private function init():void
    {
        _slider = new Slider();
        addChild(_slider);

        _eventDispatcherManager = new EventDispatcherManager(IEventDispatcher(_slider));

    }// end function

}// end class

import fl.controls.Slider;
import fl.events.SliderEvent;
import flash.events.EventDispatcher;

internal class EventDispatcherManager extends EventDispatcher
{
    public function EventDispatcherManager(slider:IEventDispatcher)
    {
        slider.addEventListener(SliderEvent.CHANGE, onSliderChange);
        this.addEventListener(CustomEvent.CUSTOM_EVENT_TYPE, onCustomEventType);

    }// end function

    private function onSliderChange(e:SliderEvent):void
    {
        this.dispatchEvent(new CustomEvent(CustomEvent.CUSTOM_EVENT_TYPE, e.value));

    }// end function

    private function onCustomEventType(e:CustomEvent):void
    {
        trace(e.value);

    }// end function

}// end function

Answer 2

если вы не импортируете класс CustomEventDispatcher в свой тестовый файл

Answer 3

event.value не существует
попробуйте отследить событие в одиночку и посмотреть, что вы получите
Уверен, вам нужно что-то вроде event.target.value

Answer 4

Трассируется ли привет?

Похоже, что существует неопределенная ссылка на то, какой диспетчер вызывает метод disptachEvent().Попробуйте указать slider.dispatchEvent() и использовать slider.addEventListener() для прослушивания вашего пользовательского события.