Хранимая процедура SQL Server добавляет два объявленных значения для общего количества

Question

Вот что я использовал, используя две объявленные переменные в хранимой процедуре:

SET @QuestionPoints = (SELECT SUM(points) 
                       FROM   tb_responses 
                       WHERE  userid = @UserId 
                              AND id = @ID) 
SET @EventPoints =(SELECT SUM(dbo.tb_events.points) 
                   FROM   dbo.tb_attendance 
                          INNER JOIN dbo.tb_events 
                            ON dbo.tb_attendance.eventid = dbo.tb_events.dbid 
                   WHERE  dbo.tb_attendance.userid = @UserID 
                          AND dbo.tb_attendance.didattend = 'Y' 
                          AND dbo.tb_events.id = @ID) 

Как я могу добавить @QuestionPoints и @EventPoints вместе, чтобы получить общее количество очков? Могу ли я просто добавить их, используя «+» и присвоить третью объявленную переменную, или иметь один общий оператор?

Спасибо

Джеймс

Answer 1

Если вам больше не нужны две компонентные переменные, вы можете (повторно) использовать одну из переменных:

SET @QuestionPoints = ...
SET @EventPoints = ...
SET @QuestionPoints = @QuestionPoints + @EventPoints 

Будьте осторожны при добавлении SUM(), потому что они могут быть NULL. 20 + null => null. При необходимости используйте ISNULL, например

SET @QuestionPoints = isnull(@QuestionPoints, 0) + isnull(@EventPoints, 0)

Если они вам все еще нужны, вы можете объявить третий.

DECLARE @TotalPoints float  --- or numeric or whatever the type should be
SET @TotalPoints = @QuestionPoints + @EventPoints 

Вы можете даже пропустить отдельные переменные

SET @QuestionPoints = (SELECT SUM(POINTS) FROM tb_Responses WHERE UserID = @UserId AND ID = @ID)
                      +
                      (SELECT SUM(dbo.tb_Events.Points) FROM  dbo.tb_Attendance INNER JOIN   dbo.tb_Events ON dbo.tb_Attendance.EventID = dbo.tb_Events.dbID WHERE dbo.tb_Attendance.UserID = @UserID AND dbo.tb_Attendance.DidAttend = 'Y' AND dbo.tb_Events.ID = @ID)

Answer 2

Вы можете сделать это в одном выражении

Set @Total =    (
                Select Sum( Z.points )
                From    (
                        Select points
                        From tb_responses
                        Where userid = @UserId
                            And Id = @Id
                        Union All
                        Select E.points
                        From dbo.tb_attendance As A
                            Join dbo.tb_events As E
                                On E.dbid = A.eventid
                        Where A.userid = @UserId
                            And A.didattend = 'Y'
                            And E.Id = @ID
                        ) As Z
                )

Answer 3

Если вам нужно, чтобы @QuestionPoints и @EventPoints сохранили свои текущие значения, тогда да, вам нужна третья переменная:

DECLARE @totalPoints INT
SET @totalPoints = @QuestionPoints + @EventPoints

Если вам не нужно, чтобы они сохраняли одно и то же значение, тогда выможно просто перезаписать один из них:

SET @QuestionPoints = @QuestionPoints + @EventPoints

Или, в последних версиях SQL:

SET @QuestionPoints += @EventPoints