Запись и воспроизведение аудио в MS Access

Question

Я искал все выше и ниже и нахожусь в отчаянии.Что я пытаюсь сделать, это просто записать звук с микрофона, сохранить его в файл и затем воспроизвести.Вещи, которые я пробовал:

• Запись звука из командной строки.Я нашел пару вариантов, но НИЧЕГО, чтобы я мог приступить к работе.
• http://support.microsoft.com/kb/210067 Я думаю, это будет работать в XP, но не в Vista / 7.
• http://www.experts -exchange.com / Программное обеспечение / Office_Productivity / Office_Suites / MS_Office / Excel / Q_26416850.html (Вы можете получить полную информацию, нажав Здесь , тогда это был 5-й вариант для меня.)Это решение работает без сбоев, но никогда ничего не записывает.

Как я уже сказал, я открыт ко всему, что я могу автоматизировать, используя любые ужасные трюки, о которых кто-либо может подумать.Какие-либо предложения? Давай ТАК, ты можешь снова спасти меня ...: -)

Answer 1

Я знаю, что это старый пост, но я несколько раз приземлялся здесь в поисках решения для записи звука с помощью vba.Наконец-то я нашел решение для http://www.vbarchiv.net, которым я хотел бы поделиться: поместите это в модуль, назовите его sndmodule:

Option Compare Database
Option Explicit

REM found at http://www.vbarchiv.net

Public Declare Function sndPlaySound Lib "winmm.dll" Alias "sndPlaySoundA" _
    (ByVal lpszSoundName As String, ByVal uFlags As Long) As Long

Const SND_SYNC = &H0
Const SND_ASYNC = &H1
Const SND_FILENAME = &H20000

Public Declare Function mciSendString Lib "winmm.dll" _
  Alias "mciSendStringA" ( _
  ByVal lpstrCommand As String, _
  ByVal lpstrReturnString As String, _
  ByVal uReturnLength As Long, _
  ByVal hwndCallback As Long) As Long

Public Enum BitsPerSec
  Bits16 = 16
  Bits8 = 8
End Enum

Public Enum SampelsPerSec
  Sampels8000 = 8000
  Sampels11025 = 11025
  Sampels12000 = 12000
  Sampels16000 = 16000
  Sampels22050 = 22050
  Sampels24000 = 24000
  Sampels32000 = 32000
  Sampels44100 = 44100
  Sampels48000 = 48000
End Enum

Public Enum Channels
  Mono = 1
  Stereo = 2
End Enum

Public Sub play(file As String)
  Dim wavefile
  wavefile = file
  Call sndPlaySound(wavefile, SND_ASYNC Or SND_FILENAME)
End Sub


Public Sub StartRecord(ByVal BPS As BitsPerSec, _
  ByVal SPS As SampelsPerSec, ByVal Mode As Channels)

  Dim retStr As String
  Dim cBack As Long
  Dim BytesPerSec As Long

  retStr = Space$(128)
  BytesPerSec = (Mode * BPS * SPS) / 8
  mciSendString "open new type waveaudio alias capture", retStr, 128, cBack
  mciSendString "set capture time format milliseconds" & _
    " bitspersample " & CStr(BPS) & _
    " samplespersec " & CStr(SPS) & _
    " channels " & CStr(Mode) & _
    " bytespersec " & CStr(BytesPerSec) & _
    " alignment 4", retStr, 128, cBack
  mciSendString "record capture", retStr, 128, cBack
End Sub

Public Sub SaveRecord(strFile)
  Dim retStr As String
  Dim TempName As String
  Dim cBack As Long
  Dim fs, F

  TempName = strFile 'Left$(strFile, 3) & "Temp.wav"
  retStr = Space$(128)
  mciSendString "stop capture", retStr, 128, cBack
  mciSendString "save capture " & TempName, retStr, 128, cBack
  mciSendString "close capture", retStr, 128, cBack

End Sub

В своем коде вы можете использовать его следующим образом:

Private Sub StartRecord_Click()
  sndmodule.StartRecord Bits16, Sampels32000, Mono
End Sub

Private Sub EndRecord_Click()
  sndmodule.SaveRecord "C:\Users\Johanness\Downloads\test.wav"
End Sub

Private Sub Play_Click()
  sndmodule.play "C:\Users\Johanness\Downloads\test.wav"
End Sub

Answer 2

Маби, это поможет:

http://www.ehow.com/how_7889013_use-vba-access-capture-audio.html