Как мне интегрировать Flash с Php

Question

Я хочу интегрировать мой flash-файл с php-кодом.Я получил следующий код от

http://www.kirupa.com/developer/actionscript/flashphpxml_integration2.htm

function lv(l, n, t, e, f) {
    if (l == undefined) {
        l = new LoadVars();
        l.onLoad = function () {
            var i;
            n.htmlText = "";
            if (t == undefined) {
                n.htmlText += "<b>" + this["title" + e] + "</b><br>";
            } else {
                for (i = 0; i < this.n; i++) {
                    n.htmlText += "<a href='" + this["link" + i] + "'>" + this["title" + i] + "</a><br>";
                }
            }
        };
    }
    l.load(f);
}
lv(sites_txt, "cycle", null, "sites.php");

Я выполнил все действия, описанные на этом форуме, но во время выполнения этого кода я получил ошибку Как

1180: Call to a possibly undefined method LoadVars.

Warning: 1060: Migration issue: The method LoadVars is no longer supported.  For more information, see the URLVariables class, the URLRequest.urlVariables and URLRequest.postData properties, and the URLLoader.dataFormat property..

1136: Incorrect number of arguments.  Expected 5.

Я новичок во флэш-сценариях, пожалуйста, объясните мне, как устранить эти

Answer 1

Ваш пример кода был в AS2, вот как вы отправляете и получаете данные из и в PHP, используя AS3, используя:

1. URLRequest
2. URLLoader
3. URLVariables

Вот небольшой урок, который я сделал для вас:

package
{
    import flash.net.URLRequest;
    import flash.net.URLLoader;
    import flash.net.URLVariables;
    import flash.net.URLRequestMethod;
    import flash.events.Event;

    public class PHPData extends Object
    {
        /**
         * Sends data to a PHP script
         * @param script A URL to the PHP script
         */
        public function send(script:String, vars:URLVariables):void
        {
            var req:URLRequest = new URLRequest(script);

            req.data = vars;
            req.method = URLRequestMethod.POST;

            var loader:URLLoader = new URLLoader();
            loader.load(req);

            // listeners
            loader.addEventListener(Event.COMPLETE, _complete);
        }

        /**
         * Called when a response has been received from a PHP script
         * @param e Event.COMPLETE
         */
        private function _complete(e:Event):void
        {
            var vars:URLVariables = new URLVariables(e.target.data);

            var i:String;
            for(i in vars)
            {
                trace(i + ": " + vars[i]);
            }

            e.target.removeEventListener(Event.COMPLETE, _complete);
        }
    }
}

С его помощью вы можете отправлять данные в данный скрипт PHP в формате URLVariables.

URLVariables легко подготовить следующим образом:

var vars:URLVariables = new URLVariables();

vars.myvar = "some value";
vars.myothervar = 30;

Вот небольшой пример, который я смоделировал для вас, который отправляет строку в PHP, затем PHP отправляет обратно строку, хэшированную как MD5, и также имеетвременная метка, прикрепленная как вторичное значение.

var php:PHPData = new PHPData();

var vars:URLVariables = new URLVariables();
vars.myvar = "marty";

php.send("http://projectavian.com/md5.php", vars);

Ваш вывод для этого будет примерно таким:

response: bb3761a33402b4f82806178e79ec5261
time: 1306133172

Просто измените метод _complete в классе PHPData наобработайте ваши данные ответа как требуется:)

---

Я добавлю это, потому что ваш вопрос имеет тег mysql ..

Все, что вам нужно сделать, этоваши стандартные запросы INSERT и SELECT в PHP-скрипте и закодируйте ваш результат в этот формат:

var=1&other=2&more=three

Так что вы могли бы иметь ..

<?php
    mysql_connect(/* ?? */);
    mysql_select_db(/* ?? */);

    // INSERT example
    $thing = mysql_real_escape_string($_POST["thing"]);
    mysql_query("INSERT INTO table VALUES('','$thing')");

    // SELECT for response
    $id = mysql_real_escape_string($_POST["uid"]);
    $query = mysql_query("SELECT * FROM table WHERE id='$uid' LIMIT 1");

    // send response
    $r = mysql_fetch_assoc($query);
    echo 'fname=' . $r["first_name"] . '&lname=' . $r["last_name"];
?>