Преобразование из Camelcase в _ в Emacs

Question

Существует ли функция emacs для преобразования слова в верблюжьей букве в подчеркивание?Что-то вроде:

longVariableName

M-x to-underscore

long_variable_name

Answer 1

Используйте пакет с перегибом строки, доступный на MELPA, или на https://github.com/akicho8/string-inflection.

Полезные сочетания клавиш, скопированные с https://www.emacswiki.org/emacs/CamelCase:

;; Cycle between snake case, camel case, etc.
(require 'string-inflection)
(global-set-key (kbd "C-c i") 'string-inflection-cycle)
(global-set-key (kbd "C-c C") 'string-inflection-camelcase)        ;; Force to CamelCase
(global-set-key (kbd "C-c L") 'string-inflection-lower-camelcase)  ;; Force to lowerCamelCase
(global-set-key (kbd "C-c J") 'string-inflection-java-style-cycle) ;; Cycle through Java styles

Answer 2

Я использую следующее для переключения между верблюдом и подчеркиванием:

(defun toggle-camelcase-underscores ()
  "Toggle between camelcase and underscore notation for the symbol at point."
  (interactive)
  (save-excursion
    (let* ((bounds (bounds-of-thing-at-point 'symbol))
           (start (car bounds))
           (end (cdr bounds))
           (currently-using-underscores-p (progn (goto-char start)
                                                 (re-search-forward "_" end t))))
      (if currently-using-underscores-p
          (progn
            (upcase-initials-region start end)
            (replace-string "_" "" nil start end)
            (downcase-region start (1+ start)))
        (replace-regexp "\\([A-Z]\\)" "_\\1" nil (1+ start) end)
        (downcase-region start (cdr (bounds-of-thing-at-point 'symbol)))))))

Answer 3

(progn (replace-regexp "\\([A-Z]\\)" "_\\1" nil (region-beginning) (region-end))
       (downcase-region (region-beginning) (region-end)))

Answer 4

Я использую это при преобразовании кода C # в PHP.

(defun un-camelcase-word-at-point ()
  "un-camelcase the word at point, replacing uppercase chars with
the lowercase version preceded by an underscore.

The first char, if capitalized (eg, PascalCase) is just
downcased, no preceding underscore.
"
  (interactive)
  (save-excursion
    (let ((bounds (bounds-of-thing-at-point 'word)))
      (replace-regexp "\\([A-Z]\\)" "_\\1" nil
                      (1+ (car bounds)) (cdr bounds))
      (downcase-region (car bounds) (cdr bounds)))))

А потом в моем php-режиме fn:

(local-set-key "\M-\C-C"  'un-camelcase-word-at-point)

Answer 5

В 2018 году появился еще один общий путь: magnars / s.el: давно потерянная библиотека Emacs для работы со строками. - github.com , несколько примеров относительно вопроса ОП:

1. в любом случае к случаю змеи (подчеркивание отделено):

   (s-snake-case "some words") ;; => "some_words"
   (s-snake-case "dashed-words") ;; => "dashed_words"
   (s-snake-case "camelCasedWords") ;; => "camel_cased_words"
   

2. в любом случае, чтобы опустить верблюд:

   (s-lower-camel-case "some words") ;; => "someWords"
   (s-lower-camel-case "dashed-words") ;; => "dashedWords"
   (s-lower-camel-case "under_scored_words") ;; => "underScoredWords"
   

см. Больше примеров в репо.