F # Установить с помощью пользовательского класса - PullRequest
Новая
       27

F # Установить с помощью пользовательского класса

4 голосов
/ 22 мая 2009

Я пытаюсь использовать операции Set с классом, который у меня есть. Каждый экземпляр этого класса имеет уникальный идентификатор. Нужно ли реализовывать интерфейс System.IComparable, и если да, то как мне это сделать? 

type SomeClass(id : int) =
    member this.ID = id

let someSet = Set.of_list [SomeClass(1); SomeClass(2)]
let test = someSet.Contains(SomeClass(2))

Ответы [ 3 ]

4 голосов
/ 22 мая 2009

Вот реализация, которая должна работать: 

type SomeClass(id : int) =    
    member this.ID = id
    override this.Equals(o) =
        match o with
        | :? SomeClass as sc -> this.ID = sc.ID
        | _ -> false
    override this.GetHashCode() =
        id.GetHashCode()
    interface System.IComparable with
        member this.CompareTo(o) =
            match o with
            | :? SomeClass as sc -> compare this.ID sc.ID
            | _ -> -1
1 голос
/ 22 мая 2009

Что касается комментария к моему другому ответу, вы можете включить его в базовый класс многократного использования, но я не уверен, что это действительно хорошая идея: 

type EqCompBase<'EqKey, 
        'DerivedType when 'DerivedType :> EqCompBase<'EqKey,'DerivedType> >
        (id : 'EqKey) =    
    member this.ID = id
    override this.Equals(o) =
        match o with
        | :? EqCompBase<'EqKey, 'DerivedType> as sc -> this.ID = sc.ID
        | _ -> false
    override this.GetHashCode() =
        id.GetHashCode()
    interface System.IComparable with
        member this.CompareTo(o) =
            match o with
            | :? EqCompBase<'EqKey, 'DerivedType> as sc -> compare this.ID sc.ID
            | _ -> -1

type SomeClass(id : int, otherFieldThatDoesNotMatterForEquality : string) =
    inherit EqCompBase<int, SomeClass>(id)

let someSet = Set.of_list [SomeClass(1,"yadda"); SomeClass(2,"blah")]
let test = someSet.Contains(SomeClass(2,"foo"))
printfn "%A" test  // true
1 голос
/ 22 мая 2009

Я полагаю, вам нужно будет внедрить IComparer<T>, чтобы сработали определенные понимания (например, Set.of_list). ( Не IComparable<T>, который имеет тенденцию менее широко использоваться - хотя я могу ошибаться.)

В этом сообщении в блоге в общих чертах объясняется, как реализовать интерфейсы в F #. Он также включает в себя конкретный пример типа, реализующего IComparer<T>, что на самом деле не так просто, как вы можете надеяться. 

type Comp() =  
    interface IComparer with  
        member x.Compare(a, b) = 0  
    member x.Compare(a, b) = (x :> IComparer).Compare(a,b)

Дайте мне знать, если это работает для вас. У меня есть некоторые подозрения, что вам может понадобиться реализовать IEqualityComparer<T> вместо этого, поскольку именно на этом основаны методы расширения набора LINQ, насколько я знаю. (Это действительно путает со всеми этими интерфейсами для сравнения в BCL!)

...