Добавление параметров TEXT в ADODB.Command без использования хранимых процедур - PullRequest
Новая
       40

Добавление параметров TEXT в ADODB.Command без использования хранимых процедур

3 голосов
/ 13 декабря 2011

Мне нужно выполнить INSERT s для таблицы SQL Server 2008 с некоторыми столбцами TEXT, и я не могу иметь параметр ADODB.Command для работающего столбца TEXT.

Таблица определяется как: 

CREATE TABLE dbo.Test (
    TestId INT NOT NULL IDENTITY(1, 1)
    , CreationDate DATETIME NOT NULL
    , Value TEXT NOT NULL
    , CONSTRAINT pkTest PRIMARY KEY (TestId)
)

Тестовая страница выглядит следующим образом: 

<!-- METADATA TYPE="typelib" NAME="Microsoft ActiveX Data Objects 2.8 Library" UUID="{2A75196C-D9EB-4129-B803-931327F72D5C}" VERSION="2.8" -->
<%@ CODEPAGE = 65001 LCID = 1040 %>
<%
    Option Explicit
    Response.Clear
    Response.CharSet = "UTF-8"
    Response.CodePage = 65001
    Response.ContentType = "text/plain"
    Dim i : i = 0
    Dim value : value = ""
    For i = 1 To 10000
        If i Mod 3 = 0 Then
            value = value & "a "
        Else
            value = value & "a"
        End If
    Next
    Dim connection : Set connection = Server.CreateObject("ADODB.Connection")
    connection.CommandTimeout = 5
    connection.ConnectionString = "Server=XXX; Database=XXX; Uid=XXX; Pwd=XXX;"
    connection.ConnectionTimeout = 5
    connection.IsolationLevel = adXactReadUncommitted
    connection.Mode = adModeRead
    connection.Provider = "SQLOLEDB"
    connection.Open
    Dim command : Set command = Server.CreateObject("ADODB.Command")
    command.ActiveConnection = connection
    command.CommandText = "insert into dbo.Test (CreationDate, Value) values (getdate(), ?)"
    command.CommandTimeout = 5
    command.CommandType = adCmdText
    command.Parameters.Append command.CreateParameter("Value", adVarChar, adParamInput, 0, value)
    command.Prepared = True
    command.Execute
    Set command = Nothing
    connection.Close
    Set connection = Nothing
    Response.End
%>

Когда я ее выполняю, я получаю эту ошибку: 

ADODB.Command error '800a0d5d'
Application uses a value of the wrong type for the current operation.
/test/default.asp, line 32

Строка32 - это 

command.Parameters.Append command.CreateParameter("Value", adVarChar, adParamInput, 0, value)

Я попытался изменить параметр Size, но безрезультатно.

Просматривая сеть, я нашел статью базы знаний Майкрософт под названием Как вызывать хранимые процедуры SQL Serverиз ASP интересен пример «Метод 1», поскольку он не объявляет параметры, а читает их с сервера: 

cmd.CommandText = "sp_test"
cmd.CommandType = adCmdStoredProc
cmd.Parameters.Refresh
cmd.Parameters(1) = 11

, поэтому я создал хранимую процедуру для выполнения INSERT: 

CREATE PROCEDURE dbo.TestInsertion (@CreationDate DATETIME, @Value TEXT) AS BEGIN
    SET NOCOUNT ON
    INSERT INTO dbo.Test (CreationDate, Value) VALUES (@CreationDate, @Value)
    SELECT TestId = SCOPE_IDENTITY()
END

и изменил бит ADODB.Command на странице следующим образом: 

Dim command : Set command = Server.CreateObject("ADODB.Command")
command.ActiveConnection = connection
command.CommandText = "dbo.TestInsertion"
command.CommandTimeout = 5
command.CommandType = adCmdStoredProc
command.Parameters.Refresh
command.Parameters(1).Value = Date
command.Parameters(2).Value = value
command.Prepared = True
command.Execute
Set command = Nothing

, и это сработало.

Можно ли указать TEXT параметр для ADODB.Command s в классическом ASP без использования хранимых процедур?

1 Ответ

8 голосов
/ 13 декабря 2011

Попытайтесь передать adLongVarChar константу для типа данных text .

С adLongVarChar вам также необходимо указать размер value, в противном случае вы получите Parameter object is improperly defined. Inconsistent or incomplete information was provided. ошибка. 

command.Parameters.Append command.CreateParameter("Value", adLongVarChar, adParamInput, Len(value), value)

См. Некоторые сопоставления типов данных ADO .

...