Сохраните файл, загруженный через WinHTTP, на диск, используя Delphi XE - PullRequest
Новая
       31

Сохраните файл, загруженный через WinHTTP, на диск, используя Delphi XE

3 голосов
/ 23 июля 2011

Ответ на на этот вопрос показал, насколько просто использовать WinHTTP с помощью импорта библиотеки типов в delphi.

Я импортировал библиотеку типов для WinHTTP, а затем попытался написать вспомогательную функцию загрузки файлов, используя этот API. Вот как далеко я добрался:

Я не могу понять, как сохранить IWinHttpRequest.ResponseStream (объявленный как OleVariant в файле TLB) в виде потока на диск. 

// IWinHttpRequest is defined by importing type library of WinHTTP.
// Microsoft WinHTTP Services, version 5.1 (Version 5.1) C:\Windows\system32\winhttp.dll
function Download(const url, filename: String): Boolean;
var
   http: IWinHttpRequest;
   wUrl: WideString;
   fs:TFileStream;
   FileStream:IStream;
   sz,rd,wr:Int64;
begin
  try
   wUrl := url;
   http := CoWinHttpRequest.Create;
   http.open('GET', wurl, False);
   http.send(EmptyParam);

   FStatus := http.status; // 200=OK!
   result := FStatus=200;


   if result then
   begin
     fs := TFileStream.Create(filename, fmCreate, fmShareExclusive );
     try
      FileStream := TStreamAdapter.Create(fs, soReference) as IStream;
      sz := http.ResponseStream.Size;
      http.ResponseStream.CopyTo(FileStream,sz,rd,wr);
     finally
         FileStream :=  nil;
         fs.Free;
     end;
   end;
  except
      result := false;
      // do not raise exceptions.
  end;
end;

Выдержка из WinHTTP_TLB.pas: 

 IWinHttpRequest = interface(IDispatch)
    ['{016FE2EC-B2C8-45F8-B23B-39E53A75396B}']
    ......
    property ResponseStream: OleVariant read Get_ResponseStream;

Обновление: теперь я получаю исключение во время выполнения о ole-вариантах при вызове http.ResponseStream.CopyTo(...)

 EOleError 'Variant does not reference an automation object'.

1 Ответ

6 голосов
/ 23 июля 2011

Уоррен, вы должны использовать класс AxCtrls.TOleStream, чтобы связать поток ответов с Classes.TFileStream

примерно так 

IWinHttpRequest.ResponseStream -> TOleStream -> TFileStream

Проверьте этот пример кода 

{$APPTYPE CONSOLE}

uses
  Variants,
  ActiveX,
  Classes,
  AxCtrls,
  WinHttp_TLB,
  SysUtils;


function Download(const url, filename: String): Boolean;
var
   http: IWinHttpRequest;
   wUrl: WideString;
   fs:TFileStream;
   HttpStream :IStream;
   sz,rd,wr:Int64;
   FStatus : Integer;
   OleStream: TOleStream;
begin
  try
   wUrl := url;
   http := CoWinHttpRequest.Create;
   http.open('GET', wurl, False);
   http.send(EmptyParam);

   FStatus := http.status; // 200=OK!
   result := FStatus=200;

   if result then
   begin
    HttpStream:=IUnknown(http.ResponseStream) as IStream;
    OleStream:= TOleStream.Create(HttpStream);
    try
      fs:= TFileStream.Create(FileName, fmCreate);
      try
        OleStream.Position:= 0;
        fs.CopyFrom(OleStream, OleStream.Size);
      finally
        fs.Free;
      end;
    finally
      OleStream.Free;
    end;
   end;

  except
      result := false;
      // do not raise exceptions.
  end;
end;


begin
  try
    Download('http://foo.html','C:\Foo\anyfile.foo');
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.
...