Получение свойств файла с использованием командного файла

Question

Мне было интересно, можно ли получить свойства выбранных файлов с помощью командного файла.Я нашел только пример winbatch, который смог это сделать.Любые предложения приветствуются.Спасибо

Answer 1

Для стандартных свойств файлов Windows используйте WMIC DATAFILE.

Некоторые форматы файлов (например, .mp3 в заголовках ID3) имеют хорошо известные свойства. Даже если некоторые из них могут отображаться в Проводнике, не все из них доступны через WMIC DATAFILE.

И, наконец, многие другие свойства документа в пользовательских форматах файлов хранятся без простого (или даже вообще возможного) внешнего доступа.

Answer 2

Используя VBScript, я смог отобразить последнего автора и менеджера из недавнего документа Word 2010, который я создал:

Option Explicit

Const Schema_LastAuthor = "{F29F85E0-4FF9-1068-AB91-08002B27B3D9} 8"
Const Schema_Manager = "{D5CDD502-2E9C-101B-9397-08002B2CF9AE} 14"

Dim Shell
Set Shell = CreateObject("Shell.Application")

If (Not Shell Is Nothing) Then

    Dim ThisFolder
    Set ThisFolder = Shell.NameSpace("YOUR_FOLDER_HERE")

    If (Not ThisFolder Is Nothing) Then

        Dim ThisFolderItem
        Set ThisFolderItem = ThisFolder.ParseName("YOUR_DOCUMENT_HERE")

        If (Not ThisFolderItem Is Nothing) Then

            Dim lastAuthor, manager
            lastAuthor = ThisFolderItem.ExtendedProperty(Schema_LastAuthor)
            manager = ThisFolderItem.ExtendedProperty(Schema_Manager)

            WScript.Echo "   Document:   " & ThisFolderItem.Name
            WScript.Echo "Last author:   " & lastAuthor
            WScript.Echo "    Manager:   " & manager

        End If

        Set ThisFolderItem = Nothing

    End If

    Set ThisFolder = Nothing

End If

Set Shell = Nothing

WScript.Quit

Подробнее о схеме системы свойств Windows для документов . Надеюсь, это поможет!