Haskell FFI: вызов FunPtrs - PullRequest
Новая
       7

Haskell FFI: вызов FunPtrs

10 голосов
/ 15 июня 2009

Вот моя ситуация:

Я бы хотел вызвать функцию av_free_packet в ffmpeg: 

// avformat.h
static inline void av_free_packet(AVPacket *pkt)
{
  if (pkt && pkt->destruct)
    pkt->destruct(pkt);
}

Но, к сожалению, эта функция static inline, и поэтому в связанной библиотеке ее нет.

Однако это очень простая функция, которую я мог бы переопределить в Haskell. И это то, что я не могу понять, как это сделать. Вот частичная попытка (.hsc): 

av_free_packet :: Ptr AVPacket -> IO ()
av_free_packet pkt =
  when (nullPtr /= pkt) $ do
    destruct <- (#peek AVPacket, destruct) pkt :: IO (FunPtr (Ptr AVPacket -> IO ()))
    when (nullFunPtr /= destruct) $ funPtrToFun destruct pkt

funPtrToFun :: FunPtr a -> a
funPtrToFun = ?

Пока я мог бы прибегнуть к реализации этой функции в C (просто вызвав оригинал), но мне кажется, что вызов указателей на функции должен быть как-то возможен ..

Ответы [ 2 ]

8 голосов
/ 16 июня 2009

С Интерфейс внешних функций Haskell 98 1.0 ,

Динамический импорт.

Тип заглушки dynamic должен иметь вид (FunPtr ft) -> ft, где ft может быть любого стороннего типа.

В качестве примера рассмотрим 

foreign import ccall "dynamic"  
  mkFun :: FunPtr (CInt -> IO ()) -> (CInt -> IO ())

Фабрика заглушки mkFun преобразует любой указатель на функцию C, которая получает целочисленное значение в качестве единственного аргумента и не имеет возвращаемого значения в соответствующую функцию Haskell.

В вашем случае использование будет выглядеть примерно так: 

foreign import ccall "dynamic"
  funPktToNil:: FunPtr (Ptr AVPacket -> IO ()) -> Ptr AVPacket -> IO ()

av_free_packet :: Ptr AVPacket -> IO ()
av_free_packet pkt =
  when (nullPtr /= pkt) $ do
    destruct <- (#peek AVPacket, destruct) pkt
    when (nullFunPtr /= destruct) $ funPktToNil destruct pkt
7 голосов
/ 16 июня 2009

Небольшой пример, демонстрирующий, что это (ответ эфиманта) действительно работает (следуя заботе гбэкона):

C 

#include <stdio.h>

typedef void funcType(int, int);
typedef funcType * pFuncType;

void printer(int a, int b) {
  printf("%d %% %d\n", a, b);
}

pFuncType gimmeFunc(int dummy) {
  return printer;
}

Haskell: 

{-# LANGUAGE ForeignFunctionInterface #-}

import Foreign.Ptr

foreign import ccall unsafe "gimmeFunc"
  c_gimmeFunc :: Int -> IO (FunPtr (Int -> Int -> IO ()))
foreign import ccall "dynamic"
  mkFunIntIntNil :: FunPtr (Int -> Int -> IO ()) -> Int -> Int -> IO ()

main :: IO ()
main = do
  fun <- c_gimmeFunc 1
  mkFunIntIntNil fun 3 5

Это работает для меня - печатает 3 % 5

...