Как я могу динамически получить список методов в (не Moose) библиотеке Perl?

Question

Как я могу динамически получить список методов в (не Moose) библиотеке Perl?

Я пытаюсь обернуть не Moose класс в класс Moose, используя делегирование. В настоящее время я жестко программирую список методов, которые я делегирую. Это не имеет большого значения, но мне было интересно, есть ли более элегантный способ.

Answer 1

Невозможно.Нет никакого способа отличить, является ли подпрограмма методом или нет.Если вы согласны с перечислением сабов вместо этого, вы можете использовать

grep exists(&{ 'Foo::Bar::'.$_ }), keys %Foo::Bar::

Конечно, это не сканирует дерево наследования.Если вы хотите это сделать, вы можете получить список пакетов для сканирования, используя

mro::get_linear_isa('Foo::Bar')

Answer 2

Альтернативой ответу ikegami является использование модуля Package::Stash. Его метод list_all_symbols даст вам все вложенные имена в данном пакете. Вот пример:

perl -MPackage::Stash -E "say for Package::Stash->new('Package::Stash')->list_all_symbols('CODE')"

Answer 3

Ну, строго говоря, невозможно различить подводные лодки и методы, как упомянул икегами .

Но если вы проявите творческий подход, вы всегда можете использовать PadWalker's peek_sub и closed_over, чтобы в некотором роде отличить сабвуфер от метода, хотя, конечно, возможны как ложные срабатывания, так и ложные отрицания:

use strict;
use warnings;

use PadWalker;

my $self;

sub test_sub
{
    my $x = shift;
    print $self;
}

sub test_method
{
    my $self = shift;
}

sub is_method
{
    my $coderef = shift;
    my $all = PadWalker::peek_sub($coderef);
    my $closed = PadWalker::closed_over($coderef);
    for my $k (qw($self $me $class)) {
        return 1 if $all->{$k} && !$closed->{$k};
    }
    return 0;
}

print "test_sub: ", is_method(\&test_sub) ?
    "is a method\n" : "is a sub\n";
print "test_method: ", is_method(\&test_method) ?
    "is a method\n" : "is a sub\n";

Получение coderefs оставлено читателю в качестве упражнения.

Answer 4

Если вы уже используете Moose, вы можете использовать Class :: MOP для этого. Я думаю, что Class :: MOP - самый чистый способ, и вы также можете извлечь все методы / функции из наследования. Но, как говорили другие, вы не можете различить метод и функцию.

use Class::MOP;
use Test::More;

my $class = Class::MOP::Class->initialize('Test::More');
my @methods     = $class->get_method_list(); # Only Methods in this Class
my @all_methods = $class->get_all_methods(); # Include all inherited methods

printf "%d functions in Test::More\n", scalar @methods;
printf "%d functions including inheritance\n", scalar @all_methods;

print "methods:     @methods\n\n";
print "all methods: ", join(' ', map({ $_->fully_qualified_name } @all_methods)), "\n";

Эти отпечатки примерно такие:

39 functions in Test::More
49 functions including inheritance
methods:     subtest _whoa cmp_ok isa_ok use_ok isnt _format_stack like _eq_array plan _eval fail _carp done_testing _type diag _is_module_name import_extra eq_array require_ok BAIL_OUT _dne is ok _eq_hash explain todo todo_skip unlike new_ok eq_set pass can_ok eq_hash is_deeply note _equal_nonrefs _deep_check skip
all methods: Exporter::export_fail Test::More::_whoa Test::More::subtest Exporter::export_tags Test::More::cmp_ok Test::More::use_ok Test::More::isa_ok Test::More::_format_stack Test::More::isnt Test::More::like Test::More::_eq_array Test::More::plan Exporter::export Test::More::_eval Test::More::_carp Test::More::fail Test::More::done_testing Test::More::_type Test::More::diag Test::Builder::Module::_strip_imports Test::More::_is_module_name Test::More::import_extra Exporter::as_heavy Test::More::eq_array Test::More::require_ok Exporter::export_to_level Test::More::BAIL_OUT Test::More::_dne Test::More::is Test::More::ok Exporter::export_ok_tags Test::More::explain Test::More::_eq_hash Test::More::todo_skip Test::More::todo Test::More::new_ok Test::More::unlike Test::More::pass Test::More::eq_set Test::More::can_ok Test::More::eq_hash Test::More::is_deeply Test::More::note Test::Builder::Module::import Test::More::_equal_nonrefs Test::More::skip Test::More::_deep_check Exporter::require_version Test::Builder::Module::builder