Можно ли объявить строковый тип с ограниченной длиной, который не начинается с 0/1?

Question

В Delphi можно объявлять поддиапазоны для целочисленных значений.Например:

type
  myInt = 2..150

Что ограничивает значения типа myInt значениями от 2 до 150. Но что, если я хочу ограничить длину строки?

Если я напишу:

type 
  myString = string [150]

Я объявляю mystring длиной 150 байт и ограничиваю длину от 0, 1, 2 и т. Д. До 150. Но как я ограничиваю длину, например, от 2 до 150?Конечно, я могу проверить длину строки и вызвать исключение, но включает ли Delphi какой-то синтаксис, специфичный для этой ситуации, похожий по стилю на поддиапазоны?

Это, очевидно, не работает, но я бы хотел что-тонапример:

type
  myString = string[2..150] 

Если это невозможно, тогда я могу просто проверить длину, повысить исключение и т. д.

---

, попробовав этот код:

var
 str1, str2, str3: TRestrictedString;
begin
  str1.Create(2, 5, 'pp');
  str2.Create(2, 5, 'aaaa');
  str3.Create(2, 10, str1 + str2);
  writeln (str3.getstring)
end

или:

var
 str1, str2, str3: TRestrictedString;
begin
  str1.Create(2, 5, 'pp');
  str2.Create(2, 5, 'aaaa');
  str3.Create(2, 10);
  str3.SetString(str1 + str2);
  writeln (str3.getstring)
end

или:

var
 str1, str2, str3: TRestrictedString;
begin
  str1.Create(2, 5, 'pp');
  str2.Create(2, 5, 'aaaa');
  str3.Create(2, 10);
  str3 := str1 + str2;
  writeln(str3.GetString);
end

Все они вызывают исключение.Возможно ли это решить?Для нескольких операций над строкой необходимо разделить функцию на несколько частей?В конструктор лучше добавить проверку, что minlength < maxlength?Если я установлю minlength > maxlength, это вызовет исключение.

Answer 1

Я бы сделал

type
  TRestrictedString = record
  strict private type
    TBounds = record
      MinLength,
      MaxLength: integer;
    end;
  strict private
    FStr: string;
  public
    Bounds: TBounds;
    procedure SetString(const AString: string);
    function GetString: string;
    constructor Create(AMinLength, AMaxLength: integer); overload;
    constructor Create(AMinLength, AMaxLength: integer; const AString: string); overload;
    constructor Create(const AString: string); overload;
    class operator Implicit(S: string): TRestrictedString;
    class operator Implicit(S: TRestrictedString): string;
    class operator Equal(const A, B: TRestrictedString): boolean;
    class operator NotEqual(const A, B: TRestrictedString): boolean;
    class operator Add(const A, B: TRestrictedString): TRestrictedString;
  end;

{ TRestrictedString }


constructor TRestrictedString.Create(AMinLength, AMaxLength: integer);
begin
  Bounds.MinLength := AMinLength;
  Bounds.MaxLength := AMaxLength;
  FStr := '';
end;

constructor TRestrictedString.Create(AMinLength, AMaxLength: integer;
  const AString: string);
begin
  Bounds.MinLength := AMinLength;
  Bounds.MaxLength := AMaxLength;
  SetString(AString);
end;

class operator TRestrictedString.Add(const A,
  B: TRestrictedString): TRestrictedString;
begin
  result.Bounds := A.Bounds;
  result.SetString(A.GetString + B.GetString);
end;

constructor TRestrictedString.Create(const AString: string);
begin
  Bounds.MinLength := 0;
  Bounds.MaxLength := MaxInt;
  FStr := AString;
end;

class operator TRestrictedString.Equal(const A, B: TRestrictedString): boolean;
begin
  result := A.GetString = B.GetString;
end;

function TRestrictedString.GetString: string;
begin
  result := FStr;
end;

class operator TRestrictedString.Implicit(S: TRestrictedString): string;
begin
  result := S.GetString;
end;

class operator TRestrictedString.NotEqual(const A,
  B: TRestrictedString): boolean;
begin
  result := A.GetString <> B.GetString;
end;

class operator TRestrictedString.Implicit(S: string): TRestrictedString;
begin
  result.Create(S);
end;

procedure TRestrictedString.SetString(const AString: string);
begin
  with Bounds do
    if (length(AString) < MinLength) or (length(AString) > MaxLength) then
      raise Exception.Create('Invalid length of string.');
  FStr := AString;
end;

Теперь вы можете делать очень естественные вещи, как

procedure TForm1.Button1Click(Sender: TObject);
var
  str: TRestrictedString;
begin
  str.Create(5, 10);         // Create a string w/ length 5 to 10 chrs
  str.SetString('Testing!'); // Assign a compatible string
  ShowMessage(str);          // Display the string
end;

Вы также можете сделать просто

str.Create(5, 10, 'Testing!');
ShowMessage(str);

Вы можете добавитьСтрока обычным способом:

var
  s1, s2, s3: TRestrictedString;
begin
  s1.Create(2, 10, 'Hi ');
  s2.Create(2, 10, 'there!');
  s3 := s1 + s2;
  ShowMessage(s3);
end;

или даже

var
  s1, s3: TRestrictedString;
begin
  s1.Create(2, 10, 'Hi ');
  s3 := s1 + 'there!';
  ShowMessage(s3);

Когда вы добавите два TRestrictedString s, или один TRestrictedString и a string, результат будет иметьтакое же ограничение как первый операнд.Вы можете попробовать

var
  str: TRestrictedString;
begin
  str.Create(5, 10);
  str.SetString('Testing!');
  str := str + '!!';
  ShowMessage(str);

, который будет работать, но не

var
  str: TRestrictedString;
begin
  str.Create(5, 10);
  str.SetString('Testing!');
  str := str + '!!!';
  ShowMessage(str);

Просто знайте, что назначение a string для TRestrictedString также назначит«границы» строки, то есть TRestrictedString будет иметь границы, установленные на 0 и MaxInt.Таким образом, независимо от того, как ограничено s: TRestrictedString, назначение s := 'some string' всегда будет работать.

Обновление : Крис Роллистон использовал этот ответ как вдохновение для очень интересной статьи .