ActionScript проигрывает аудио

Question

Я просто пытаюсь создать простой файл .swf, который воспроизводит фрагмент аудио при загрузке.Это компилируется, но когда я поднимаю его в браузере, ничего не происходит.Я мог только найти учебники на основе спрайтов, поэтому я сделал удар, чтобы вы могли расширять звук так же, как вы расширяете Sprite.Окончательная версия будет безголовой и будет называться моим Java Script для воспроизведения звука в событиях.

   package {
            import flash.media.Sound;
            import flash.net.URLRequest;

            public class typeRight extends Sound {
                    public function HelloWorld( ) {
                    load(new URLRequest('./sound.mp3'));
                    play();
                    }
            }
    }

Я НЕ работаю во Flash, поэтому, пожалуйста, не советуйте GUI;)

Answer 1

Вместо того, чтобы создавать подклассы класса Sound, создайте такой класс документов, который содержит класс Sound:

package
{
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.media.Sound;
    import flash.media.SoundChannel;
    import flash.net.URLRequest;

    public class SoundPlayer extends Sprite
    {
        protected var _sound : Sound;
        protected var _channel : SoundChannel;

        public function SoundPlayer()
        {
            _sound = new Sound();
            _sound.addEventListener(Event.COMPLETE, soundLoadCompleteHandler);
            _sound.addEventListener(IOErrorEvent.IO_ERROR, loadError);
            _sound.load(new URLRequest("./sound.mp3"));
        }

        protected function soundLoadCompleteHandler(evt : Event) : void
        {
            // Use the _channel object to control sound properties such as pan and volume.
            _channel = _sound.play();
        }

        protected function loadError(evt : IOErrorEvent) : void
        {
            trace ("ERROR :: " + evt);
            // You could try recovering from the error here.
        }

    }
}