ActionScript 3: нарезать растровое изображение на листы

Question

У меня есть данные растрового изображения из объекта Loader, и я хотел бы нарезать их на квадраты 32x32 для использования в качестве плиток.Какой самый эффективный способ сделать это?

Answer 1

Я сделал всю работу за вас. Основная идея заключается в использовании функции BitmapData copyPixels, см. Adobe Reference. Он позволяет копировать пиксели из одной области (указанной прямоугольником) в исходном BitmapData, в конкретную точку в целевом BitmapData. Я создал новый BitmapData для каждого квадрата 32x32 и прошел через загруженный объект, чтобы заполнить квадраты с copyPixels.

var imageLoader:Loader;

function loadImage(url:String):void
{
    // Set properties on my Loader object
    imageLoader = new Loader();
    imageLoader.load(new URLRequest(url));
    imageLoader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, imageLoading);
    imageLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, imageLoaded);
}
loadImage("Cow Boy.jpg");//--------->Replace this by your image. I hope you know to specify path. 
function imageLoaded(e:Event):void
{
    // Load Image
    imageArea.addChild(imageLoader);

    var mainImage:BitmapData = new BitmapData(imageArea.width,imageArea.height);
    var tileX:Number = 36; 
    var tileY:Number = 36;
    var bitmapArray:Array;

    var tilesH:uint = Math.ceil(mainImage.width / tileX); // Number  of Columns
    var tilesV:uint = Math.ceil(mainImage.height / tileY);// Number of Rows

    mainImage.draw(imageArea);
    imageArea.x += 500;

    bitmapArray = new Array();

    for (var i:Number = 0; i < tilesH; i++)
    {
        bitmapArray[i] = new Array();
        for (var n:Number = 0; n < tilesV; n++)
        {
            var tempData:BitmapData=new BitmapData(tileX,tileY);
            var tempRect = new Rectangle((tileX * i),(tileY * n),tileX,tileY);
            tempData.copyPixels(mainImage,tempRect,new Point(0,0));
            bitmapArray[i][n]=tempData;
        }
    }

    for (var j:uint =0; j<bitmapArray.length; j++)
    {

        for (var k:uint=0; k<bitmapArray[j].length; k++)
        {

            var bitmap:Bitmap=new Bitmap(bitmapArray[j][k]);
            this.addChild(bitmap);
            bitmap.x = (j+1)* bitmap.width + j*10;
            bitmap.y = (k+1)* bitmap.height + k*10;

        }
    }



}
function imageLoading(e:ProgressEvent):void
{
    // Use it to get current download progress
    // Hint: You could tie the values to a preloader :)
}

Answer 2

Вы можете использовать функцию BitmapData copyPixels, см. Ссылку . Это позволяет копировать пиксели из одной области (указанной прямоугольником) в исходном BitmapData, в конкретный Point в месте назначения BitmapData. По сути, вы можете просто создать новый BitmapData для каждого квадрата 32x32 и пройтись по загруженному объекту, чтобы заполнить квадраты copyPixels.