Могу ли я назначить элементы в массиве одновременно в Delphi / Pascal?

Question

Я хочу сделать что-то вроде PHP, Python и большинства других языков программирования:

my_array_name = [128, 38459, 438, 23674...] 

Поэтому я попытался воспроизвести это в Delphi / Pascal как можно лучше:

HSVtoRGB := [0, 0, 0];

(это для функции, которая возвращает массив RGB с данными значениями HSV.)

Но я получаю ошибки:

[DCC Error] Unit2.pas(44): E2001 Ordinal type required
[DCC Error] Unit2.pas(45): E2010 Incompatible types: 'HSVRealArray' and 'Set'

Есть идеи?Это школьная работа, но мой учитель не знал ответа.

Answer 1

Когда речь идет о динамических массивах, да:

type
  TIntArray = array of integer;

procedure TForm1.Button1Click(Sender: TObject);
var
  MyArr: TIntArray;
begin
  MyArr := TIntArray.Create(10, 20, 30, 40);
end;

Когда речь идет о статических массивах, вам нужно написать вспомогательную функцию:

type
  TIntArray = array[0..2] of integer;

function IntArray(const A, B, C: integer): TIntArray;
begin
  result[0] := A;
  result[1] := B;
  result[2] := C;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  MyArr: TIntArray;
begin
  MyArr := IntArray(10, 20, 30);
end;

Это похоже на то, как *Функция 1007 * создает запись TPoint.(Записи и массивы не одно и то же.)

Answer 2

Это область, в которой Delphi превращает что-то, что является простым однострочным оператором присваивания в большинстве языков, в нечто более сложное.

Один из подходов - объявить значение как типизированную константу:

type
  HSVRealArray = array[1..3] of real;
const
  constHSVVal: HSVRealArray = (0, 0, 0);
var
  currentValue: HSVRealArray;
begin
  currentValue := constHSVVal;
end;

Другой подход заключается в создании служебных функций, которые возвращают нужный вам тип:

function MakeHSVRealArray(H, S, V: Real): HSVRealArray;
begin
  Result[1] := H;
  Result[2] := S;
  Result[3] := V;
end;

currentValue := MakeHSVRealArray(0,0,0);

Answer 3

С некоторой дополнительной работой вы можете добиться чистой реализации:

var
    x: TRGB;
begin
    x := TRGB.Init(0,0,0);
end;

---

TRGB = record
    Red, Green, Blue: real;
    class function Init(r,g,b: real): TRGB; static;
end;

class function TRGB.Init(r, g, b: real): TRGB;
begin
    Result.Red := r;
    Result.Green := g;
    Result.Blue := b;
end;

Answer 4

Для обработки массива, инициализации массива и объявления констант массива Delphi не делает простые вещи простыми.

В некоторых ситуациях, подобных вашей, я инициализирую массив с помощью служебной функции, принимающей один параметр открытого массива, ивозвращает подходящую статическую строку.

const
    MaxArray = 10;
type
    TRealStaticArray = array[0..MaxArray] of Real;

function RealArray(const AnArray: array of real):TRealStaticArray;
    const DefaultValue=0.0;
    var i: integer;
    begin
        // EDIT: commented out, thanks Serg. for i:= 0 to low(AnArray)-1 do result[i]:=DefaultValue;
        for i:= High(AnArray)+1 to MaxArray do
            result[i]:=DefaultValue;
        for i:= Low(AnArray) to High(AnArray) do
            if (i>=0) and (i<=MaxArray) then
                result[i]:=AnArray[i];
    end;

Используйте это следующим образом:

 var MyArray: TRealStaticArray;
 ...
 MyArray := RealArray([10.0, 20.0, 30.0]);

Answer 5

Delphi-XE7 представил новый синтаксис для инициализации dynamic array.

// compile time const declaration of dynamic array
const
  my_ConstArray_name: TArray<Integer> = [128, 38459, 438, 23674];

// compile time var declaration of dynamic array
var
  my_VarArray_name: TArray<Integer> = [128, 38459, 438, 23674];

Назначение динамических массивов во время выполнения:

var
  a : TArray<Integer>;
begin
  a := [1,2,3];

К сожалению, этот синтаксис нельзя использовать в обычных статических массивах:

Type
  TMyArray = array[0..3] of Integer;  

const
  cMyArray: TMyArray = [0,1,2,3]; // E2010 Incompatible types: 'TMyArray' and 'Set'
  cMyArray: TMyArray = (0,1,2,3); // Works, as in all Delphi versions

var
  MyArray: TMyArray;
begin
  // This fails as well
  MyArray := [0,1,2,3]; // E2010 Incompatible types: 'TMyArray' and 'Set'
  MyArray := (0,1,2,3); // E2029 ')' expected but ',' found  
  //-----------^-------

  // This works in all Delphi versions !
  MyArray := cMyArray;

Answer 6

Я знаю, что это старый пост, но я сталкивался с этим, изучая технику автоматического назначения для Delphi. Этот пост имеет очень хорошее объяснение, а также способ автоматического назначения массива записей:

http://delphi.about.com/od/adptips2006/qt/const_array.htm

К сожалению, инициализация может быть выполнена только с собственным типом или типом записи. Объекты класса нуждаются во вспомогательной функции, как другие показали выше.

Answer 7

Можете ли вы попробовать что-то подобное:

TRGB = record
      Red  : integer;
      Green: integer;
      Bklue: integer;
  end;

var Variable:TRGB;

Variable.Red:=0;
Variable.Green:=0;
Variable.Blue:=0;

Answer 8

Оставляя в стороне общий вопрос, я хотел бы отметить, что конкретный вариант использования никогда не сработает: Delphi не может вернуть в стек содержимое массива неизвестной длины.

Тип возвращаемого значения функции должен быть известен по вызывающему коду.Это может быть указатель на кучу: это может быть даже управляемый памятью объект в стеке, но это не может быть неопределенным числом байтов в стеке, определяемое динамически целевой функцией.

И во многих других языках пример

return (0,0,0)  //return pointer to automatic allocation

будет неопределенным, даже если компилятор позволит вам это сделать.

Распространенный метод определения, использования и возврата константных значений:

int myarray[8] = {128, 38459, 438 ... 23674};
memcpy (myparam, myArray, sizeof (myArray)); 

... и вы можете сделать это в Delphi

Answer 9

[0, 0, 0] - это набор в Delphi. (0, 0, 0) - константа массива в Delphi! Просто используйте:

HSVtoRGB := (0, 0, 0);

(Если HSVtoRGB не является динамическим массивом. Вы объявили его как var HSVtoRGB: array[1..3] of integer; или что-то подобное?