Кассандра: получить через Perl

Question

Cassandra 1.0.6
Thrift 0.8

Я записал ~ 120K значений в мои узлы Cassandra, используя Perl.У рассматриваемой семьи ColumnFamily «активность» есть два индекса: «ValTypeA» и «ValTypeB».Если я получаю доступ к БД через cassandra-cli, я могу вводить команды типа «получить действия, где ValTypeA = 10;»и получить некоторые данные.

Вопрос -> как мне перевести это действие в Perl?

Answer 1

FWIW: ответ - «индексированный фрагмент».В Perl так:

#!/usr/bin/perl -w

use strict;
use warnings;

# Change for your environment
use lib '/vol2/users/progs/perl/cassandra_lib';
use lib '/usr/local/src/thrift-0.8.0/lib/perl/lib';
use Cassandra::Cassandra;
use Cassandra::Constants;
use Cassandra::Types;

use Thrift;
use Thrift::BinaryProtocol;
use Thrift::Socket;
use Thrift::FramedTransport;

use Data::Dumper;


# localhost and 9160 are default in storage conf for rpc listener
my $socket = new Thrift::Socket( '10.127.56.42', 9160 );
my $transport = new Thrift::FramedTransport( $socket, 1024, 1024 );
my $protocol = new Thrift::BinaryProtocol( $transport );
my $client = new Cassandra::CassandraClient( $protocol );

eval {
   $transport->open();
   my $keyspace = 'some_data';

   # ColumnParent tells the API the ColumnFamily or SuperColumn we're working on
   my $column_parent     = new Cassandra::ColumnParent({ column_family => "activity" });
   my $consistency_level = Cassandra::ConsistencyLevel::ONE;

   $client->set_keyspace($keyspace);

   my $slice_range = new Cassandra::SliceRange();
   $slice_range->{start} = "";
   $slice_range->{finish} = "";

   my $slice_predicate = new Cassandra::SlicePredicate();
   $slice_predicate->{slice_range} = $slice_range;

   my $index_expression0 = new Cassandra::IndexExpression();
   $index_expression0->{ column_name } = 'ValTypeA';
   $index_expression0->{ op } = Cassandra::IndexOperator::EQ;
   $index_expression0->{ value } = 13;

   my $index_expression1 = new Cassandra::IndexExpression();
   $index_expression1->{ column_name } = 'ValTypeB';
   $index_expression1->{ op } = Cassandra::IndexOperator::EQ;
   $index_expression1->{ value } = '2011-12-26 15:43:34';


   my $index_clause = new Cassandra::IndexClause();
   $index_clause->{ expressions } = [ $index_expression0, $index_expression1 ];
   $index_clause->{ start_key } = '';


   my $result = $client->get_indexed_slices( $column_parent, $index_clause, $slice_predicate, $consistency_level );

print Dumper( $result );   
};

if( $@ )
{
    print Dumper( $@ );
}