Нужно вставить узел при обработке HTML через XSLT

Question

Я конвертирую HTML в XML, используя XSLT 1.0.Вот мой ввод

<table>
<tr id=1>
   <td rowspan=2>
   <td>
</tr>
<tr id=2>
   <td>   
</tr>
</table>

Это обычный код строки в html.Если у меня есть атрибут rowspan в td (id = 1), я должен создать новый элемент td перед уже существующим td в tr (id = 2). Число новых элементов td в последовательном tr зависит от значения rowspan.

Как это сделать в шаблоне xsl (или) в любом пост-процессе после преобразования xslt .. Пожалуйста, помогите мне .. Заранее спасибо ..

Я сделаю это более ясным ..

Таблица 3 * 3.рассмотрим первый столбец в каждой строке, слитый. поэтому мой входной html выглядит следующим образом

<table>
<tr id="1">
    <td  rowspan="3">
         </p>
    </td>
   <td>
      </p>
   </td>
   <td>
      </p>
   </td>
</tr>
<tr id="2">
    <td>
         </p>
   </td>
   <td>
         </p>
   </td>
</tr>
<tr id="3">
   <td> 
         </p>
   </td>
   <td>
         </p>
   </td>
</tr>
</table>

tr с id = 2 & 3 имеет два td, что означает, что первый столбец объединен с первым tr--> td, значение строки которого равно 3 (то есть 3 строки, включая текущую ячейку строки, объединяются).мой результат должен быть

<w:tbl> <!-- represents table -->
<w:tr> <!-- represents table tr-->
  <w:tc>   <!-- represents table td-->
     <w:tcPr>  <!-- represents td style-->
         <w:vMerge w:val="restart"/> <!-- added due to having rowspan attribute-->
      </w:tcPr>
       <w:p/>
  </w:tc>
  <w:tc>
       <w:p/>
  </w:tc>
  <w:tc>
       <w:p/>
  </w:tc>
</w:tr>
<w:tr>
    <w:tc>  <!-- have to add this node in addition-->
          <w:tcPr>  
              <w:vMerge/>
          </w:tcPr>           
          <w:p/>
    </w:tc>
    <w:tc> 
         <w:p/>
    </w:tc>
    <w:tc>
         <w:p/>
    </w:tc>
<w:tr>
<w:tr>
    <w:tc>  <!-- have to add this node in addition-->
          <w:tcPr>  
              <w:vMerge/>
          </w:tcPr>           
          <w:p/>
    </w:tc>
    <w:tc>
          <w:p/>
     </w:tc>
     <w:tc>
          <w:p/>
     </w:tc>
<w:tr>
</w:tbl>

Answer 1

Обновлено: Мой последний подход заключается в подсчете общего количества требуемых ячеек на основе количества ячеек в первой строке и их значений rowspan. Итак, этот вход:

<table>
<tr id="1">
   <td rowspan="3"/>
   <td rowspan="2"/>
   <td/>
</tr>
<tr id="2">
   <td/>   
</tr>
<tr id="3">
   <td rowspan="2"/>
   <td/>   
</tr>
</table>

Должен привести к такому выводу:

<table>
<tr id="1">
   <td rowspan="3"/>
   <td rowspan="2"/>
   <td/>
</tr>
<tr id="2">
   <td/><td/><td/><td/><td/><td/>   
</tr>
<tr id="3">
   <td/><td/><td/><td rowspan="2"/>
   <td/>   
</tr>
</table>

То есть в каждой строке должно быть 6 ячеек (исходя из того, что было видно в первом ряду). Это намного гибче, чем моя первая попытка.

Примечание: Непонятно точно, каков желаемый выход OP, но вы могли бы избавить себя от многих проблем, просто выводя одну новую ячейку с соответствующим значением rowspan вместо нескольких новых ячеек. .

Вот таблица стилей:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:variable name="rowspan">
        <xsl:call-template name="sum">
            <xsl:with-param name="nodes" select="/table/tr[1]/td" />
        </xsl:call-template>
    </xsl:variable>
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template>
    <xsl:template match="tr[position() &gt; 1]/td[1]">
        <xsl:variable name="currcount">
            <xsl:call-template name="sum">
                <xsl:with-param name="nodes" select="../td" />
            </xsl:call-template>
        </xsl:variable>
        <xsl:variable name="needed" select="$rowspan - $currcount" />
        <xsl:if test="$needed &gt; 0">
            <xsl:call-template name="loop">
                <xsl:with-param name="i">0</xsl:with-param>
                <xsl:with-param name="count">
                    <xsl:value-of select="$needed" />
                </xsl:with-param>
            </xsl:call-template>
        </xsl:if>
        <xsl:copy>
            <xsl:apply-templates select="@*|node()" />
        </xsl:copy>
    </xsl:template>
    <xsl:template name="loop">
        <xsl:param name="i" />
        <xsl:param name="count" />
        <td />
        <xsl:if test="$i &lt; $count - 1">
            <xsl:call-template name="loop">
                <xsl:with-param name="i">
                    <xsl:value-of select="$i + 1" />
                </xsl:with-param>
                <xsl:with-param name="count">
                    <xsl:value-of select="$count" />
                </xsl:with-param>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>
    <!-- modified version of @Tomalak's code in question 1333558 -->
    <xsl:template name="sum">
        <xsl:param name="nodes" />
        <xsl:param name="sum" select="0" />
        <xsl:variable name="curr" select="$nodes[1]" />
        <!-- if we have a node, calculate & recurse -->
        <xsl:if test="$curr">
            <xsl:variable name="runningsum">
                <xsl:choose>
                    <xsl:when test="$curr[@rowspan]">
                        <xsl:value-of select="$sum + $curr/@rowspan" />
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:value-of select="$sum + 1" />
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:variable>
            <xsl:call-template name="sum">
                <xsl:with-param name="nodes" 
                                select="$nodes[position() &gt; 1]" />
                <xsl:with-param name="sum" select="$runningsum" />
            </xsl:call-template>
        </xsl:if>
        <!-- if we don't have a node (last recursive step), return sum -->
        <xsl:if test="not($curr)">
            <xsl:value-of select="$sum" />
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

Я надеюсь, что кто-то придет с гораздо более коротким и элегантным решением.