Есть ли в XSL-FO что-то похожее на CSS? - PullRequest
Новая
       15

Есть ли в XSL-FO что-то похожее на CSS?

10 голосов
/ 11 июня 2009

Я знаю, что сам XSLT имеет наборы атрибутов, но это заставляет меня использовать 

<xsl:element name="fo:something">

каждый раз, когда я хочу вывести 

<fo:something>

бирка. Есть ли в спецификации XSL-FO что-нибудь, что позволило бы мне указать (скажем) набор атрибутов по умолчанию (margin, padding и т. Д.) Для всех таблиц в выводе FO?

По сути, я ищу функциональность CSS, но для вывода FO вместо HTML.

Ответы [ 2 ]

11 голосов
/ 11 июня 2009

Нет, вы не обязаны использовать xsl: element, атрибут use-attribute-sets может появляться в элементах литеральных результатов, если вы поместите его в пространство имен XSLT, поэтому вы можете использовать что-то вроде: 

<fo:something xsl:use-attribute-sets="myAttributeSet">

Если вы хотите иметь что-то близкое к функциональности CSS, вы можете добавить другое XSLT-преобразование в конце вашей обработки, которое добавит нужные вам атрибуты. Вы можете начать с рекурсивного преобразования идентификаторов, а затем добавить шаблоны, соответствующие элементам, которые вы хотите изменить, см. Небольшой пример ниже 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:attribute-set name="commonAttributes">
    <xsl:attribute name="common">value</xsl:attribute>
  </xsl:attribute-set>
  <xsl:template match="node() | @*">
    <xsl:copy>
      <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
  </xsl:template>
  <xsl:template match="someElement">
    <xsl:copy use-attribute-sets="commonAttributes">
      <xsl:attribute name="someAttribute">someValue</xsl:attribute>
      <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>
0 голосов
/ 10 мая 2012

В XSLT 2.0 есть и другая опция. Следующий шаблон может быть в отдельном файле. Вам нужно только включить этот файл в исходный xsl-файл, который создает структуру FO. 

<xsl:transform 
    version="2.0"
    xmlns:fo="http://www.w3.org/1999/XSL/Format"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

    <xsl:template match="/" priority="1000">
        <!-- Store generated xsl-fo document in variable-->
        <xsl:variable name="xsl-fo-document">
            <xsl:next-match/>
        </xsl:variable>

        <!-- Copy everything to result document and apply "css" -->
        <xsl:apply-templates select="$xsl-fo-document" mode="css"/>
    </xsl:template>

    <xsl:template match="@*|node()" priority="1000" mode="css">
        <xsl:param name="copy" select="true()" tunnel="yes"/>
        <xsl:if test="$copy">
            <xsl:copy>
                <xsl:next-match>
                    <xsl:with-param name="copy" select="false()" tunnel="yes"/>
                </xsl:next-match>
                <xsl:apply-templates select="@*|node()" mode="css"/>
            </xsl:copy>
            </xsl:if>
    </xsl:template>

    <!-- **************************** -->
    <!-- CSS Examples (e.g. fo:table) -->
    <!-- **************************** -->

    <xsl:template match="fo:table-cell[not(@padding)]" mode="css">
        <xsl:attribute name="padding" select="'2pt'"/>
        <xsl:next-match/>
    </xsl:template>

    <xsl:template match="fo:table-header/fo:table-row/fo:table-cell" mode="css">
        <xsl:attribute name="color" select="'black'"/>
        <xsl:attribute name="font-style" select="'bold'"/>
        <xsl:next-match/>
    </xsl:template>

</xsl:transform>
...