Расширение макроса схемы: вложение let-синтаксиса в define-синтаксис - PullRequest
Новая
       50

Расширение макроса схемы: вложение let-синтаксиса в define-синтаксис

1 голос
/ 24 января 2012

Я хочу расширить 

(foo x (f n) (f n) (arbitrary) (f n) ...)

в 

(begin (x 'f n) (x 'f n) (arbitrary) (x 'f n) ...)

моя попытка: 

(define-syntax foo
  (syntax-rules ()
    ((_ l a ...)
     (let-syntax ((f (syntax-rules ()
                       ((_ n) (l (quote f) n)))))
       (begin a ...)))))

(define (x t1 t2) (cons t1 t2))   ;; for example only
(define (arbitrary) (cons 'a 'b)) ;; for example only
(foo x (f 1) (f 2) (arbitrary) (f 3))

Используя макро-шагер, я вижу, что первая стадия макроса расширяется до 

(let-syntax ((f (syntax-rules () ((_ n) (x 'f n)))))
  (begin (f 1) (f 2) (arbitrary) (f 3)))

Который при оценке в отдельности работает отлично, но при выполнении в целом я получаю ошибку о том, что f является неопределенным идентификатором. Я предполагаю, что это проблема в области видимости, возможен ли этот тип расширения макроса?

1 Ответ

3 голосов
/ 24 января 2012

Да, вам нужно получить f из где-то - ваш макрос просто создает его, и поэтому он не виден пользователям foo.Когда вы считаете, что вам нужно получить его откуда-то, возникает вопрос, откуда вы это получите?Вот исправленная версия вашего кода, которая предполагает, что это первое, что есть во второй подчиненной форме foo: 

(define-syntax foo
  (syntax-rules ()
    [(_ l (f a) more ...)
     (let-syntax ([f (syntax-rules ()
                       [(_ n) (l 'f n)])])
       (list (f a) more ...))]))

(define (x t1 t2) (cons t1 t2))
(define (arbitrary) (cons 'a 'b))
(foo x (f 1) (f 2) (arbitrary) (f 3))

(я также расширил ее до list, чтобы увидеть, что все формыпреобразуется.)

Однако, если вы хотите, чтобы глобальный вид f использовался внутри foo, то вам действительно нужно сделать именно это: определить глобальный f.Вот ограниченный способ сделать это: 

;; no body => using `f' is always an error
(define-syntax f (syntax-rules ()))

(define-syntax foo
  (syntax-rules ()
    [(_ l a ...) (list (foo-helper l a) ...)]))
(define-syntax foo-helper
  (syntax-rules (f) ; match on f and transform it
    [(_ l (f n)) (l 'f n)]
    [(_ l a)     a]))

(define (x t1 t2) (cons t1 t2))
(define (arbitrary) (cons 'a 'b))
(foo x (f 1) (f 2) (arbitrary) (f 3))

Основное ограничение в этом состоит в том, что он будет работать, только если одна из форм a использует f - но он не будет работать, еслионо вложено в выражение.Например, это приведет к синтаксической ошибке: 

(foo x (f 1) (f 2) (arbitrary)
       (let ([n 3]) (f n)))

Вы можете себе представить усложнение foo-helper и заставить его рекурсивно сканировать свои входные данные, но это скользкий уклон, в который вы не хотите входить.(Вам нужно будет сделать особые случаи для таких мест, как внутри quote, в привязке и т. Д.)

Чтобы решить эту проблему в Racket (и недавно в Guile), используйте параметр синтаксиса .Думайте об этом как о привязке f к тому же бесполезному макросу, используя define-syntax-parameter, а затем используйте syntax-parameterize, чтобы «настроить» его значение внутри foo на макросэто делает преобразование, которое вы хотите.Вот как это выглядит: 

;; needed to get syntax parameters
(require racket/stxparam)

;; same useless definition, but as a syntax parameter
(define-syntax-parameter f (syntax-rules ()))

(define-syntax foo
  (syntax-rules ()
    [(_ l a ...)
     ;; adjust it inside these forms
     (syntax-parameterize ([f (syntax-rules ()
                                [(_ n) (l 'f n)])])
       (list a ...))]))

(define (x t1 t2) (cons t1 t2))
(define (arbitrary) (cons 'a 'b))
(foo x (f 1) (f 2) (arbitrary)
       (let ([n 3]) (f n)))
...