Как отобразить общее количество строк в модельном ряду Emacs

Question

Моделин Emacs по умолчанию показывает только текущий номер строки и ее процент по отношению к общему количеству строк.Как мне сделать так, чтобы он показывал итоговую сумму?

Answer 1

Это может быть немного сложно, потому что если вы постоянно обновляете счетчик строк и имеете большой буфер, это может сделать Emacs несколько не отвечающим, так как он считает строки снова и снова. Я написал это для ленивого подхода к подсчету: он делает это только при первом чтении файла или после его сохранения / возврата. Если буфер изменен, он не зависит от количества строк, он просто не отображается, пока вы не сохраните снова.

(defvar my-mode-line-buffer-line-count nil)
(make-variable-buffer-local 'my-mode-line-buffer-line-count)

(setq-default mode-line-format
              '("  " mode-line-modified
                (list 'line-number-mode "  ")
                (:eval (when line-number-mode
                         (let ((str "L%l"))
                           (when (and (not (buffer-modified-p)) my-mode-line-buffer-line-count)
                             (setq str (concat str "/" my-mode-line-buffer-line-count)))
                           str)))
                "  %p"
                (list 'column-number-mode "  C%c")
                "  " mode-line-buffer-identification
                "  " mode-line-modes))

(defun my-mode-line-count-lines ()
  (setq my-mode-line-buffer-line-count (int-to-string (count-lines (point-min) (point-max)))))

(add-hook 'find-file-hook 'my-mode-line-count-lines)
(add-hook 'after-save-hook 'my-mode-line-count-lines)
(add-hook 'after-revert-hook 'my-mode-line-count-lines)
(add-hook 'dired-after-readin-hook 'my-mode-line-count-lines)

Вы, возможно, захотите настроить mode-line-format на свой вкус, конечно, выше я лично предпочитаю.