Получить список самых коротких текстов из списка узлов

Question

Я хотел бы получить список элементов и типов узлов с кратчайшим текстом. Использование xslt / xpath.

У меня есть следующий пример xml:

<a>
  <b>
    <item>short</item>
    <item>longest</item>
    <item type="x">longest text</item>
    <item type="x">short text</item>
    <item type="y">text</item>
  </b>
</a>

Это то, что я имею до сих пор

<xsl:template match="ns:item">
  <xsl:variable name="type">
    <xsl:choose>
       <xsl:when test="@type">
         <xsl:value-of select="@type" />
       </xsl:when>
       <xsl:otherwise>default</xsl:otherwise>
    </xsl:choose>
  </xsl:variable>
  <xsl:if test="position() = 1">{</xsl:if>
  "<xsl:value-of select='$type' />" : "<xsl:value-of select='.' />"
  <xsl:if test="position() != last()">,</xsl:if>
  <xsl:if test="position() = last()">}</xsl:if>  
</xsl:template>

Как отфильтровать весь результат, кроме самого короткого, из результата?

Вывод должен выглядеть примерно так:

{ "default": "short",
 "x" : "short text",
 "y" : "text" }

Поскольку я использую xslt / xpath только изредка и только для очень простых вещей, я надеюсь, что кто-то может мне помочь.

Answer 1

Решение XSLT 2.0 :

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>
    <xsl:variable name="vQ">"</xsl:variable>
 <xsl:template match="/a/b">
    <xsl:text>{ </xsl:text>
     <xsl:for-each-group select="item" group-by="string(@type)">
      <xsl:variable name="vShortest" select=
      "current-group()[string-length(.) eq min(current-group()/string-length(.))]
      " />
      <xsl:variable name="vNotLast" select="not(position() eq last())"/>
      <xsl:variable name="vType" select=
      "'default'[not($vShortest/@type)],$vShortest/@type"/>
      <xsl:value-of select=
      "concat($vQ,$vType,$vQ,':', $vQ,$vShortest,$vQ, ',&#xA;'[$vNotLast])"/>
     </xsl:for-each-group>
      <xsl:text> }</xsl:text>
 </xsl:template>
</xsl:stylesheet>

при применении к предоставленному документу XML :

<a>
    <b>
        <item>short</item>
        <item>longest</item>
        <item type="x">longest text</item>
        <item type="x">short text</item>
        <item type="y">text</item>
    </b>
</a>

требуемыйрезультат получается:

{ "default":"short",
"x":"short text",
"y":"text" }

Answer 2

Я бы сгруппировался (с мюнхенской группировкой http://www.jenitennison.com/xslt/grouping/index.xml), а затем взял бы самый короткий элемент в каждой группе (просто отсортировав по длине и взяв первый элемент):

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">

  <xsl:output method="text"/>

  <xsl:key name="k1" match="item" use="string(@type)"/>

  <xsl:template match="/">
    <xsl:text>{ </xsl:text>
    <xsl:apply-templates 
      select="a/b/item[generate-id() = generate-id(key('k1', string(@type))[1])]"/>
    <xsl:text> }</xsl:text>
  </xsl:template>

  <xsl:template match="item">
    <xsl:if test="position() &gt; 1"><xsl:text>,&#10;</xsl:text></xsl:if>
    <xsl:for-each select="key('k1', string(@type))">
      <xsl:sort select="string-length(.)" data-type="number"/>
      <xsl:if test="position() = 1">
        <xsl:variable name="type">
          <xsl:choose>
            <xsl:when test="@type">
              <xsl:value-of select="@type"/>
            </xsl:when>
            <xsl:otherwise>default</xsl:otherwise>
          </xsl:choose>
        </xsl:variable>
        <xsl:text>"</xsl:text>
        <xsl:value-of select="$type"/>
        <xsl:text>" : "</xsl:text>
        <xsl:value-of select="."/>
        <xsl:text>"</xsl:text>
      </xsl:if>
    </xsl:for-each>
  </xsl:template>

</xsl:stylesheet>

Свходное значение

<a>
  <b>
    <item>short</item>
    <item>longest</item>
    <item type="x">longest text</item>
    <item type="x">short text</item>
    <item type="y">text</item>
  </b>
</a>

результат

{ "default" : "short",
"x" : "short text",
"y" : "text" }