подсчитать количество слов в узле xml, используя xsl

Question

Вот пример XML-документа.

<root>
  <node> count the number of words </node>
</root>

Для этого примера я хочу подсчитать количество слов в узле "" в xslt.

Вывод будет как Number ofwords :: 5

Есть идеи для этого?

Ваш (Dimitre Novatchev) код работает нормально для вышеупомянутого xml.Ваш код будет работать для следующего xml?

<root>

<test>
   <node> pass pass </node>
</test>

  <test>
      <node> fail pass fail </node>
  </test>

  <test>
      <node> pass pass fail </node>
  </test>

 </root>

вывод будет следующим: общее количество слов в узле "узел": 8

Update3 ::

Этот код прекрасно работает для вышеупомянутого документа XML.Предположим, что

<root>
<test>
   <node> pass pass </node>
   <a> value </a>
   <b> value </b>
</test>

  <test>
      <node> fail fail </node>
      <b> value </b>
  </test>

  <test>
      <node> pass pass</node>
      <a> value </a>
  </test>
 </root>

Но ваш код подсчитывает количество слов во всем документе.Я хочу посчитать количество слов только в узле типа "узел".Вывод наподобие

Количество слов в "узле" :: 6 Всего проходов :: 4 Всего ошибок :: 2

Спасибо Sathish

Answer 1

Используйте этот однострочный XPath :

  string-length(normalize-space(node)) 
- 
  string-length(translate(normalize-space(node),' ','')) +1

Вот краткая проверка с использованием XSLT :

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>

 <xsl:template match="/*">
  <xsl:value-of select=
   " string-length(normalize-space(node))
    -
     string-length(translate(normalize-space(node),' ','')) +1"/>
 </xsl:template>
</xsl:stylesheet>

Когда это преобразование применяется к предоставленному XML-документу :

<root>
    <node> count the number of words </node>
</root>

, требуется требуемый, правильный результат:

5

Объяснение : Использованиестандартных функций XPath normalize-space(), translate() и string-length().

Update1 :

ОП спросил:

"Ваш (Димитр Новатчев) код работает нормально для вышеупомянутого xml. Будет ли ваш код работать для следующего xml? "

<root>
  <test>
      <node> pass pass </node>
  </test>
  <test>
      <node> fail pass fail </node>
  </test>
  <test>
      <node> pass pass fail </node>
  </test>
</root>

Ответ : Можно использовать тот же подход:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="/">
        <xsl:value-of select=
        "string-length(normalize-space(.))
        -
         string-length(translate(normalize-space(.),' ','')) +1
         "/>
    </xsl:template>
</xsl:stylesheet>

Когда это преобразование используется во вновь предоставленном XML-документе (см. Выше), будет получен требуемый правильный ответ :

8

Update2 : OP затем спросил вкомментарий:

"Могу ли я сравнить словав узле с некоторым словом по умолчанию.Рассмотрим узел, содержащий значение "pass pass fail".Я хочу рассчитать количество проходов и количество неудач.Нравится pass=2 fail=1.Является ли это возможным?Помоги мне, человек "

Ответ :

Тот же самый подход работает и с этой модификацией проблемы (хотя в общем случае.хорошая токенизация - спросите меня об этом в новом вопросе, пожалуйста):

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="node">
        pass: <xsl:value-of select=
                "string-length()
                -
                 string-length(translate(.,'p',''))
         "/>
<xsl:text/>     fail: <xsl:value-of select=
                "string-length()
                -
                 string-length(translate(.,'f',''))
         "/>
    </xsl:template>
</xsl:stylesheet>

Когда это преобразование применяется к последнему XML-документу (см. выше), создается искомое правильное:

    pass: 2     fail: 0
    pass: 1     fail: 2
    pass: 2     fail: 1

Answer 2

в xslt Я думаю, вам нужно будет обработать, чтобы удалить любой двойной интервал, а затем подсчитать оставшиеся пробелы, чтобы найти ответ.хотя я уверен, что есть лучшие способы!

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl">
<xsl:output method="xml" indent="yes"/>

<xsl:template match="root">
        <xsl:for-each select="node">
                <xsl:call-template name="word-count">
                        <xsl:with-param name="data" select="normalize-space(.)"/>
                        <xsl:with-param name="num" select="1"/>
                </xsl:call-template>
        </xsl:for-each>
</xsl:template>

    <xsl:template name="word-count">
            <xsl:param name="data"/>
            <xsl:param name="num"/>
            <xsl:variable name="newdata" select="$data"/>
            <xsl:variable name="remaining" select="substring-after($newdata,' ')"/>                

            <xsl:choose>
                    <xsl:when test="$remaining">
                            <xsl:call-template name="word-count">
                                    <xsl:with-param name="data" select="$remaining"/>
                                    <xsl:with-param name="num" select="$num+1"/>
                            </xsl:call-template>
                    </xsl:when>
                    <xsl:when test="$num = 1">
                            no words...
                    </xsl:when>
                    <xsl:otherwise>
                            <xsl:value-of select="$num"/>
                    </xsl:otherwise>
            </xsl:choose>                
    </xsl:template>

</xsl:stylesheet>

этот пример кода работает, исправьте его из таблицы стилей, которая у меня была, которая обрабатывала какой-то устаревший код, в полезный вывод html!

обновленный код для улучшенияот ошибок, перехватывает дублирующиеся пробелы, а также перехватывает пустые узлы:>

Обновлено для решения дополнительной проблемы!

 <xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
        <xsl:output method="html"/>

        <xsl:template match="root">
        <xsl:for-each select="test/node">
                <xsl:call-template name="word-count">
                        <xsl:with-param name="data" select="normalize-space(.)"/>
                        <xsl:with-param name="num" select="1"/>
                        <xsl:with-param name="pass" select="0"/>
                        <xsl:with-param name="fail" select="0"/>
                </xsl:call-template>
        </xsl:for-each>
</xsl:template>

<xsl:template name="word-count">
        <xsl:param name="data"/>
        <xsl:param name="num"/>
        <xsl:param name="fail"/>
        <xsl:param name="pass"/>
        <xsl:variable name="newdata" select="$data"/>
        <xsl:variable name="first">
                <xsl:choose>
                        <xsl:when test="substring-before($newdata,' ')">
                                <xsl:value-of select="substring-before($newdata,' ')"/>  
                        </xsl:when>
                        <xsl:otherwise>
                                <xsl:value-of select="$newdata"/>
                        </xsl:otherwise>
                </xsl:choose>
        </xsl:variable> 
        <xsl:variable name="remaining" select="substring-after($newdata,' ')"/>
        <xsl:variable name="newpass">
                <xsl:choose>
                        <xsl:when test="$first='pass'">
                                <xsl:value-of select="$pass+1"/>
                        </xsl:when>
                        <xsl:otherwise>
                                <xsl:value-of select="$pass"/>
                        </xsl:otherwise>
                </xsl:choose>
        </xsl:variable>        
        <xsl:variable name="newfail">
                <xsl:choose>
                        <xsl:when test="$first='fail'">
                                <xsl:value-of select="$fail+1"/>
                        </xsl:when>
                        <xsl:otherwise>
                                <xsl:value-of select="$fail"/>
                        </xsl:otherwise>
                </xsl:choose>
        </xsl:variable>

        <xsl:choose>
                <xsl:when test="$remaining">
                        <xsl:call-template name="word-count">                        
                                <xsl:with-param name="data" select="$remaining"/>
                                <xsl:with-param name="num" select="$num+1"/>
                                <xsl:with-param name="pass" select="$newpass"/>
                                <xsl:with-param name="fail" select="$newfail"/>
                        </xsl:call-template>
                </xsl:when>
                <xsl:when test="$num = 1">
                        it was empty
                </xsl:when>
                <xsl:otherwise>
                        <xsl:value-of select="$first"/>
                        wordcount:<xsl:value-of select="$num"/>
                        pass:<xsl:value-of select="$newpass"/>
                        fail:<xsl:value-of select="$newfail"/><br/>
                </xsl:otherwise>
        </xsl:choose>
</xsl:template>
</xsl:stylesheet>

Answer 3

Вот XSLT, который я только что построил, основываясь на ответе Димитра Новатчева выше. Он считает слова в корне / data / value (это для файлов ресурсов .NET [.RESX]), но вы можете легко его адаптировать.

Относительно используемой им функции набора узлов см. URL, упомянутый в XSLT, о том, как это сделать с процессорами с поддержкой EXSLT или другими, которые изначально поддерживают эту функцию (использование пространства имен msxml для .NET / MSXML, может легко изменить это, чтобы сослаться на EXSLT и т. д.)

<?xml version="1.0" encoding="UTF-8"?>

<!--
Filename: ResX_WordCount.xsl
Version: 20141006
-->

<xsl:stylesheet 
  version="1.0"
  xmlns:msxsl="urn:schemas-microsoft-com:xslt"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  >

  <xsl:output method="text" indent="yes"/>

  <xsl:template match="/root">
    <!-- see http://www.xml.com/pub/a/2003/07/16/nodeset.html -->
    <xsl:variable name="WordCounts">
      <xsl:for-each select="data/value">
        <!-- see /7937040/podschitat-kolichestvo-slov-v-uzle-xml-ispolzuya-xsl -->
        <count>
          <xsl:value-of select="string-length(normalize-space(text())) - string-length(translate(normalize-space(text()),' ','')) + 1"/>
        </count>
      </xsl:for-each>
    </xsl:variable>

    <xsl:value-of select="sum(msxsl:node-set($WordCounts)/count)"/>
  </xsl:template>

</xsl:stylesheet>